common/lib/libc/arch/arm/string/strchr_naive.S

   1 /*-
   2  * Copyright (c) 2013 The NetBSD Foundation, Inc.
   3  * All rights reserved.
   4  *
   5  * This code is derived from software contributed to The NetBSD Foundation
   6  * by Matt Thomas of 3am Software Foundry.
   7  *
   8  * Redistribution and use in source and binary forms, with or without
   9  * modification, are permitted provided that the following conditions
  10  * are met:
  11  * 1. Redistributions of source code must retain the above copyright
  12  *    notice, this list of conditions and the following disclaimer.
  13  * 2. Redistributions in binary form must reproduce the above copyright
  14  *    notice, this list of conditions and the following disclaimer in the
  15  *    documentation and/or other materials provided with the distribution.
  16  *
  17  * THIS SOFTWARE IS PROVIDED BY THE NETBSD FOUNDATION, INC. AND CONTRIBUTORS
  18  * ``AS IS'' AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED
  19  * TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR
  20  * PURPOSE ARE DISCLAIMED.  IN NO EVENT SHALL THE FOUNDATION OR CONTRIBUTORS
  21  * BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR
  22  * CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF
  23  * SUBSTITUTE GOODS OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS
  24  * INTERRUPTION) HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN
  25  * CONTRACT, STRICT LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE)
  26  * ARISING IN ANY WAY OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE
  27  * POSSIBILITY OF SUCH DAMAGE.
  28  */
  29 #include <machine/asm.h>
  30
  31 RCSID("$NetBSD: strchr_naive.S,v 1.4 2013/08/19 17:02:25 matt Exp $")
  32
  33 /* LINTSTUB: char * strchr(const char *, int) */
  34 ENTRY(strchr)
  35 #ifdef __thumb__
  36         movs    r3, #0xff
  37         ands    r1, r1, r3      /* restrict to a byte value */
  38 1:      ldrb    r3, [r0]        /* read a byte */
  39         cmp     r3, r1          /* does it match? */
  40         beq     2f              /*   yes, set return value */
  41         adds    r0, r0, #1      /* advance to next byte */
  42         cmp     r3, #0          /* was it a NUL? */
  43         bne     1b              /*   no, get next byte */
  44         movs    r0, #0          /* set return to NULL */
  45 2:      RET                     /* return */
  46 #else
  47         mov     r2, r0          /* using r0 as return value */
  48         mov     r0, #0          /* default to no match */
  49         and     r1, r1, #0xff   /* restrict to a byte value */
  50 1:      ldrb    r3, [r2], #1    /* read a byte */
  51         cmp     r3, r1          /* does it match? */
  52         subeq   r0, r2, #1      /*   yes, set return value to point to it */
  53         cmpne   r3, #0          /*   no, was it a NUL? */
  54         bne     1b              /*     no, get next byte */
  55         RET
  56 #endif
  57 END(strchr)