common/lib/libc/arch/arm/string/strlen_naive.S

   1 /*-
   2  * Copyright (c) 2013 The NetBSD Foundation, Inc.
   3  * All rights reserved.
   4  *
   5  * This code is derived from software contributed to The NetBSD Foundation
   6  * by Matt Thomas of 3am Software Foundry.
   7  *
   8  * Redistribution and use in source and binary forms, with or without
   9  * modification, are permitted provided that the following conditions
  10  * are met:
  11  * 1. Redistributions of source code must retain the above copyright
  12  *    notice, this list of conditions and the following disclaimer.
  13  * 2. Redistributions in binary form must reproduce the above copyright
  14  *    notice, this list of conditions and the following disclaimer in the
  15  *    documentation and/or other materials provided with the distribution.
  16  *
  17  * THIS SOFTWARE IS PROVIDED BY THE NETBSD FOUNDATION, INC. AND CONTRIBUTORS
  18  * ``AS IS'' AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED
  19  * TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR
  20  * PURPOSE ARE DISCLAIMED.  IN NO EVENT SHALL THE FOUNDATION OR CONTRIBUTORS
  21  * BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR
  22  * CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF
  23  * SUBSTITUTE GOODS OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS
  24  * INTERRUPTION) HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN
  25  * CONTRACT, STRICT LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE)
  26  * ARISING IN ANY WAY OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE
  27  * POSSIBILITY OF SUCH DAMAGE.
  28  */
  29 #include <machine/asm.h>
  30
  31 RCSID("$NetBSD: strlen_naive.S,v 1.8 2013/08/19 17:02:25 matt Exp $")
  32
  33 #ifdef STRNLEN
  34 /* LINTSTUB: size_t strnlen(const char *, size_t) */
  35 ENTRY(strnlen)
  36         adds    r3, r0, #1      /* start of src + NUL */
  37 #ifdef __thumb__
  38         adds    r2, r0, r1      /* &src[maxlen] */
  39         mov     ip, r2
  40 #else
  41         adds    ip, r0, r1      /* &src[maxlen] */
  42 #endif
  43 1:      cmp     r0, ip          /* is this of string? */
  44         beq     2f              /*   yes it is */
  45 #ifdef __thumb__
  46         ldrb    r2, [r0]        /* read a byte */
  47         adds    r0, r0, #1      /* advance to next byte */
  48 #else
  49         ldrb    r2, [r0], #1    /* read a byte */
  50 #endif
  51         cmp     r2, #0          /* is it a NUL? */
  52         bne     1b              /*   no, get next byte */
  53         subs    r0, r0, r3      /* get difference between start and end */
  54         RET                     /* return */
  55 2:      mov     r0, r1          /* get maxlen */
  56         RET                     /* return */
  57 END(strnlen)
  58 #else /* STRNLEN */
  59 /* LINTSTUB: size_t strlen(const char *) */
  60 ENTRY(strlen)
  61         adds    r3, r0, #1      /* start of src + NUL */
  62 1:
  63 #ifdef __thumb__
  64         ldrb    r2, [r0]        /* read a byte */
  65         adds    r0, r0, #1
  66 #else
  67         ldrb    r2, [r0], #1    /* read a byte */
  68 #endif
  69         cmp     r2, #0          /* is it a NUL? */
  70         bne     1b              /*   no, get next byte */
  71         subs    r0, r0, r3      /* return difference between start and end */
  72         RET
  73 END(strlen)
  74 #endif /* !STRNLEN */