common/lib/libc/arch/arm/string/strncmp.S

   1 /*      $NetBSD: strncmp.S,v 1.2 2013/08/19 00:57:25 matt Exp $ */
   2
   3 /*
   4  * Copyright (c) 2002 ARM Ltd
   5  * All rights reserved.
   6  *
   7  * Redistribution and use in source and binary forms, with or without
   8  * modification, are permitted provided that the following conditions
   9  * are met:
  10  * 1. Redistributions of source code must retain the above copyright
  11  *    notice, this list of conditions and the following disclaimer.
  12  * 2. Redistributions in binary form must reproduce the above copyright
  13  *    notice, this list of conditions and the following disclaimer in the
  14  *    documentation and/or other materials provided with the distribution.
  15  * 3. The name of the company may not be used to endorse or promote
  16  *    products derived from this software without specific prior written
  17  *    permission.
  18  *
  19  * THIS SOFTWARE IS PROVIDED BY ARM LTD ``AS IS'' AND ANY EXPRESS OR IMPLIED
  20  * WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE IMPLIED WARRANTIES OF
  21  * MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE ARE DISCLAIMED.
  22  * IN NO EVENT SHALL ARM LTD BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL,
  23  * SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT LIMITED
  24  * TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE, DATA, OR
  25  * PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY THEORY OF
  26  * LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT (INCLUDING
  27  * NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE OF THIS
  28  * SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.
  29  */
  30
  31 #include <machine/asm.h>
  32
  33 RCSID("$NetBSD: strncmp.S,v 1.2 2013/08/19 00:57:25 matt Exp $")
  34
  35 ENTRY(strncmp)
  36 /* if ((len - 1) < 0) return 0 */
  37         subs    r2, r2, #1
  38 #ifdef __thumb__
  39         bmi     5f
  40 #else
  41         movmi   r0, #0
  42         RETc(mi)
  43 #endif
  44
  45 /* ip == last src address to compare */
  46 #ifdef __thumb__
  47         adds    r3, r0, r2
  48         mov     ip, r3
  49         subs    r1, r1, r0
  50 #else
  51         add     ip, r0, r2
  52 #endif
  53 1:
  54 #ifdef __thumb__
  55         ldrb    r2, [r0]
  56         ldrb    r3, [r1, r0]
  57         adds    r0, r0, #1
  58         cmp     ip, r0          /* exhausted length? */
  59         bcc     4f              /*   yes, we're done */
  60         cmp     r2, #1          /* NUL? */
  61         bcc     4f              /*   yes, we're done */
  62         cmp     r2, r3          /* different? */
  63 #else
  64         ldrb    r2, [r0], #1
  65         ldrb    r3, [r1], #1
  66         cmp     ip, r0
  67         cmpcs   r2, #1
  68         cmpcs   r2, r3
  69 #endif
  70         beq     1b
  71 4:      subs    r0, r2, r3
  72         RET
  73 #ifdef __thumb__
  74 5:      movs    r0, #0
  75         RET
  76 #endif
  77 END(strncmp)