common/lib/libc/arch/vax/gen/urem.S

   1 /*-
   2  * Copyright (c) 1991, 1993
   3  *      The Regents of the University of California.  All rights reserved.
   4  *
   5  * This code is derived from software contributed to Berkeley by
   6  * Donn Seeley at UUNET Technologies, Inc.
   7  *
   8  * Redistribution and use in source and binary forms, with or without
   9  * modification, are permitted provided that the following conditions
  10  * are met:
  11  * 1. Redistributions of source code must retain the above copyright
  12  *    notice, this list of conditions and the following disclaimer.
  13  * 2. Redistributions in binary form must reproduce the above copyright
  14  *    notice, this list of conditions and the following disclaimer in the
  15  *    documentation and/or other materials provided with the distribution.
  16  * 3. Neither the name of the University nor the names of its contributors
  17  *    may be used to endorse or promote products derived from this software
  18  *    without specific prior written permission.
  19  *
  20  * THIS SOFTWARE IS PROVIDED BY THE REGENTS AND CONTRIBUTORS ``AS IS'' AND
  21  * ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE
  22  * IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE
  23  * ARE DISCLAIMED.  IN NO EVENT SHALL THE REGENTS OR CONTRIBUTORS BE LIABLE
  24  * FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL
  25  * DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS
  26  * OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION)
  27  * HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT
  28  * LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY
  29  * OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF
  30  * SUCH DAMAGE.
  31  */
  32
  33 #include <machine/asm.h>
  34
  35         /* .asciz "@(#)urem.s   8.1 (Berkeley) 6/4/93" */
  36 RCSID("$NetBSD: urem.S,v 1.3 2011/01/25 04:45:28 matt Exp $")
  37
  38 /*
  39  * Unsigned modulus, PCC flavor.
  40  * urem() takes an ordinary dividend/divisor pair;
  41  * aurem() takes a pointer to a dividend and an ordinary divisor.
  42  */
  43
  44 #define DIVIDEND        4(%ap)
  45 #define DIVISOR         8(%ap)
  46
  47 ASENTRY(__urem,0)
  48         movl    DIVISOR,%r2
  49         jlss    Leasy           # big divisor: settle by comparison
  50         movl    DIVIDEND,%r0
  51         jlss    Lhard           # big dividend: need extended division
  52         divl3   %r2,%r0,%r1     # small divisor and dividend: signed modulus
  53         mull2   %r2,%r1
  54         subl2   %r1,%r0
  55         ret
  56 Lhard:
  57         clrl    %r1
  58         ediv    %r2,%r0,%r1,%r0
  59         ret
  60 Leasy:
  61         subl3   %r2,DIVIDEND,%r0
  62         jcc     Ldifference     # if divisor goes in once, return difference
  63         movl    DIVIDEND,%r0    # if divisor is bigger, return dividend
  64 Ldifference:
  65         ret
  66 END(__urem)
  67
  68 ASENTRY(__aurem,0)
  69         movl    DIVIDEND,%r3
  70         movl    DIVISOR,%r2
  71         jlss    La_easy         # big divisor: settle by comparison
  72         movl    (%r3),%r0
  73         jlss    La_hard         # big dividend: need extended division
  74         divl3   %r2,%r0,%r1     # small divisor and dividend: signed modulus
  75         mull2   %r2,%r1
  76         subl2   %r1,%r0
  77         movl    %r0,(%r3)               # leave the value of the assignment in %r0
  78         ret
  79 La_hard:
  80         clrl    %r1
  81         ediv    %r2,%r0,%r1,%r0
  82         movl    %r0,(%r3)
  83         ret
  84 La_easy:
  85         subl3   %r2,(%r3),%r0
  86         jcs     La_dividend     # if divisor is bigger, leave dividend alone
  87         movl    %r0,(%r3)               # if divisor goes in once, store difference
  88         ret
  89 La_dividend:
  90         movl    (%r3),%r0
  91         ret
  92 END(__aurem)