lib/libc/arch/powerpc/gen/_setjmp.S

   1 /*      $NetBSD: _setjmp.S,v 1.3 2011/01/15 07:31:12 matt Exp $ */
   2
   3 #include <machine/asm.h>
   4
   5 #if defined(LIBC_SCCS)
   6 __RCSID("$NetBSD: _setjmp.S,v 1.3 2011/01/15 07:31:12 matt Exp $")
   7 #endif
   8
   9 /*
  10  * C library -- _setjmp, _longjmp
  11  *
  12  *      _longjmp(a,v)
  13  * will generate a "return(v?v:1)" from the last call to
  14  *      _setjmp(a)
  15  * by restoring registers from the stack.
  16  * The previous signal state is NOT restored.
  17  */
  18
  19 ENTRY(_setjmp)
  20         mflr    %r11                    /* save return address */
  21         mfcr    %r12                    /* save condition register */
  22         mr      %r10,%r1                /* save stack pointer */
  23         mr      %r9,%r2                 /* save GPR2 (not needed) */
  24         stmw    %r9,8(%r3)              /* save r9..r31 */
  25         li      %r3,0                   /* indicate success */
  26         blr                             /* return */
  27 END(_setjmp)
  28
  29 ENTRY(_longjmp)
  30         lmw     %r9,8(%r3)              /* save r9..r31 */
  31         mtlr    %r11                    /* restore LR */
  32         mtcr    %r12                    /* restore CR */
  33         mr      %r2,%r9                 /* restore GPR2 (not needed) */
  34         mr      %r1,%r10                /* restore stack */
  35         or.     %r3,%r4,%r4             /* get return value */
  36         bnelr                           /* return if not 0 */
  37         li      %r3,1                   /* what's the point? */
  38         blr                             /* return */
  39 END(_longjmp)