lib/libc/arch/x86_64/gen/__setjmp14.S

   1 /*      $NetBSD: __setjmp14.S,v 1.3 2014/05/22 15:01:56 uebayasi Exp $  */
   2
   3 /*
   4  * Copyright (c) 2001 Wasabi Systems, Inc.
   5  * All rights reserved.
   6  *
   7  * Written by Frank van der Linden for Wasabi Systems, Inc.
   8  *
   9  * Redistribution and use in source and binary forms, with or without
  10  * modification, are permitted provided that the following conditions
  11  * are met:
  12  * 1. Redistributions of source code must retain the above copyright
  13  *    notice, this list of conditions and the following disclaimer.
  14  * 2. Redistributions in binary form must reproduce the above copyright
  15  *    notice, this list of conditions and the following disclaimer in the
  16  *    documentation and/or other materials provided with the distribution.
  17  * 3. All advertising materials mentioning features or use of this software
  18  *    must display the following acknowledgement:
  19  *      This product includes software developed for the NetBSD Project by
  20  *      Wasabi Systems, Inc.
  21  * 4. The name of Wasabi Systems, Inc. may not be used to endorse
  22  *    or promote products derived from this software without specific prior
  23  *    written permission.
  24  *
  25  * THIS SOFTWARE IS PROVIDED BY WASABI SYSTEMS, INC. ``AS IS'' AND
  26  * ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED
  27  * TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR
  28  * PURPOSE ARE DISCLAIMED.  IN NO EVENT SHALL WASABI SYSTEMS, INC
  29  * BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR
  30  * CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF
  31  * SUBSTITUTE GOODS OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS
  32  * INTERRUPTION) HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN
  33  * CONTRACT, STRICT LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE)
  34  * ARISING IN ANY WAY OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE
  35  * POSSIBILITY OF SUCH DAMAGE.
  36  */
  37
  38
  39 #include <machine/asm.h>
  40 #include <machine/setjmp.h>
  41
  42 #if defined(LIBC_SCCS)
  43         RCSID("$NetBSD: __setjmp14.S,v 1.3 2014/05/22 15:01:56 uebayasi Exp $")
  44 #endif
  45
  46 /*
  47  * C library -- _setjmp, _longjmp
  48  *
  49  *      longjmp(a,v)
  50  * will generate a "return(v)" from the last call to
  51  *      setjmp(a)
  52  * by restoring registers from the stack.
  53  * The previous signal state is restored.
  54  */
  55
  56 ENTRY(__setjmp14)
  57         movq    (%rsp),%r11
  58         movq    %rbx,(_JB_RBX * 8)(%rdi)
  59         movq    %rbp,(_JB_RBP * 8)(%rdi)
  60         movq    %r12,(_JB_R12 * 8)(%rdi)
  61         movq    %r13,(_JB_R13 * 8)(%rdi)
  62         movq    %r14,(_JB_R14 * 8)(%rdi)
  63         movq    %r15,(_JB_R15 * 8)(%rdi)
  64         movq    %rsp,(_JB_RSP * 8)(%rdi)
  65         movq    %r11,(_JB_PC  * 8)(%rdi)
  66
  67         leaq    (_JB_SIGMASK * 8)(%rdi),%rdx
  68         xorl    %edi,%edi
  69         xorq    %rsi,%rsi
  70
  71 #ifdef __PIC__
  72         call    PIC_PLT(_C_LABEL(__sigprocmask14))
  73 #else
  74         call    _C_LABEL(__sigprocmask14)
  75 #endif
  76 2:      xorl    %eax,%eax
  77         ret
  78 END(__setjmp14)
  79
  80 ENTRY(__longjmp14)
  81         movq    %rdi,%r12
  82         movl    %esi,%r8d
  83
  84         leaq    (_JB_SIGMASK * 8)(%rdi),%rsi
  85         movl    $3,%edi         /* SIG_SETMASK */
  86         xorq    %rdx,%rdx
  87
  88         pushq   %r8
  89 #ifdef __PIC__
  90         call    PIC_PLT(_C_LABEL(__sigprocmask14))
  91 #else
  92         call    _C_LABEL(__sigprocmask14)
  93 #endif
  94         popq    %r8
  95         movq    (_JB_RBX * 8)(%r12),%rbx
  96         movq    (_JB_RBP * 8)(%r12),%rbp
  97         movq    (_JB_R13 * 8)(%r12),%r13
  98         movq    (_JB_R14 * 8)(%r12),%r14
  99         movq    (_JB_R15 * 8)(%r12),%r15
 100         movq    (_JB_RSP * 8)(%r12),%rsp
 101         movq    (_JB_PC  * 8)(%r12),%r11
 102         movq    (_JB_R12 * 8)(%r12),%r12
 103
 104         movl    %r8d,%eax
 105         testl   %eax,%eax
 106         jnz     1f
 107         incl    %eax
 108 1:      movq    %r11,0(%rsp)
 109         ret
 110 END(__longjmp14)