lib/libc/arch/i386/gen/swapcontext.S

   1 /*      $NetBSD: swapcontext.S,v 1.8 2014/05/23 02:34:19 uebayasi Exp $ */
   2
   3 /*-
   4  * Copyright (c) 1999 The NetBSD Foundation, Inc.
   5  * All rights reserved.
   6  *
   7  * This code is derived from software contributed to The NetBSD Foundation
   8  * by Klaus Klein.
   9  *
  10  * Redistribution and use in source and binary forms, with or without
  11  * modification, are permitted provided that the following conditions
  12  * are met:
  13  * 1. Redistributions of source code must retain the above copyright
  14  *    notice, this list of conditions and the following disclaimer.
  15  * 2. Redistributions in binary form must reproduce the above copyright
  16  *    notice, this list of conditions and the following disclaimer in the
  17  *    documentation and/or other materials provided with the distribution.
  18  *
  19  * THIS SOFTWARE IS PROVIDED BY THE NETBSD FOUNDATION, INC. AND CONTRIBUTORS
  20  * ``AS IS'' AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED
  21  * TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR
  22  * PURPOSE ARE DISCLAIMED.  IN NO EVENT SHALL THE FOUNDATION OR CONTRIBUTORS
  23  * BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR
  24  * CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF
  25  * SUBSTITUTE GOODS OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS
  26  * INTERRUPTION) HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN
  27  * CONTRACT, STRICT LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE)
  28  * ARISING IN ANY WAY OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE
  29  * POSSIBILITY OF SUCH DAMAGE.
  30  */
  31
  32 #include <machine/asm.h>
  33 #if defined(LIBC_SCCS) && !defined(lint)
  34         RCSID("$NetBSD: swapcontext.S,v 1.8 2014/05/23 02:34:19 uebayasi Exp $")
  35 #endif /* LIBC_SCCS && !lint */
  36
  37 ENTRY(swapcontext)
  38         movl    4(%esp),%ecx
  39         PIC_PROLOGUE
  40         pushl   %ecx                    /* push oucp */
  41 #ifdef __PIC__
  42         call    PIC_PLT(_C_LABEL(_getcontext))
  43 #else
  44         call    _C_LABEL(_getcontext)
  45 #endif
  46         addl    $4,%esp                 /* pop oucp */
  47         PIC_EPILOGUE
  48         testl   %eax,%eax
  49         jnz     2f
  50         movl    4(%esp),%ecx
  51         movl    0(%esp),%edx
  52         movl    %edx,(36 + 14 * 4)(%ecx)        /*  Adjust saved %eip ... */
  53 #ifdef __PIC__
  54         movl    %ebx,(36 +  8 * 4)(%ecx)        /* ... clobbered PIC reg ... */
  55 #endif
  56         leal    4(%esp),%edx
  57         movl    %edx,(36 + 17 * 4)(%ecx)        /* ... and %esp. */
  58         /* Note: oucp->%eax has been cleared by getcontext(). */
  59         movl    8(%esp),%ecx
  60         PIC_PROLOGUE
  61         pushl   %ecx                    /* push ucp */
  62 #ifdef __PIC__
  63         call    PIC_PLT(_C_LABEL(setcontext))
  64 #else
  65         call    _C_LABEL(setcontext)
  66 #endif
  67         addl    $4,%esp                 /* pop ucp */
  68         PIC_EPILOGUE
  69         /* No need to error-check: setcontext() must have failed. */
  70 2:      ret
  71 END(swapcontext)