lib/libc/arch/powerpc/gen/__setjmp14.S

   1 /*      $NetBSD: __setjmp14.S,v 1.5 2011/01/15 07:31:12 matt Exp $      */
   2
   3 #include "SYS.h"
   4 #include "assym.h"
   5
   6 #if defined(LIBC_SCCS)
   7 __RCSID("$NetBSD: __setjmp14.S,v 1.5 2011/01/15 07:31:12 matt Exp $")
   8 #endif
   9
  10 /*
  11  * C library -- _setjmp, _longjmp
  12  *
  13  *      longjmp(a,v)
  14  * will generate a "return(v?v:1)" from the last call to
  15  *      setjmp(a)
  16  * by restoring registers from the stack.
  17  * The previous signal state is restored.
  18  */
  19
  20 ENTRY(__setjmp14)
  21         mr      %r6,%r3
  22         li      %r3,SIG_BLOCK
  23         li      %r4,0
  24         addi    %r5,%r6,4*(1+24)        # &sigmask
  25         _DOSYSCALL(__sigprocmask14)     # assume no error       XXX
  26         mflr    %r11
  27         mfcr    %r12
  28         mr      %r10,%r1
  29         mr      %r9,%r2
  30         stmw    %r8,4(%r6)              # save r8-r31
  31         li      %r3,0
  32         blr
  33 END(__setjmp14)
  34
  35 ENTRY(__longjmp14)
  36         lmw     %r8,4(%r3)              # load r8-r31
  37         mr      %r6,%r4
  38         mtlr    %r11
  39         mtcr    %r12
  40         mr      %r2,%r9
  41         mr      %r1,%r10
  42         addi    %r4,%r3,4*(1+24)        # &sigmask
  43         li      %r3,SIG_SETMASK
  44         li      %r5,0
  45         _DOSYSCALL(__sigprocmask14)     # assume no error       XXX
  46         or.     %r3,%r6,%r6
  47         bnelr
  48         li      %r3,1
  49         blr
  50 END(__longjmp14)