common/lib/libc/arch/arm/string/strlcat_naive.S

   1 /*-
   2  * Copyright (c) 2013 The NetBSD Foundation, Inc.
   3  * All rights reserved.
   4  *
   5  * This code is derived from software contributed to The NetBSD Foundation
   6  * by Matt Thomas of 3am Software Foundry.
   7  *
   8  * Redistribution and use in source and binary forms, with or without
   9  * modification, are permitted provided that the following conditions
  10  * are met:
  11  * 1. Redistributions of source code must retain the above copyright
  12  *    notice, this list of conditions and the following disclaimer.
  13  * 2. Redistributions in binary form must reproduce the above copyright
  14  *    notice, this list of conditions and the following disclaimer in the
  15  *    documentation and/or other materials provided with the distribution.
  16  *
  17  * THIS SOFTWARE IS PROVIDED BY THE NETBSD FOUNDATION, INC. AND CONTRIBUTORS
  18  * ``AS IS'' AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED
  19  * TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR
  20  * PURPOSE ARE DISCLAIMED.  IN NO EVENT SHALL THE FOUNDATION OR CONTRIBUTORS
  21  * BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR
  22  * CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF
  23  * SUBSTITUTE GOODS OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS
  24  * INTERRUPTION) HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN
  25  * CONTRACT, STRICT LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE)
  26  * ARISING IN ANY WAY OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE
  27  * POSSIBILITY OF SUCH DAMAGE.
  28  */
  29
  30 #include <machine/asm.h>
  31
  32 RCSID("$NetBSD: strlcat_naive.S,v 1.3 2013/08/22 19:25:00 matt Exp $")
  33
  34 /* LINTSTUB: size_t strlcat(char *, const char *, size_t) */
  35 ENTRY(strlcat)
  36         adds    r3, r2, r0              /* point to just end of dst */
  37         mov     ip, r0                  /* need to keep r0 for a while */
  38 1:      cmp     ip, r3                  /* still within dst? */
  39         beq     3f                      /*   no, get length of src */
  40         ldrb    r2, [ip], #1            /* load next byte */
  41         cmp     r2, #0                  /* was it a NUL? */
  42         bne     1b                      /*   no, get next byte */
  43
  44         sub     r0, ip, r0              /* get actual length of dst */
  45         subs    r0, r0, #1              /* account for the trailing NUL */
  46         subs    r3, r3, #1              /* back up to last byte in dst */
  47         sub     ip, ip, #1              /* back up over the NUL */
  48
  49 2:      ldrb    r2, [r1], #1            /* load next byte from append */
  50 #if defined(__thumb__) && defined(_ARM_ARCH_T2)
  51         cbz     r2, 5f                  /* was it a NUL? yes, end of append */
  52 #else
  53         cmp     r2, #0                  /* was it a NUL? */
  54         beq     5f                      /*   yes, end of append */
  55 #endif
  56         adds    r0, r0, #1              /* count another byte */
  57         cmp     ip, r3                  /* do we have enough room for it? */
  58 #ifdef __thumb__
  59         bge     2b
  60         strb    r2, [ip], #1            /*   yes, store it */
  61 #else
  62         strblt  r2, [ip], #1            /*   yes, store it */
  63 #endif
  64         b       2b                      /* get next byte from append */
  65
  66 3:      subs    r0, r3, r0              /* move size to return value */
  67 4:      ldrb    r2, [r1], #1            /* load next byte from append */
  68 #if defined(__thumb__) && defined(_ARM_ARCH_T2)
  69         cbz     r2, 6f                  /* was it a NUL? yes, we're done */
  70 #else
  71         RETc(eq)                        /*   yes, we're done */
  72 #endif
  73         adds    r0, r0, #1              /* add one to return value */
  74         b       4b                      /* get next byte from append */
  75
  76 5:      movs    r2, #0                  /* NUL */
  77         strb    r2, [ip]                /* append final NUL */
  78 6:      RET                             /* return */
  79 END(strlcat)