lib/libc/compat/arch/i386/gen/compat_setjmp.S

   1 /*      $NetBSD: compat_setjmp.S,v 1.3 2014/05/23 02:34:33 uebayasi Exp $       */
   2
   3 /*-
   4  * Copyright (c) 1990 The Regents of the University of California.
   5  * All rights reserved.
   6  *
   7  * This code is derived from software contributed to Berkeley by
   8  * William Jolitz.
   9  *
  10  * Redistribution and use in source and binary forms, with or without
  11  * modification, are permitted provided that the following conditions
  12  * are met:
  13  * 1. Redistributions of source code must retain the above copyright
  14  *    notice, this list of conditions and the following disclaimer.
  15  * 2. Redistributions in binary form must reproduce the above copyright
  16  *    notice, this list of conditions and the following disclaimer in the
  17  *    documentation and/or other materials provided with the distribution.
  18  * 3. Neither the name of the University nor the names of its contributors
  19  *    may be used to endorse or promote products derived from this software
  20  *    without specific prior written permission.
  21  *
  22  * THIS SOFTWARE IS PROVIDED BY THE REGENTS AND CONTRIBUTORS ``AS IS'' AND
  23  * ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE
  24  * IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE
  25  * ARE DISCLAIMED.  IN NO EVENT SHALL THE REGENTS OR CONTRIBUTORS BE LIABLE
  26  * FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL
  27  * DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS
  28  * OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION)
  29  * HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT
  30  * LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY
  31  * OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF
  32  * SUCH DAMAGE.
  33  *
  34  *      from: @(#)setjmp.s      5.1 (Berkeley) 4/23/90
  35  */
  36
  37 #include <machine/asm.h>
  38 #if defined(LIBC_SCCS)
  39         RCSID("$NetBSD: compat_setjmp.S,v 1.3 2014/05/23 02:34:33 uebayasi Exp $")
  40 #endif
  41
  42 /*
  43  * C library -- _setjmp, _longjmp
  44  *
  45  *      longjmp(a,v)
  46  * will generate a "return(v)" from the last call to
  47  *      setjmp(a)
  48  * by restoring registers from the stack.
  49  * The previous signal state is restored.
  50  */
  51
  52 ENTRY(setjmp)
  53
  54         PIC_PROLOGUE
  55         pushl   $0
  56 #ifdef __PIC__
  57         call    PIC_PLT(_C_LABEL(sigblock))
  58 #else
  59         call    _C_LABEL(sigblock)
  60 #endif
  61         addl    $4,%esp
  62         PIC_EPILOGUE
  63
  64         movl    4(%esp),%ecx
  65         movl    0(%esp),%edx
  66         movl    %edx, 0(%ecx)
  67         movl    %ebx, 4(%ecx)
  68         movl    %esp, 8(%ecx)
  69         movl    %ebp,12(%ecx)
  70         movl    %esi,16(%ecx)
  71         movl    %edi,20(%ecx)
  72         movl    %eax,24(%ecx)
  73         xorl    %eax,%eax
  74         ret
  75 END(setjmp)
  76
  77 ENTRY(longjmp)
  78         movl    4(%esp),%edx
  79
  80         PIC_PROLOGUE
  81         pushl   24(%edx)
  82 #ifdef __PIC__
  83         call    PIC_PLT(_C_LABEL(sigsetmask))
  84 #else
  85         call    _C_LABEL(sigsetmask)
  86 #endif
  87         addl    $4,%esp
  88         PIC_EPILOGUE
  89
  90         movl    4(%esp),%edx
  91         movl    8(%esp),%eax
  92         movl    0(%edx),%ecx
  93         movl    4(%edx),%ebx
  94         movl    8(%edx),%esp
  95         movl    12(%edx),%ebp
  96         movl    16(%edx),%esi
  97         movl    20(%edx),%edi
  98         testl   %eax,%eax
  99         jnz     1f
 100         incl    %eax
 101 1:      movl    %ecx,0(%esp)
 102         ret
 103 END(longjmp)