common/lib/libc/arch/arm/gen/byte_swap_4.S

   1 /*      $NetBSD: byte_swap_4.S,v 1.7 2013/08/19 03:44:47 matt Exp $     */
   2
   3 /*-
   4  * Copyright (c) 1997 The NetBSD Foundation, Inc.
   5  * All rights reserved.
   6  *
   7  * This code is derived from software contributed to The NetBSD Foundation
   8  * by Neil A. Carson
   9  *
  10  * Redistribution and use in source and binary forms, with or without
  11  * modification, are permitted provided that the following conditions
  12  * are met:
  13  * 1. Redistributions of source code must retain the above copyright
  14  *    notice, this list of conditions and the following disclaimer.
  15  * 2. Redistributions in binary form must reproduce the above copyright
  16  *    notice, this list of conditions and the following disclaimer in the
  17  *    documentation and/or other materials provided with the distribution.
  18  *
  19  * THIS SOFTWARE IS PROVIDED BY THE NETBSD FOUNDATION, INC. AND CONTRIBUTORS
  20  * ``AS IS'' AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED
  21  * TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR
  22  * PURPOSE ARE DISCLAIMED.  IN NO EVENT SHALL THE FOUNDATION OR CONTRIBUTORS
  23  * BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR
  24  * CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF
  25  * SUBSTITUTE GOODS OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS
  26  * INTERRUPTION) HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN
  27  * CONTRACT, STRICT LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE)
  28  * ARISING IN ANY WAY OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE
  29  * POSSIBILITY OF SUCH DAMAGE.
  30  */
  31
  32 #include <machine/asm.h>
  33
  34 #if defined(_KERNEL) || defined(_STANDALONE)
  35 #define FUNC    _C_LABEL(bswap32)
  36 #else
  37 #define FUNC    _C_LABEL(__bswap32)
  38 #endif
  39 ENTRY(FUNC)
  40 #ifdef _ARM_ARCH_6
  41         rev     r0, r0
  42 #elif !defined(__thumb__)
  43         eor     r1, r0, r0, ror #16     /* 4.3.2.1 -> 42.31.42.31 */
  44         bic     r1, r1, #0x00FF0000     /* 42.31.42.31 -> 42.0.42.31 */
  45         mov     r0, r0, ror #8          /* 4.3.2.1 -> 1.4.3.2 */
  46         eor     r0, r0, r1, lsr #8      /* 1.4.3.2 ^ 0.42.0.42 -> 1.2.3.4 */
  47 #else
  48         movs    r3, #16
  49         lsls    r1, r0, #8              /* 4.3.2.1 -> 3.2.1.0 /*
  50         lsrs    r0, r0, #8              /* 4.3.2.1 -> 0.4.3.2 */
  51         rors    r1, r3                  /* 3.2.1.0 -> 1.0.3.2 */
  52         rors    r0, r3                  /* 0.4.3.2 -> 3.2.0.4 */
  53         lsrs    r1, r1, #8              /* 1.0.3.2 -> 0.1.0.3 */
  54         lsls    r1, r1, #8              /* 0.1.0.3 -> 1.0.3.0 */
  55         lsls    r0, r0, #8              /* 3.2.0.4 -> 2.0.4.0 */
  56         lsrs    r0, r0, #8              /* 2.0.4.0 -> 0.2.0.4 */
  57         orrs    r0, r0, r1              /* 1.0.3.0 | 0.2.0.4 -> 1.2.3.4 */
  58 #endif
  59         RET
  60 END(FUNC)
  61
  62 #if BYTE_ORDER == LITTLE_ENDIAN
  63 STRONG_ALIAS(_C_LABEL(ntohl), FUNC)
  64 STRONG_ALIAS(_C_LABEL(htonl), FUNC)
  65 #endif