libexec/ld.elf_so/arch/x86_64/rtld_start.S

   1 /*      $NetBSD: rtld_start.S,v 1.8 2010/12/05 00:56:07 joerg Exp $     */
   2
   3 /*
   4  * Copyright (c) 2001 Wasabi Systems, Inc.
   5  * All rights reserved.
   6  *
   7  * Written by Frank van der Linden for Wasabi Systems, Inc.
   8  *
   9  * Redistribution and use in source and binary forms, with or without
  10  * modification, are permitted provided that the following conditions
  11  * are met:
  12  * 1. Redistributions of source code must retain the above copyright
  13  *    notice, this list of conditions and the following disclaimer.
  14  * 2. Redistributions in binary form must reproduce the above copyright
  15  *    notice, this list of conditions and the following disclaimer in the
  16  *    documentation and/or other materials provided with the distribution.
  17  * 3. All advertising materials mentioning features or use of this software
  18  *    must display the following acknowledgement:
  19  *      This product includes software developed for the NetBSD Project by
  20  *      Wasabi Systems, Inc.
  21  * 4. The name of Wasabi Systems, Inc. may not be used to endorse
  22  *    or promote products derived from this software without specific prior
  23  *    written permission.
  24  *
  25  * THIS SOFTWARE IS PROVIDED BY WASABI SYSTEMS, INC. ``AS IS'' AND
  26  * ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED
  27  * TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR
  28  * PURPOSE ARE DISCLAIMED.  IN NO EVENT SHALL WASABI SYSTEMS, INC
  29  * BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR
  30  * CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF
  31  * SUBSTITUTE GOODS OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS
  32  * INTERRUPTION) HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN
  33  * CONTRACT, STRICT LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE)
  34  * ARISING IN ANY WAY OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE
  35  * POSSIBILITY OF SUCH DAMAGE.
  36  */
  37
  38 #include <machine/asm.h>
  39
  40         .text
  41         .align  16
  42         .globl  .rtld_start
  43         .hidden .rtld_start
  44         .type   .rtld_start,@function
  45 .rtld_start:
  46         subq    $16,%rsp                # make room of obj_main and exit proc
  47         movq    %rsp,%r12               # stack pointer arg to _rtld
  48         pushq   %rbx                    # save ps_strings
  49
  50         leaq    _GLOBAL_OFFSET_TABLE_(%rip),%rax
  51         leaq    _DYNAMIC(%rip),%rdi     # &_DYNAMIC
  52         movq    %rdi,%rbx
  53         subq    (%rax),%rbx             # relocbase
  54
  55         movq    %rbx,%rsi
  56         call    _rtld_relocate_nonplt_self
  57
  58         movq    %r12,%rdi
  59         movq    %rbx,%rsi
  60         call    _rtld                   # _rtld(sp, relocbase)
  61
  62         popq    %rbx                    # %rbx = ps_strings
  63         popq    %rdx                    # %rdx = cleanup
  64         popq    %rcx                    # %rcx = obj_main
  65         jmp     *%rax
  66
  67         .align  4
  68         .globl  _rtld_bind_start
  69         .hidden _rtld_bind_start
  70         .type   _rtld_bind_start,@function
  71 _rtld_bind_start:       # (obj, reloff)
  72         # This function is called with a misaligned stack from the PLT
  73         # due to the additional argument pushed.
  74         # At this point %rsp % 16 == 8.
  75         pushfq                          # save caller-saved registers
  76         pushq   %rax
  77         pushq   %rcx
  78         pushq   %rdx
  79         pushq   %rsi
  80         pushq   %rdi
  81         pushq   %r8
  82         pushq   %r9
  83         pushq   %r10
  84         pushq   %r11
  85
  86         movq    80(%rsp),%rdi
  87         movq    88(%rsp),%rsi
  88
  89         call    _rtld_bind              # call the binder
  90         movq    %rax,88(%rsp)           # store function in obj
  91
  92         popq    %r11
  93         popq    %r10
  94         popq    %r9
  95         popq    %r8
  96         popq    %rdi
  97         popq    %rsi
  98         popq    %rdx
  99         popq    %rcx
 100         popq    %rax
 101         popfq
 102
 103         leaq    8(%rsp),%rsp
 104
 105         ret