lib/libc/compat/arch/m68k/gen/compat_setjmp.S

   1 /*      $NetBSD: compat_setjmp.S,v 1.3 2014/03/04 06:27:00 matt Exp $   */
   2
   3 /*-
   4  * Copyright (c) 1990 The Regents of the University of California.
   5  * All rights reserved.
   6  *
   7  * This code is derived from software contributed to Berkeley by
   8  * the Systems Programming Group of the University of Utah Computer
   9  * Science Department.
  10  *
  11  * Redistribution and use in source and binary forms, with or without
  12  * modification, are permitted provided that the following conditions
  13  * are met:
  14  * 1. Redistributions of source code must retain the above copyright
  15  *    notice, this list of conditions and the following disclaimer.
  16  * 2. Redistributions in binary form must reproduce the above copyright
  17  *    notice, this list of conditions and the following disclaimer in the
  18  *    documentation and/or other materials provided with the distribution.
  19  * 3. Neither the name of the University nor the names of its contributors
  20  *    may be used to endorse or promote products derived from this software
  21  *    without specific prior written permission.
  22  *
  23  * THIS SOFTWARE IS PROVIDED BY THE REGENTS AND CONTRIBUTORS ``AS IS'' AND
  24  * ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE
  25  * IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE
  26  * ARE DISCLAIMED.  IN NO EVENT SHALL THE REGENTS OR CONTRIBUTORS BE LIABLE
  27  * FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL
  28  * DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS
  29  * OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION)
  30  * HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT
  31  * LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY
  32  * OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF
  33  * SUCH DAMAGE.
  34  */
  35
  36 #include <machine/asm.h>
  37
  38 #if defined(LIBC_SCCS) && !defined(lint)
  39 #if 0
  40         RCSID("from: @(#)setjmp.s       5.1 (Berkeley) 5/12/90")
  41 #else
  42         RCSID("$NetBSD: compat_setjmp.S,v 1.3 2014/03/04 06:27:00 matt Exp $")
  43 #endif
  44 #endif /* LIBC_SCCS and not lint */
  45
  46 /*
  47  * C library -- setjmp, longjmp
  48  *
  49  *      longjmp(a,v)
  50  * will generate a "return(v)" from
  51  * the last call to
  52  *      setjmp(a)
  53  * by restoring registers from the stack,
  54  * and a struct sigcontext, see <signal.h>
  55  */
  56
  57 ENTRY(setjmp)
  58         lea     -12(%sp),%sp    /* space for sigstack args/rvals */
  59         clrl    (%sp)           /* don't change it... */
  60         movl    %sp,4(%sp)      /* ...but return the current val */
  61         jbsr    PIC_PLT(_C_LABEL(__sigaltstack14))
  62                                 /* note: flags returned in sp@(8) */
  63         clrl    (%sp)           /* don't change mask, just return */
  64         jbsr    PIC_PLT(_C_LABEL(sigblock)) /*  old value */
  65         movl    8(%sp),%d1      /* old flags value */
  66         andl    #1,%d1          /* extract onstack flag */
  67         lea     12(%sp),%sp
  68         movl    4(%sp),%a0      /* save area pointer */
  69         movl    %d1,(%a0)+      /* save old onstack value */
  70         movl    %d0,(%a0)+      /* save old signal mask */
  71         lea     4(%sp),%a1      /* adjust saved SP since we won't rts */
  72         movl    %a1,(%a0)+      /* save old SP */
  73         movl    %a6,(%a0)+      /* save old FP */
  74         clrl    (%a0)+          /* no AP */
  75         movl    (%sp),(%a0)+    /* save old PC */
  76         clrl    (%a0)+          /* clean PS */
  77         moveml  #0x3CFC,(%a0)   /* save remaining non-scratch regs */
  78         clrl    %d0             /* return 0 */
  79         rts
  80 END(setjmp)
  81
  82 ENTRY(longjmp)
  83         movl    4(%sp),%a0      /* save area pointer */
  84         tstl    8(%a0)          /* ensure non-zero SP */
  85         jeq     botch           /* oops! */
  86         movl    8(%sp),%d0      /* grab return value */
  87         jne     ok              /* non-zero ok */
  88         moveq   #1,%d0          /* else make non-zero */
  89 ok:
  90         moveml  28(%a0),#0x3CFC /* restore non-scratch regs */
  91         movl    %a0,-(%sp)      /* let sigreturn */
  92         trap    #1              /* finish via compat_13_sigreturn13() */
  93
  94 botch:
  95         jbsr    PIC_PLT(_C_LABEL(longjmperror))
  96         stop    #0
  97 END(longjmp)