lib/libm/arch/i387/e_exp.S

   1 /*      $NetBSD: e_exp.S,v 1.14 2008/06/23 10:24:13 drochner Exp $      */
   2
   3 /*
   4  * Copyright (c) 1993,94 Winning Strategies, Inc.
   5  * All rights reserved.
   6  *
   7  * Redistribution and use in source and binary forms, with or without
   8  * modification, are permitted provided that the following conditions
   9  * are met:
  10  * 1. Redistributions of source code must retain the above copyright
  11  *    notice, this list of conditions and the following disclaimer.
  12  * 2. Redistributions in binary form must reproduce the above copyright
  13  *    notice, this list of conditions and the following disclaimer in the
  14  *    documentation and/or other materials provided with the distribution.
  15  * 3. All advertising materials mentioning features or use of this software
  16  *    must display the following acknowledgement:
  17  *      This product includes software developed by Winning Strategies, Inc.
  18  * 4. The name of the author may not be used to endorse or promote products
  19  *    derived from this software without specific prior written permission.
  20  *
  21  * THIS SOFTWARE IS PROVIDED BY THE AUTHOR ``AS IS'' AND ANY EXPRESS OR
  22  * IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE IMPLIED WARRANTIES
  23  * OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE ARE DISCLAIMED.
  24  * IN NO EVENT SHALL THE AUTHOR BE LIABLE FOR ANY DIRECT, INDIRECT,
  25  * INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT
  26  * NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE,
  27  * DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY
  28  * THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT
  29  * (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE OF
  30  * THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.
  31  */
  32
  33 /*
  34  * Written by:
  35  *      J.T. Conklin (jtc@wimsey.com), Winning Strategies, Inc.
  36  */
  37
  38 #include <machine/asm.h>
  39
  40 #include "abi.h"
  41
  42 RCSID("$NetBSD: e_exp.S,v 1.14 2008/06/23 10:24:13 drochner Exp $")
  43 #if 0
  44 RCSID("$FreeBSD: src/lib/msun/i387/e_exp.S,v 1.8.2.1 2000/07/10 09:16:28 obrien Exp $")
  45 #endif
  46
  47 /* e^x = 2^(x * log2(e)) */
  48 ENTRY(__ieee754_exp)
  49         XMM_ONE_ARG_DOUBLE_PROLOGUE
  50         /*
  51          * If x is +-Inf, then the subtraction would give Inf-Inf = NaN.
  52          * Avoid this.  Also avoid it if x is NaN for convenience.
  53          */
  54         movl    ARG_DOUBLE_ONE_MSW, %eax
  55         andl    $0x7fffffff, %eax
  56         cmpl    $0x7ff00000, %eax
  57         jae     x_Inf_or_NaN
  58
  59         fldl    ARG_DOUBLE_ONE
  60
  61         /*
  62          * Ensure that the rounding mode is to nearest (to give the smallest
  63          * possible fraction) and that the precision is as high as possible.
  64          * We may as well mask interrupts if we switch the mode.
  65          */
  66 #define CWSTORE_SAV ARG_DOUBLE_ONE_LSW /* XXX overwrites the argument */
  67 #define CWSTORE_TMP ARG_DOUBLE_ONE_MSW
  68         fstcw   CWSTORE_SAV
  69         movl    CWSTORE_SAV, %eax
  70         andl    $0x0f00, %eax
  71         cmpl    $0x0300, %eax           /* RC == 0 && PC == 3? */
  72         je      1f                      /* jump if mode is good */
  73         movl    $0x137f, CWSTORE_TMP
  74         fldcw   CWSTORE_TMP
  75 1:
  76         fldl2e
  77         fmulp                           /* x * log2(e) */
  78         fst     %st(1)
  79         frndint                         /* int(x * log2(e)) */
  80         fst     %st(2)
  81         fsubrp                          /* fract(x * log2(e)) */
  82         f2xm1                           /* 2^(fract(x * log2(e))) - 1 */
  83         fld1
  84         faddp                           /* 2^(fract(x * log2(e))) */
  85         fscale                          /* e^x */
  86         fstp    %st(1)
  87         je      1f
  88         fldcw   CWSTORE_SAV
  89 1:
  90         XMM_DOUBLE_EPILOGUE
  91         ret
  92 x_Inf_or_NaN:
  93         /*
  94          * Return 0 if x is -Inf.  Otherwise just return x, although the
  95          * C version would return (x + x) (Real Indefinite) if x is a NaN.
  96          */
  97         cmpl    $0xfff00000, ARG_DOUBLE_ONE_MSW
  98         jne     x_not_minus_Inf
  99         cmpl    $0, ARG_DOUBLE_ONE_LSW
 100         jne     x_not_minus_Inf
 101         fldz
 102         XMM_DOUBLE_EPILOGUE
 103         ret
 104
 105 x_not_minus_Inf:
 106         fldl    ARG_DOUBLE_ONE
 107         XMM_DOUBLE_EPILOGUE
 108         ret