lib/libc/compat/arch/sh3/gen/compat_setjmp.S

   1 /*      $NetBSD: compat_setjmp.S,v 1.3 2006/01/05 19:21:37 uwe Exp $    */
   2
   3 /*-
   4  * Copyright (c) 1990 The Regents of the University of California.
   5  * All rights reserved.
   6  *
   7  * This code is derived from software contributed to Berkeley by
   8  * William Jolitz.
   9  *
  10  * Redistribution and use in source and binary forms, with or without
  11  * modification, are permitted provided that the following conditions
  12  * are met:
  13  * 1. Redistributions of source code must retain the above copyright
  14  *    notice, this list of conditions and the following disclaimer.
  15  * 2. Redistributions in binary form must reproduce the above copyright
  16  *    notice, this list of conditions and the following disclaimer in the
  17  *    documentation and/or other materials provided with the distribution.
  18  * 3. Neither the name of the University nor the names of its contributors
  19  *    may be used to endorse or promote products derived from this software
  20  *    without specific prior written permission.
  21  *
  22  * THIS SOFTWARE IS PROVIDED BY THE REGENTS AND CONTRIBUTORS ``AS IS'' AND
  23  * ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE
  24  * IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE
  25  * ARE DISCLAIMED.  IN NO EVENT SHALL THE REGENTS OR CONTRIBUTORS BE LIABLE
  26  * FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL
  27  * DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS
  28  * OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION)
  29  * HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT
  30  * LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY
  31  * OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF
  32  * SUCH DAMAGE.
  33  *
  34  *      from: @(#)setjmp.s      5.1 (Berkeley) 4/23/90
  35  */
  36
  37 #include <machine/asm.h>
  38 #include <machine/setjmp.h>
  39
  40 #if defined(LIBC_SCCS)
  41         RCSID("$NetBSD: compat_setjmp.S,v 1.3 2006/01/05 19:21:37 uwe Exp $")
  42 #endif
  43
  44 /*
  45  * C library -- setjmp, longjmp
  46  *
  47  *      longjmp(a,v)
  48  * will generate a "return(v)" from the last call to
  49  *      setjmp(a)
  50  * by restoring registers from the stack.
  51  * The previous signal state is restored.
  52  */
  53
  54 ENTRY(setjmp)
  55         PIC_PROLOGUE(.L_got_1)
  56         sts.l   pr, @-sp
  57         mov.l   r4, @-sp
  58
  59         mov.l   .L_sigblock, r0
  60 1:      CALL    r0                      /* int mask = sigblock(0); */
  61          mov    #0, r4
  62
  63         mov.l   @sp+, r4
  64         lds.l   @sp+, pr
  65         PIC_EPILOGUE
  66
  67         /* identical to _setjmp except that mask is present */
  68         add     #((_JB_SIGMASK + 1) * 4), r4
  69         mov.l   r0, @-r4                /* current mask returned by sigblock */
  70         mov     #1, r0
  71         mov.l   r0, @-r4                /* has signal mask */
  72         mov.l   r15, @-r4
  73         mov.l   r14, @-r4
  74         mov.l   r13, @-r4
  75         mov.l   r12, @-r4
  76         mov.l   r11, @-r4
  77         mov.l   r10, @-r4
  78         mov.l   r9, @-r4
  79         mov.l   r8, @-r4
  80         sts.l   pr, @-r4
  81         rts
  82          xor    r0, r0
  83
  84         .align  2
  85 .L_got_1:       PIC_GOT_DATUM
  86 .L_sigblock:    CALL_DATUM(_C_LABEL(sigblock), 1b)
  87         SET_ENTRY_SIZE(setjmp)
  88
  89
  90 ENTRY(longjmp)
  91         /* we won't return here, so we don't need to save pr and r12 */
  92         PIC_PROLOGUE_NOSAVE(.L_got_2)
  93         mov.l   r5, @-sp
  94         mov.l   r4, @-sp
  95
  96         mov.l   .L_sigsetmask, r0
  97 1:      CALL    r0                      /* sigsetmask(saved mask) */
  98          mov.l  @(_JB_SIGMASK * 4, r4), r4
  99
 100         mov.l   @sp+, r4
 101         mov.l   @sp+, r5
 102
 103         /* identical to _longjmp */
 104         lds.l   @r4+, pr
 105         mov.l   @r4+, r8
 106         mov.l   @r4+, r9
 107         mov.l   @r4+, r10
 108         mov.l   @r4+, r11
 109         mov.l   @r4+, r12
 110         mov.l   @r4+, r13
 111         mov.l   @r4+, r14
 112         mov.l   @r4+, r15
 113
 114         mov     r5, r0
 115         tst     r0, r0  /* make sure return value is non-zero */
 116         bf      .L0
 117         add     #1, r0
 118 .L0:
 119         rts
 120          nop
 121
 122         .align  2
 123 .L_got_2:       PIC_GOT_DATUM
 124 .L_sigsetmask:  CALL_DATUM(_C_LABEL(sigsetmask), 1b)
 125         SET_ENTRY_SIZE(longjmp)