crypto/external/bsd/heimdal/dist/configure.ac

   1 dnl Process this file with autoconf to produce a configure script.
   2 AC_REVISION(Revision)
   3 AC_PREREQ(2.62)
   4 test -z "$CFLAGS" && CFLAGS="-g"
   5 AC_INIT([Heimdal],[1.5.3],[heimdal-bugs@h5l.org])
   6 AC_CONFIG_SRCDIR([kuser/kinit.c])
   7 AC_CONFIG_HEADERS(include/config.h)
   8 AC_CONFIG_MACRO_DIR([cf])
   9
  10 AM_INIT_AUTOMAKE([foreign 1.10.3])
  11 AM_MAINTAINER_MODE
  12
  13 dnl Checks for programs.
  14 AC_PROG_CC
  15 AM_PROG_CC_C_O
  16 AC_PROG_CPP
  17 AC_PROG_LIBTOOL
  18
  19 AC_PREFIX_DEFAULT(/usr/heimdal)
  20
  21 test "$sysconfdir" = '${prefix}/etc' && sysconfdir='/etc'
  22 test "$localstatedir" = '${prefix}/var' && localstatedir='/var/heimdal'
  23
  24 AC_CANONICAL_HOST
  25 CANONICAL_HOST=$host
  26 AC_SUBST(CANONICAL_HOST)
  27
  28 rk_SYS_LARGEFILE
  29
  30 rk_AIX
  31 rk_IRIX
  32 rk_SUNOS
  33
  34 dnl
  35 dnl this is needed to run the configure tests against glibc
  36 dnl
  37 AC_DEFINE([_GNU_SOURCE], 1,
  38         [Define to enable extensions on glibc-based systems such as Linux.])
  39
  40 AC_OBJEXT
  41 AC_EXEEXT
  42
  43 dnl AC_KRB_PROG_YACC
  44 AC_PROG_YACC
  45 AM_PROG_LEX
  46 dnl AC_PROG_RANLIB
  47 AC_PROG_AWK
  48 AC_KRB_PROG_LN_S
  49
  50 AC_MIPS_ABI
  51 CC="$CC $abi"
  52 libdir="$libdir$abilibdirext"
  53
  54 AC_C___ATTRIBUTE__
  55
  56 LT_PREREQ([2.2])
  57 LT_INIT([shared static win32-dll])
  58
  59 AM_CONDITIONAL(ENABLE_SHARED, test "$enable_shared" = "yes")
  60 rk_VERSIONSCRIPT
  61
  62 dnl
  63 dnl Helper bits for cross compiling
  64 dnl
  65
  66
  67
  68 AM_CONDITIONAL(CROSS_COMPILE, test "${cross_compiling}" = yes)
  69
  70 AC_ARG_WITH(cross-tools,
  71         AS_HELP_STRING([--with-cross-tools=dir], [use cross tools in dir]),
  72         [if test "$withval" = "yes"; then
  73                 AC_MSG_ERROR([Need path to cross tools])
  74         fi
  75         with_cross_tools="${with_cross_tools}/"
  76         ])
  77
  78 if test "${cross_compiling}" != yes ; then
  79
  80    ASN1_COMPILE="\$(top_builddir)/lib/asn1/asn1_compile\$(EXEEXT)"
  81    SLC="\$(top_builddir)/lib/sl/slc"
  82
  83    ASN1_COMPILE_DEP="\$(ASN1_COMPILE)"
  84    SLC_DEP="\$(SLC)"
  85 else
  86    ASN1_COMPILE="${with_cross_tools}asn1_compile"
  87    SLC="${with_cross_tools}slc"
  88
  89    ASN1_COMPILE_DEP=
  90    SLC_DEP=
  91
  92    ac_cv_prog_COMPILE_ET=${with_cross_tools}compile_et
  93
  94 fi
  95
  96 AC_SUBST([ASN1_COMPILE])
  97 AC_SUBST([ASN1_COMPILE_DEP])
  98 AC_SUBST([SLC])
  99 AC_SUBST([SLC_DEP])
 100
 101
 102 dnl ---
 103
 104 AC_DEFINE(HEIM_WEAK_CRYPTO, 1, [Define if you want support for weak crypto])
 105
 106 rk_TEST_PACKAGE(openldap,
 107 [#include <lber.h>
 108 #include <ldap.h>],
 109 [-lldap -llber],,,OPENLDAP)
 110
 111 AC_ARG_ENABLE(hdb-openldap-module,
 112         AS_HELP_STRING([--enable-hdb-openldap-module],
 113                 [if you want support to build openldap hdb as shared object]))
 114 if test "$enable_hdb_openldap_module" = yes -a "$with_openldap" = yes; then
 115     AC_DEFINE(OPENLDAP_MODULE, 1, [Define if you want support for hdb ldap module])
 116 fi
 117 AM_CONDITIONAL(OPENLDAP_MODULE, test "$enable_hdb_openldap_module" = yes -a "$with_openldap" = yes)
 118
 119 dnl
 120 dnl Optional modules, pk-init, digest, kx509
 121 dnl
 122
 123 AC_ARG_ENABLE(pk-init,
 124         AS_HELP_STRING([--disable-pk-init],
 125                 [if you want disable to PK-INIT support]))
 126 if test "$enable_pk_init" != no ;then
 127         AC_DEFINE([PKINIT], 1, [Define to enable PKINIT.])
 128 fi
 129 AM_CONDITIONAL(PKINIT, test "$enable_pk_init" != no)
 130
 131 AC_ARG_ENABLE(digest,
 132         AS_HELP_STRING([--disable-digest],
 133                 [if you want disable to DIGEST support]))
 134 if test "$enable_digest" != no ;then
 135         AC_DEFINE([DIGEST], 1, [Define to enable DIGEST.])
 136 fi
 137
 138 AC_ARG_ENABLE(kx509,
 139         AS_HELP_STRING([--disable-kx509],
 140                 [if you want disable to kx509 support]))
 141 if test "$enable_kx509" != no ;then
 142         AC_DEFINE([KX509], 1, [Define to enable kx509.])
 143 fi
 144
 145 dnl Need to test if pkg-config exists
 146 PKG_PROG_PKG_CONFIG
 147
 148 dnl libcap-ng
 149 AC_ARG_WITH([capng],
 150   AC_HELP_STRING([--with-capng], [use libcap-ng to drop KDC privileges @<:@default=check@:>@]),
 151   [],
 152   [with_capng=check])
 153 if test "$with_capng" != "no"; then
 154   PKG_CHECK_MODULES([CAPNG], [libcap-ng >= 0.4.0],
 155                     [with_capng=yes],[with_capng=no])
 156 fi
 157 if test "$with_capng" = "yes"; then
 158   AC_DEFINE_UNQUOTED([HAVE_CAPNG], 1, [whether capng is available for privilege reduction])
 159 fi
 160 AM_CONDITIONAL([HAVE_CAPNG], [test "$with_capng" != "no"])
 161 AC_SUBST([CAPNG_CFLAGS])
 162 AC_SUBST([CAPNG_LIBS])
 163
 164 dnl Check for sqlite
 165 rk_TEST_PACKAGE(sqlite3,
 166 [#include <sqlite3.h>
 167 #ifndef SQLITE_OPEN_CREATE
 168 #error "old version"
 169 #endif],
 170 [-lsqlite3],,,SQLITE3)
 171
 172 if test "X$with_sqlite3" != Xyes ; then
 173    INCLUDE_sqlite3="-I\$(top_srcdir)/lib/sqlite"
 174    LIB_sqlite3="\$(top_builddir)/lib/sqlite/libheimsqlite.la"
 175 fi
 176 AM_CONDITIONAL(SQLITE3,  test "X$with_sqlite3" = Xyes)
 177
 178 AC_DEFINE(HAVE_SQLITE3, 1, [Define if you want support for sqlite in Heimdal.])
 179
 180 AC_ARG_ENABLE(sqlite-cache,
 181         AS_HELP_STRING([--disable-sqlite-cache],[if you want support for cache in sqlite]))
 182 if test "$enable_sqlite_cache" != no; then
 183     AC_DEFINE(HAVE_SCC, 1, [Define if you want support for cache in sqlite.])
 184 fi
 185 AM_CONDITIONAL(have_scc, test "$enable_sqlite_cache" != no)
 186
 187
 188 dnl check for libintl
 189 rk_TEST_PACKAGE(libintl,
 190 [#include <libintl.h>],
 191 [-lintl],,,LIBINTL)
 192
 193 dnl path where the hdb directory is stored
 194 AC_ARG_WITH([hdbdir],
 195         [AS_HELP_STRING([--with-hdbdir],[Default location for KDC database @<:@default=/var/heimdal@:>@])],
 196         [],
 197         [with_hdbdir=/var/heimdal])
 198 DIR_hdbdir="$with_hdbdir"
 199 AC_SUBST([DIR_hdbdir])
 200
 201
 202 dnl no kerberos4 any more
 203 with_krb4=no
 204 AC_SUBST(INCLUDE_krb4)
 205 AC_SUBST(LIB_krb4)
 206 AM_CONDITIONAL(KRB4, false)
 207
 208 AM_CONDITIONAL(KRB5, true)
 209 AM_CONDITIONAL(do_roken_rename, true)
 210
 211 AC_DEFINE(SUPPORT_INETD, 1, [Enable use of inetd style startup.])dnl
 212
 213
 214 AC_DEFINE(KRB5, 1, [Enable Kerberos 5 support in applications.])dnl
 215 AC_SUBST(LIB_kdb)dnl
 216
 217 KRB_CRYPTO
 218
 219 KRB_PTHREADS
 220
 221 AC_ARG_ENABLE(dce,
 222         AS_HELP_STRING([--enable-dce],[if you want support for DCE/DFS PAG's]))
 223 if test "$enable_dce" = yes; then
 224     AC_DEFINE(DCE, 1, [Define if you want support for DCE/DFS PAG's.])
 225 fi
 226 AM_CONDITIONAL(DCE, test "$enable_dce" = yes)
 227
 228 ## XXX quite horrible:
 229 if test -f /etc/ibmcxx.cfg; then
 230         dpagaix_ldadd=`sed -n '/^xlc_r4/,/^$/p' /etc/ibmcxx.cfg | sed -n -e '/libraries/{;s/^[[^=]]*=\(.*\)/\1/;s/,/ /gp;}'`
 231         dpagaix_cflags=`sed -n '/^xlc_r4/,/^$/p' /etc/ibmcxx.cfg | sed -n -e '/options/{;s/^[[^=]]*=\(.*\)/\1/;s/-q[^,]*//;s/,/ /gp;}'`
 232         dpagaix_ldflags=
 233 else
 234         dpagaix_cflags="-D_THREAD_SAFE -D_AIX_PTHREADS_D7 -D_AIX32_THREADS=1 -D_AES_SOURCE -D_AIX41 -I/usr/include/dce"
 235         dpagaix_ldadd="-L/usr/lib/threads -ldcelibc_r -ldcepthreads -lpthreads_compat lpthreads -lc_r"
 236         dpagaix_ldflags="-Wl,-bI:dfspag.exp"
 237 fi
 238 AC_SUBST(dpagaix_cflags)
 239 AC_SUBST(dpagaix_ldadd)
 240 AC_SUBST(dpagaix_ldflags)
 241
 242 AC_ARG_ENABLE([afs-support],
 243         AS_HELP_STRING([--disable-afs-support],[if you don't want support for AFS]))
 244 if test "$enable_afs_support" = no; then
 245         AC_DEFINE(NO_AFS, 1, [Define if you don't wan't support for AFS.])
 246         NO_AFS="1"
 247 fi
 248 AC_SUBST(NO_AFS)dnl
 249
 250 rk_DB
 251
 252 dnl AC_ROKEN(10,[/usr/heimdal /usr/athena],[lib/roken],[$(top_builddir)/lib/roken/libroken.la],[-I$(top_builddir)/lib/roken -I$(top_srcdir)/lib/roken])
 253
 254 rk_ROKEN(lib/roken)
 255 LIBADD_roken="$LIB_roken"
 256 AC_SUBST(LIBADD_roken)dnl
 257 LIB_roken="\$(top_builddir)/lib/vers/libvers.la $LIB_roken"
 258
 259 rk_OTP
 260
 261 rk_LIBDISPATCH
 262
 263 AC_CHECK_OSFC2
 264
 265 AC_ARG_ENABLE(mmap,
 266         AS_HELP_STRING([--disable-mmap],[disable use of mmap]))
 267 if test "$enable_mmap" = "no"; then
 268         AC_DEFINE(NO_MMAP, 1, [Define if you don't want to use mmap.])
 269 fi
 270
 271 AC_ARG_ENABLE(afs-string-to-key,
 272         AS_HELP_STRING([--disable-afs-string-to-key],
 273         [disable use of weak AFS string-to-key functions]),
 274         [], [enable_afs_string_to_key=yes])
 275
 276 if test "$enable_afs_string_to_key" = "yes"; then
 277         AC_DEFINE(ENABLE_AFS_STRING_TO_KEY, 1, [Define if want to use the weak AFS string to key functions.])
 278 fi
 279
 280
 281 rk_CHECK_MAN
 282
 283 rk_TEST_PACKAGE(readline,
 284 [#include <stdio.h>
 285 #if defined(HAVE_READLINE_READLINE_H)
 286 #include <readline/readline.h>
 287 #elif defined(HAVE_READLINE_H)
 288 #include <readline.h>
 289 #endif
 290 ],-lreadline,,, READLINE,, [readline.h readline/readline.h])
 291
 292 rk_TEST_PACKAGE(libedit,
 293 [#include <stdio.h>
 294 #if defined(HAVE_READLINE_READLINE_H)
 295 #include <readline/readline.h>
 296 #elif defined(HAVE_READLINE_H)
 297 #include <readline.h>
 298 #endif
 299 ],-ledit,,, READLINE,, [readline.h readline/readline.h])
 300
 301 AC_CONFIG_SUBDIRS([lib/libedit])
 302
 303 rk_TEST_PACKAGE(hesiod,[#include <hesiod.h>],-lhesiod,,, HESIOD)
 304
 305 KRB_C_BIGENDIAN
 306 AC_C_INLINE
 307
 308 KRB_CHECK_X
 309
 310 AM_CONDITIONAL(HAVE_X, test "$no_x" != yes)
 311
 312 AC_CHECK_XAU
 313
 314 dnl AM_C_PROTOTYPES
 315
 316 dnl Checks for typedefs, structures, and compiler characteristics.
 317 AC_C_CONST
 318 AC_TYPE_OFF_T
 319 AC_CHECK_TYPE_EXTRA(mode_t, unsigned short, [])
 320 AC_CHECK_TYPE_EXTRA(sig_atomic_t, int, [#include <signal.h>])
 321 AC_HAVE_TYPE([long long])
 322 AC_HEADER_TIME
 323 AC_STRUCT_TM
 324
 325 dnl Checks for header files.
 326 AC_HEADER_STDC
 327
 328 AC_CHECK_HEADERS([\
 329         CommonCrypto/CommonDigest.h             \
 330         CommonCrypto/CommonCryptor.h            \
 331         arpa/ftp.h                              \
 332         arpa/telnet.h                           \
 333         bind/bitypes.h                          \
 334         bsdsetjmp.h                             \
 335         curses.h                                \
 336         dlfcn.h                                 \
 337         execinfo.h                              \
 338         fnmatch.h                               \
 339         inttypes.h                              \
 340         io.h                                    \
 341         libutil.h                               \
 342         limits.h                                \
 343         maillock.h                              \
 344         netgroup.h                              \
 345         netinet/in6_machtypes.h                 \
 346         pthread.h                               \
 347         pty.h                                   \
 348         sac.h                                   \
 349         sgtty.h                                 \
 350         siad.h                                  \
 351         signal.h                                \
 352         strings.h                               \
 353         stropts.h                               \
 354         sys/bitypes.h                           \
 355         sys/category.h                          \
 356         sys/file.h                              \
 357         sys/filio.h                             \
 358         sys/ioccom.h                            \
 359         sys/mman.h                              \
 360         sys/param.h                             \
 361         sys/pty.h                               \
 362         sys/ptyio.h                             \
 363         sys/select.h                            \
 364         sys/socket.h                            \
 365         sys/str_tty.h                           \
 366         sys/stream.h                            \
 367         sys/stropts.h                           \
 368         sys/syscall.h                           \
 369         sys/termio.h                            \
 370         sys/timeb.h                             \
 371         sys/times.h                             \
 372         sys/types.h                             \
 373         sys/un.h                                \
 374         locale.h                                \
 375         termcap.h                               \
 376         termio.h                                \
 377         termios.h                               \
 378         time.h                                  \
 379         tmpdir.h                                \
 380         udb.h                                   \
 381         util.h                                  \
 382         utmp.h                                  \
 383         utmpx.h                                 \
 384 ])
 385
 386 dnl On Solaris 8 there's a compilation warning for term.h because
 387 dnl it doesn't define `bool'.
 388 AC_CHECK_HEADERS(term.h, , , -)
 389
 390 dnl aix have asl.h (A/IX screen library) that we don't want
 391 AC_CHECK_HEADERS(asl.h, , , [
 392 #include <asl.h>
 393 #ifndef ASL_STRING_EMERG
 394 #error ASL_STRING_EMERG missing
 395 #endif])
 396
 397 AC_CHECK_HEADERS(net/if.h, , , [AC_INCLUDES_DEFAULT
 398 #if HAVE_SYS_SOCKET_H
 399 #include <sys/socket.h>
 400 #endif])
 401
 402 AC_CHECK_HEADERS(sys/ptyvar.h, , , [AC_INCLUDES_DEFAULT
 403 #if HAVE_SYS_TTY_H
 404 #include <sys/tty.h>
 405 #endif])
 406
 407 AC_CHECK_HEADERS(sys/strtty.h, , , [AC_INCLUDES_DEFAULT
 408 #if HAVE_TERMIOS_H
 409 #include <termios.h>
 410 #endif
 411 #if HAVE_SYS_STREAM_H
 412 #include <sys/stream.h>
 413 #endif])
 414
 415 AC_CHECK_HEADERS(sys/ucred.h, , , [AC_INCLUDES_DEFAULT
 416 #if HAVE_SYS_TYPES_H
 417 #include <sys/types.h>
 418 #endif
 419 #if HAVE_SYS_PARAM_H
 420 #include <sys/param.h>
 421 #endif])
 422
 423 AC_CHECK_HEADERS(security/pam_modules.h, , , [AC_INCLUDES_DEFAULT
 424 #include <security/pam_appl.h>
 425 ])
 426
 427 dnl export symbols
 428 rk_WIN32_EXPORT(BUILD_KRB5_LIB, KRB5_LIB)
 429 rk_WIN32_EXPORT(BUILD_ROKEN_LIB, ROKEN_LIB)
 430 rk_WIN32_EXPORT(BUILD_GSSAPI_LIB, GSSAPI_LIB)
 431
 432 dnl Checks for libraries.
 433
 434 AC_FIND_FUNC_NO_LIBS(logwtmp, util,[
 435 #ifdef HAVE_UTIL_H
 436 #include <util.h>
 437 #endif
 438 ],[0,0,0])
 439 AC_FIND_FUNC_NO_LIBS(logout, util,[
 440 #ifdef HAVE_UTIL_H
 441 #include <util.h>
 442 #endif
 443 ],[0])
 444 AC_FIND_FUNC_NO_LIBS(openpty, util,[
 445 #ifdef HAVE_UTIL_H
 446 #include <util.h>
 447 #endif
 448 ],[0,0,0,0,0])
 449
 450 AC_FIND_FUNC_NO_LIBS(tgetent, termcap ncurses curses,[
 451 #ifdef HAVE_TERMCAP_H
 452 #include <termcap.h>
 453 #endif
 454 #ifdef HAVE_CURSES_H
 455 #include <curses.h>
 456 #endif
 457 ],[0,0])
 458
 459 dnl Checks for library functions.
 460
 461 AC_CHECK_FUNCS([                                \
 462         _getpty                                 \
 463         _scrsize                                \
 464         arc4random                              \
 465         backtrace                               \
 466         fcntl                                   \
 467         getpeereid                              \
 468         getpeerucred                            \
 469         grantpt                                 \
 470         mktime                                  \
 471         ptsname                                 \
 472         rand                                    \
 473         revoke                                  \
 474         select                                  \
 475         setitimer                               \
 476         setpcred                                \
 477         setpgid                                 \
 478         setproctitle                            \
 479         setregid                                \
 480         setresgid                               \
 481         setresuid                               \
 482         setreuid                                \
 483         setsid                                  \
 484         setutent                                \
 485         sigaction                               \
 486         strstr                                  \
 487         ttyname                                 \
 488         ttyslot                                 \
 489         umask                                   \
 490         unlockpt                                \
 491         vhangup                                 \
 492         yp_get_default_domain                   \
 493 ])
 494
 495 AC_MSG_CHECKING([checking for __sync_add_and_fetch])
 496 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <sys/types.h>]],
 497         [[unsigned int foo, bar; bar = __sync_add_and_fetch(&foo, 1);]])],
 498         [ac_rk_have___sync_add_and_fetch=yes], [ac_rk_have___sync_add_and_fetch=no])
 499 if test "$ac_rk_have___sync_add_and_fetch" = "yes" ; then
 500         AC_DEFINE_UNQUOTED(HAVE___SYNC_ADD_AND_FETCH, 1, [have __sync_add_and_fetch])
 501 fi
 502 AC_MSG_RESULT($ac_rk_have___sync_add_and_fetch)
 503
 504 AC_FUNC_MMAP
 505
 506 KRB_CAPABILITIES
 507
 508 AC_CHECK_GETPWNAM_R_POSIX
 509
 510 dnl detect doors on solaris
 511 if test "$enable_pthread_support" != no; then
 512    saved_LIBS="$LIBS"
 513    LIBS="$LIBS $PTHREADS_LIBS"
 514    AC_FIND_FUNC_NO_LIBS(door_create, door)
 515    LIBS="$saved_LIBS"
 516 fi
 517
 518 AC_ARG_ENABLE(kcm,
 519         AS_HELP_STRING([--enable-kcm],[enable Kerberos Credentials Manager]),
 520 ,[enable_kcm=yes])
 521
 522 if test "$enable_kcm" = yes ; then
 523    if test  "$ac_cv_header_sys_un_h" != yes -a "$ac_cv_funclib_door_create" != yes ; then
 524         enable_kcm=no
 525    fi
 526 fi
 527 if test "$enable_kcm" = yes; then
 528        AC_DEFINE(HAVE_KCM, 1,
 529                [Define if you want to use the Kerberos Credentials Manager.])
 530 fi
 531 AM_CONDITIONAL(KCM, test "$enable_kcm" = yes)
 532
 533
 534
 535 dnl Cray stuff
 536 AC_CHECK_FUNCS(getudbnam setlim)
 537
 538 dnl AC_KRB_FUNC_GETCWD_BROKEN
 539
 540 dnl
 541 dnl Check for fields in struct utmp
 542 dnl
 543
 544 AC_HAVE_STRUCT_FIELD(struct utmp, ut_addr, [#include <utmp.h>])
 545 AC_HAVE_STRUCT_FIELD(struct utmp, ut_host, [#include <utmp.h>])
 546 AC_HAVE_STRUCT_FIELD(struct utmp, ut_id, [#include <utmp.h>])
 547 AC_HAVE_STRUCT_FIELD(struct utmp, ut_pid, [#include <utmp.h>])
 548 AC_HAVE_STRUCT_FIELD(struct utmp, ut_type, [#include <utmp.h>])
 549 AC_HAVE_STRUCT_FIELD(struct utmp, ut_user, [#include <utmp.h>])
 550 AC_HAVE_STRUCT_FIELD(struct utmpx, ut_host, [#include <utmpx.h>])
 551 AC_HAVE_STRUCT_FIELD(struct utmpx, ut_id, [#include <utmpx.h>])
 552 AC_HAVE_STRUCT_FIELD(struct utmpx, ut_line, [#include <utmpx.h>])
 553 AC_HAVE_STRUCT_FIELD(struct utmpx, ut_pid, [#include <utmpx.h>])
 554 AC_HAVE_STRUCT_FIELD(struct utmpx, ut_tv, [#include <utmpx.h>])
 555 AC_HAVE_STRUCT_FIELD(struct utmpx, ut_type, [#include <utmpx.h>])
 556 AC_HAVE_STRUCT_FIELD(struct utmpx, ut_user, [#include <utmpx.h>])
 557 AC_HAVE_STRUCT_FIELD(struct utmpx, ut_exit, [#include <utmpx.h>])
 558 AC_HAVE_STRUCT_FIELD(struct utmpx, ut_syslen, [#include <utmpx.h>])
 559
 560 AC_CHECK_TYPES([int8_t, int16_t, int32_t, int64_t,
 561         u_int8_t, u_int16_t, u_int32_t, u_int64_t,
 562         uint8_t, uint16_t, uint32_t, uint64_t],,,[
 563 #ifdef HAVE_INTTYPES_H
 564 #include <inttypes.h>
 565 #endif
 566 #ifdef HAVE_SYS_TYPES_H
 567 #include <sys/types.h>
 568 #endif
 569 #ifdef HAVE_SYS_BITYPES_H
 570 #include <sys/bitypes.h>
 571 #endif
 572 #ifdef HAVE_BIND_BITYPES_H
 573 #include <bind/bitypes.h>
 574 #endif
 575 #ifdef HAVE_NETINET_IN6_MACHTYPES_H
 576 #include <netinet/in6_machtypes.h>
 577 #endif
 578 ])
 579
 580 rk_FRAMEWORK_SECURITY
 581
 582 KRB_READLINE
 583
 584 rk_TELNET
 585
 586 dnl Some operating systems already have com_err and compile_et
 587 CHECK_COMPILE_ET
 588
 589 rk_AUTH_MODULES([sia afskauthlib])
 590
 591 rk_DESTDIRS
 592
 593 rk_WFLAGS([-Wall -Wmissing-prototypes -Wpointer-arith -Wbad-function-cast -Wmissing-declarations -Wnested-externs])
 594
 595
 596 AH_BOTTOM([#ifdef __APPLE__
 597 #include <AvailabilityMacros.h>
 598 #endif])
 599
 600 AH_BOTTOM([#ifdef ROKEN_RENAME
 601 #include "roken_rename.h"
 602 #endif])
 603
 604 AC_ARG_ENABLE(heimdal-documentation,
 605         AS_HELP_STRING([--disable-heimdal-documentation],
 606                 [if you want disable to heimdal documentation]))
 607 AM_CONDITIONAL(HEIMDAL_DOCUMENTATION, test "$enable_heimdal_documentation" != no)
 608
 609 AC_CONFIG_FILES(Makefile                \
 610         etc/Makefile                    \
 611         include/Makefile                \
 612         include/gssapi/Makefile         \
 613         include/hcrypto/Makefile        \
 614         include/kadm5/Makefile          \
 615         lib/Makefile                    \
 616         base/Makefile                   \
 617         lib/asn1/Makefile               \
 618         lib/com_err/Makefile            \
 619         lib/hcrypto/Makefile            \
 620         lib/hx509/Makefile              \
 621         lib/gssapi/Makefile             \
 622         lib/ntlm/Makefile               \
 623         lib/hdb/Makefile                \
 624         lib/ipc/Makefile                \
 625         lib/kadm5/Makefile              \
 626         lib/kafs/Makefile               \
 627         lib/kdfs/Makefile               \
 628         lib/krb5/Makefile               \
 629         lib/otp/Makefile                \
 630         lib/roken/Makefile              \
 631         lib/sl/Makefile                 \
 632         lib/sqlite/Makefile             \
 633         lib/vers/Makefile               \
 634         lib/wind/Makefile               \
 635         po/Makefile                     \
 636         kuser/Makefile                  \
 637         kpasswd/Makefile                \
 638         kadmin/Makefile                 \
 639         admin/Makefile                  \
 640         kcm/Makefile                    \
 641         kdc/Makefile                    \
 642         appl/Makefile                   \
 643         appl/afsutil/Makefile           \
 644         appl/ftp/Makefile               \
 645         appl/ftp/common/Makefile        \
 646         appl/ftp/ftp/Makefile           \
 647         appl/ftp/ftpd/Makefile          \
 648         appl/gssmask/Makefile           \
 649         appl/kx/Makefile                \
 650         appl/login/Makefile             \
 651         appl/otp/Makefile               \
 652         appl/popper/Makefile            \
 653         appl/push/Makefile              \
 654         appl/rsh/Makefile               \
 655         appl/rcp/Makefile               \
 656         appl/su/Makefile                \
 657         appl/xnlock/Makefile            \
 658         appl/telnet/Makefile            \
 659         appl/telnet/libtelnet/Makefile  \
 660         appl/telnet/telnet/Makefile     \
 661         appl/telnet/telnetd/Makefile    \
 662         appl/test/Makefile              \
 663         appl/kf/Makefile                \
 664         appl/dceutils/Makefile          \
 665         tests/Makefile                  \
 666         tests/bin/Makefile              \
 667         tests/can/Makefile              \
 668         tests/db/Makefile               \
 669         tests/kdc/Makefile              \
 670         tests/ldap/Makefile             \
 671         tests/gss/Makefile              \
 672         tests/java/Makefile             \
 673         tests/plugin/Makefile           \
 674         packages/Makefile               \
 675         packages/mac/Makefile           \
 676         doc/Makefile                    \
 677         tools/Makefile                  \
 678 )
 679
 680 AC_OUTPUT
 681
 682 dnl
 683 dnl This is the release version name-number[beta]
 684 dnl
 685
 686 cat > include/newversion.h.in <<EOF
 687 #ifndef VERSION_HIDDEN
 688 #define VERSION_HIDDEN
 689 #endif
 690 VERSION_HIDDEN const char *heimdal_long_version = "@([#])\$Version: $PACKAGE_STRING by @USER@ on @HOST@ ($host) @DATE@ \$";
 691 VERSION_HIDDEN const char *heimdal_version = "AC_PACKAGE_STRING";
 692 EOF
 693
 694 if test -f include/version.h && cmp -s include/newversion.h.in include/version.h.in; then
 695         echo "include/version.h is unchanged"
 696         rm -f include/newversion.h.in
 697 else
 698         echo "creating include/version.h"
 699         User=${USER-${LOGNAME}}
 700         Host=`(hostname || uname -n || echo unknown) 2>/dev/null | sed 1q`
 701         Date=`date`
 702         mv -f include/newversion.h.in include/version.h.in
 703         sed -e "s/@USER@/$User/" -e "s/@HOST@/$Host/" -e "s/@DATE@/$Date/" include/version.h.in > include/version.h
 704 fi