libexec/ld.elf_so/arch/i386/rtld_start.S

   1 /*      $NetBSD: rtld_start.S,v 1.11 2010/12/05 00:56:07 joerg Exp $    */
   2
   3 /*-
   4  * Copyright (c) 1998, 2002 The NetBSD Foundation, Inc.
   5  * All rights reserved.
   6  *
   7  * This code is derived from software contributed to The NetBSD Foundation
   8  * by Christos Zoulas and by Charles M. Hannum.
   9  *
  10  * Redistribution and use in source and binary forms, with or without
  11  * modification, are permitted provided that the following conditions
  12  * are met:
  13  * 1. Redistributions of source code must retain the above copyright
  14  *    notice, this list of conditions and the following disclaimer.
  15  * 2. Redistributions in binary form must reproduce the above copyright
  16  *    notice, this list of conditions and the following disclaimer in the
  17  *    documentation and/or other materials provided with the distribution.
  18  *
  19  * THIS SOFTWARE IS PROVIDED BY THE NETBSD FOUNDATION, INC. AND CONTRIBUTORS
  20  * ``AS IS'' AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED
  21  * TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR
  22  * PURPOSE ARE DISCLAIMED.  IN NO EVENT SHALL THE FOUNDATION OR CONTRIBUTORS
  23  * BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR
  24  * CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF
  25  * SUBSTITUTE GOODS OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS
  26  * INTERRUPTION) HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN
  27  * CONTRACT, STRICT LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE)
  28  * ARISING IN ANY WAY OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE
  29  * POSSIBILITY OF SUCH DAMAGE.
  30  */
  31
  32 #include <machine/asm.h>
  33
  34         .text
  35         .align  4
  36         .globl  .rtld_start
  37         .hidden .rtld_start
  38         .type   .rtld_start,@function
  39 .rtld_start:
  40         subl    $8,%esp                 # make room of obj_main and exit proc
  41         pushl   %ebx                    # save ps_strings
  42
  43         call    1f
  44 1:
  45         popl    %edx
  46         leal    _DYNAMIC-1b(%edx),%ecx  # &_DYNAMIC
  47         movl    %ecx,%ebx
  48         subl    _GLOBAL_OFFSET_TABLE_-1b(%edx),%ebx
  49
  50         pushl   %ebx                    # relocbase
  51         pushl   %ecx                    # &_DYNAMIC
  52         call    _rtld_relocate_nonplt_self
  53
  54         leal    12(%esp),%eax           # &cleanup
  55         pushl   %ebx                    # relocbase
  56         pushl   %eax                    # sp
  57         call    _rtld                   # _rtld(sp, relocbase)
  58
  59         addl    $16,%esp                # pop args
  60
  61         popl    %ebx                    # %ebx = ps_strings
  62         popl    %edx                    # %edx = cleanup
  63         popl    %ecx                    # %ecx = obj_main
  64         jmp     *%eax
  65
  66         .align  4
  67         .globl  _rtld_bind_start
  68         .hidden _rtld_bind_start
  69         .type   _rtld_bind_start,@function
  70 _rtld_bind_start:       # (obj, reloff)
  71         pushf                           # save registers
  72         pushl   %eax
  73         pushl   %ecx
  74         pushl   %edx
  75
  76         pushl   20(%esp)                # Copy of reloff
  77         pushl   20(%esp)                # Copy of obj
  78         call    _rtld_bind              # Call the binder
  79         addl    $8,%esp                 # pop binder args
  80         movl    %eax,20(%esp)           # Store function to be called in obj
  81
  82         popl    %edx
  83         popl    %ecx
  84         popl    %eax
  85         popf
  86
  87         leal    4(%esp),%esp            # Discard reloff, do not change eflags
  88         ret