lib/libc/arch/sh3/gen/sigsetjmp.S

   1 /*      $NetBSD: sigsetjmp.S,v 1.9 2006/01/05 19:21:37 uwe Exp $        */
   2
   3 /*-
   4  * Copyright (c) 1990 The Regents of the University of California.
   5  * All rights reserved.
   6  *
   7  * This code is derived from software contributed to Berkeley by
   8  * William Jolitz.
   9  *
  10  * Redistribution and use in source and binary forms, with or without
  11  * modification, are permitted provided that the following conditions
  12  * are met:
  13  * 1. Redistributions of source code must retain the above copyright
  14  *    notice, this list of conditions and the following disclaimer.
  15  * 2. Redistributions in binary form must reproduce the above copyright
  16  *    notice, this list of conditions and the following disclaimer in the
  17  *    documentation and/or other materials provided with the distribution.
  18  * 3. Neither the name of the University nor the names of its contributors
  19  *    may be used to endorse or promote products derived from this software
  20  *    without specific prior written permission.
  21  *
  22  * THIS SOFTWARE IS PROVIDED BY THE REGENTS AND CONTRIBUTORS ``AS IS'' AND
  23  * ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE
  24  * IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE
  25  * ARE DISCLAIMED.  IN NO EVENT SHALL THE REGENTS OR CONTRIBUTORS BE LIABLE
  26  * FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL
  27  * DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS
  28  * OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION)
  29  * HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT
  30  * LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY
  31  * OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF
  32  * SUCH DAMAGE.
  33  *
  34  *      from: @(#)setjmp.s      5.1 (Berkeley) 4/23/90
  35  */
  36
  37 #include <machine/asm.h>
  38 #include <machine/setjmp.h>
  39
  40 #if defined(LIBC_SCCS)
  41         RCSID("$NetBSD: sigsetjmp.S,v 1.9 2006/01/05 19:21:37 uwe Exp $")
  42 #endif
  43
  44 ENTRY(__sigsetjmp14)
  45         tst     r5, r5
  46         bt      2f                      /* if (savemask == 0) */
  47
  48         /* identical to longjmp except that _JB_HAS_MASK is in the argument */
  49         PIC_PROLOGUE(.L_got_1)
  50         sts.l   pr, @-sp
  51         mov.l   r4, @-sp
  52         mov.l   r5, @-sp
  53
  54         mov.l   .L___sigprocmask14_1, r0
  55         mov     r4, r6
  56         mov     #1, r4                  /* how = SIG_BLOCK */
  57         mov     #0, r5                  /* new = NULL */
  58 1:      CALL    r0
  59          add    #(_JB_SIGMASK * 4), r6  /* old = &sigmask */
  60
  61         mov.l   @sp+, r5
  62         mov.l   @sp+, r4
  63         lds.l   @sp+, pr
  64         PIC_EPILOGUE
  65
  66 2:      /* identical to _setjmp except that _JB_HAS_MASK is in the argument */
  67         add     #((_JB_HAS_MASK + 1) * 4), r4
  68         mov.l   r5, @-r4                /* has signal mask? */
  69         mov.l   r15, @-r4
  70         mov.l   r14, @-r4
  71         mov.l   r13, @-r4
  72         mov.l   r12, @-r4
  73         mov.l   r11, @-r4
  74         mov.l   r10, @-r4
  75         mov.l   r9, @-r4
  76         mov.l   r8, @-r4
  77         sts.l   pr, @-r4
  78         rts
  79          xor    r0, r0
  80
  81         .align  2
  82 .L_got_1:               PIC_GOT_DATUM
  83 .L___sigprocmask14_1:   CALL_DATUM(_C_LABEL(__sigprocmask14), 1b)
  84         SET_ENTRY_SIZE(__sigsetjmp14)
  85
  86
  87 ENTRY(__siglongjmp14)
  88         mov.l   @(_JB_HAS_MASK * 4, r4), r0
  89         tst     r0, r0
  90         bt      2f                      /* if no mask */
  91
  92         /* identical to longjmp */
  93         /* we won't return here, so we don't need to save pr and r12 */
  94         PIC_PROLOGUE_NOSAVE(.L_got_2)
  95         mov.l   r5, @-sp
  96         mov.l   r4, @-sp
  97
  98         mov.l   .L___sigprocmask14_2, r0
  99         mov     r4, r5
 100         mov     #3, r4                  /* how = SIG_SETMASK */
 101         add     #(_JB_SIGMASK * 4), r5  /* new = &sigmask */
 102 1:      CALL    r0
 103          mov    #0, r6                  /* old = NULL */
 104
 105         mov.l   @sp+, r4
 106         mov.l   @sp+, r5
 107
 108 2:      /* identical to _longjmp */
 109         lds.l   @r4+, pr
 110         mov.l   @r4+, r8
 111         mov.l   @r4+, r9
 112         mov.l   @r4+, r10
 113         mov.l   @r4+, r11
 114         mov.l   @r4+, r12
 115         mov.l   @r4+, r13
 116         mov.l   @r4+, r14
 117         mov.l   @r4+, r15
 118
 119         mov     r5, r0
 120         tst     r0, r0  /* make sure return value is non-zero */
 121         bf      .L0
 122         add     #1, r0
 123 .L0:
 124         rts
 125          nop
 126
 127         .align  2
 128 .L_got_2:               PIC_GOT_DATUM
 129 .L___sigprocmask14_2:   CALL_DATUM(_C_LABEL(__sigprocmask14), 1b)
 130         SET_ENTRY_SIZE(__siglongjmp14)