lib/libc/arch/mips/gen/_setjmp.S

   1 /*      $NetBSD: _setjmp.S,v 1.24 2012/07/08 00:59:34 matt Exp $        */
   2
   3 /*-
   4  * Copyright (c) 1991, 1993
   5  *      The Regents of the University of California.  All rights reserved.
   6  *
   7  * This code is derived from software contributed to Berkeley by
   8  * Ralph Campbell.
   9  *
  10  * Redistribution and use in source and binary forms, with or without
  11  * modification, are permitted provided that the following conditions
  12  * are met:
  13  * 1. Redistributions of source code must retain the above copyright
  14  *    notice, this list of conditions and the following disclaimer.
  15  * 2. Redistributions in binary form must reproduce the above copyright
  16  *    notice, this list of conditions and the following disclaimer in the
  17  *    documentation and/or other materials provided with the distribution.
  18  * 3. Neither the name of the University nor the names of its contributors
  19  *    may be used to endorse or promote products derived from this software
  20  *    without specific prior written permission.
  21  *
  22  * THIS SOFTWARE IS PROVIDED BY THE REGENTS AND CONTRIBUTORS ``AS IS'' AND
  23  * ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE
  24  * IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE
  25  * ARE DISCLAIMED.  IN NO EVENT SHALL THE REGENTS OR CONTRIBUTORS BE LIABLE
  26  * FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL
  27  * DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS
  28  * OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION)
  29  * HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT
  30  * LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY
  31  * OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF
  32  * SUCH DAMAGE.
  33  */
  34
  35 #include <machine/cdefs.h>
  36 #include <mips/regnum.h>
  37 #include <mips/asm.h>
  38 #include <machine/setjmp.h>
  39 #include <machine/signal.h>             /* XXX */
  40
  41 #include "assym.h"
  42
  43 #include "SYS.h"
  44
  45 #if defined(LIBC_SCCS) && !defined(lint)
  46 #if 0
  47         RCSID("from: @(#)_setjmp.s      8.1 (Berkeley) 6/4/93")
  48 #else
  49         RCSID("$NetBSD: _setjmp.S,v 1.24 2012/07/08 00:59:34 matt Exp $")
  50 #endif
  51 #endif /* LIBC_SCCS and not lint */
  52
  53 /*
  54  * C library -- _setjmp, _longjmp
  55  *
  56  *      _longjmp(a,v)
  57  * will generate a "return(v)" from
  58  * the last call to
  59  *      _setjmp(a)
  60  * by restoring registers from the stack,
  61  * The previous signal state is NOT restored.
  62  */
  63
  64         .set    noreorder
  65
  66 LEAF(_setjmp)
  67         REG_PROLOGUE
  68         REG_LI  v0, 0xACEDBADE                  # sigcontext magic number
  69         REG_S   ra, _OFFSETOF_SC_PC(a0)         # sc_pc = return address
  70         REG_S   v0, _OFFSETOF_SC_REGS(a0)       #   saved in sc_regs[0]
  71         REG_S   s0, _OFFSETOF_SC_REGS_S0(a0)
  72         REG_S   s1, _OFFSETOF_SC_REGS_S1(a0)
  73         REG_S   s2, _OFFSETOF_SC_REGS_S2(a0)
  74         REG_S   s3, _OFFSETOF_SC_REGS_S3(a0)
  75         REG_S   s4, _OFFSETOF_SC_REGS_S4(a0)
  76         REG_S   s5, _OFFSETOF_SC_REGS_S5(a0)
  77         REG_S   s6, _OFFSETOF_SC_REGS_S6(a0)
  78         REG_S   s7, _OFFSETOF_SC_REGS_S7(a0)
  79         REG_S   sp, _OFFSETOF_SC_REGS_SP(a0)
  80         REG_S   s8, _OFFSETOF_SC_REGS_S8(a0)
  81 #if defined(__mips_n32) || defined(__mips_n64)
  82         REG_S   gp, _OFFSETOF_SC_REGS_GP(a0)    # newabi gp is callee-saved
  83 #endif
  84         /*
  85          * In N32, FP registers F20, F22, F24, F26, F28, F30 are callee-saved.
  86          * In N64, FP registers F23 .. F31 are callee-saved.
  87          * In O32, FP registers F20 .. F23 are callee-saved.
  88          */
  89 #ifndef SOFTFLOAT_FOR_GCC
  90         cfc1    v0, $31                         # too bad cant check if FP used
  91 #if defined(__mips_n64) || defined(__mips_n32)
  92         FP_S    $f30, _OFFSETOF_SC_FPREGS_F30(a0)
  93         FP_S    $f28, _OFFSETOF_SC_FPREGS_F28(a0)
  94         FP_S    $f26, _OFFSETOF_SC_FPREGS_F26(a0)
  95         FP_S    $f24, _OFFSETOF_SC_FPREGS_F24(a0)
  96 #endif
  97 #if defined(__mips_n32) || defined(__mips_o32) || defined(__mips_o64)
  98         FP_S    $f22, _OFFSETOF_SC_FPREGS_F22(a0)
  99         FP_S    $f20, _OFFSETOF_SC_FPREGS_F20(a0)
 100 #endif
 101 #if defined(__mips_o32) || defined(__mips_o64)
 102         FP_S    $f21, _OFFSETOF_SC_FPREGS_F21(a0)
 103         FP_S    $f23, _OFFSETOF_SC_FPREGS_F23(a0)
 104 #endif
 105 #if defined(__mips_n64)
 106         FP_S    $f25, _OFFSETOF_SC_FPREGS_F25(a0)
 107         FP_S    $f27, _OFFSETOF_SC_FPREGS_F27(a0)
 108         FP_S    $f29, _OFFSETOF_SC_FPREGS_F29(a0)
 109         FP_S    $f31, _OFFSETOF_SC_FPREGS_F31(a0)
 110 #endif
 111         INT_S   v0, _OFFSETOF_SC_FPREGS_FCSR(a0)
 112 #endif  /* SOFTFLOAT_FOR_GCC */
 113         REG_EPILOGUE
 114
 115         j       ra
 116          move   v0, zero
 117 END(_setjmp)
 118
 119 LEAF(_longjmp)
 120         PIC_PROLOGUE(_longjmp)
 121         PTR_SUBU        sp, sp, CALLFRAME_SIZ
 122         SAVE_GP(CALLFRAME_GP)
 123
 124         REG_PROLOGUE
 125         REG_L           v0, _OFFSETOF_SC_REGS(a0)       # get magic number
 126         REG_L           ra, _OFFSETOF_SC_PC(a0)
 127         REG_LI          t0, 0xACEDBADE
 128         bne             v0, t0, botch           # jump if error
 129         PTR_ADDU        sp, sp, CALLFRAME_SIZ   # does not matter, sanity
 130         REG_S           a1, _OFFSETOF_SC_REGS_V0(a0)    # save return value
 131         REG_L           s0, _OFFSETOF_SC_REGS_S0(a0)
 132         REG_L           s1, _OFFSETOF_SC_REGS_S1(a0)
 133         REG_L           s2, _OFFSETOF_SC_REGS_S2(a0)
 134         REG_L           s3, _OFFSETOF_SC_REGS_S3(a0)
 135         REG_L           s4, _OFFSETOF_SC_REGS_S4(a0)
 136         REG_L           s5, _OFFSETOF_SC_REGS_S5(a0)
 137         REG_L           s6, _OFFSETOF_SC_REGS_S6(a0)
 138         REG_L           s7, _OFFSETOF_SC_REGS_S7(a0)
 139 #if defined(__mips_n32) || defined(__mips_n64)
 140         REG_L           gp, _OFFSETOF_SC_REGS_GP(a0)
 141 #endif
 142 #ifndef SOFTFLOAT_FOR_GCC
 143         # get fpu status
 144         INT_L           v0, _OFFSETOF_SC_FPREGS_FCSR(a0)
 145 #endif
 146         REG_L           sp, _OFFSETOF_SC_REGS_SP(a0)
 147         REG_L           s8, _OFFSETOF_SC_REGS_S8(a0)
 148 #ifndef SOFTFLOAT_FOR_GCC
 149         ctc1            v0, $31
 150         /*
 151          * In N32, FP registers F20, F22, F24, F26, F28, F30 are callee-saved.
 152          * In N64, FP registers F23 .. F31 are callee-saved.
 153          * In O32, FP registers F20 .. F23 are callee-saved.
 154          */
 155 #if defined(__mips_n64) || defined(__mips_n32)
 156         FP_L    $f30, _OFFSETOF_SC_FPREGS_F30(a0)
 157         FP_L    $f28, _OFFSETOF_SC_FPREGS_F28(a0)
 158         FP_L    $f26, _OFFSETOF_SC_FPREGS_F26(a0)
 159         FP_L    $f24, _OFFSETOF_SC_FPREGS_F24(a0)
 160 #endif
 161 #if defined(__mips_n32) || defined(__mips_o32) || defined(__mips_o64)
 162         FP_L    $f22, _OFFSETOF_SC_FPREGS_F22(a0)
 163         FP_L    $f20, _OFFSETOF_SC_FPREGS_F20(a0)
 164 #endif
 165 #if defined(__mips_o32) || defined(__mips_o64)
 166         FP_L    $f21, _OFFSETOF_SC_FPREGS_F21(a0)
 167         FP_L    $f23, _OFFSETOF_SC_FPREGS_F23(a0)
 168 #endif
 169 #if defined(__mips_n64)
 170         FP_L    $f25, _OFFSETOF_SC_FPREGS_F25(a0)
 171         FP_L    $f27, _OFFSETOF_SC_FPREGS_F27(a0)
 172         FP_L    $f29, _OFFSETOF_SC_FPREGS_F29(a0)
 173         FP_L    $f31, _OFFSETOF_SC_FPREGS_F31(a0)
 174 #endif
 175 #endif  /* SOFTFLOAT_FOR_GCC */
 176
 177         REG_EPILOGUE
 178         j       ra
 179          move   v0, a1                  # get return value in 1st arg
 180
 181 botch:
 182         /*
 183          * We know we aren't returning so we don't care about restoring
 184          * our caller's GP.
 185          */
 186         jal     _C_LABEL(longjmperror)
 187          nop
 188
 189         PIC_TAILCALL(abort)
 190          nop
 191 END(_longjmp)