common/lib/libc/arch/m68k/string/bzero.S

   1 /*      $NetBSD: bzero.S,v 1.2 2008/04/28 20:22:52 martin Exp $ */
   2
   3 /*-
   4  * Copyright (c) 1997 The NetBSD Foundation, Inc.
   5  * All rights reserved.
   6  *
   7  * This code is derived from software contributed to The NetBSD Foundation
   8  * by J.T. Conklin.
   9  *
  10  * Redistribution and use in source and binary forms, with or without
  11  * modification, are permitted provided that the following conditions
  12  * are met:
  13  * 1. Redistributions of source code must retain the above copyright
  14  *    notice, this list of conditions and the following disclaimer.
  15  * 2. Redistributions in binary form must reproduce the above copyright
  16  *    notice, this list of conditions and the following disclaimer in the
  17  *    documentation and/or other materials provided with the distribution.
  18  *
  19  * THIS SOFTWARE IS PROVIDED BY THE NETBSD FOUNDATION, INC. AND CONTRIBUTORS
  20  * ``AS IS'' AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED
  21  * TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR
  22  * PURPOSE ARE DISCLAIMED.  IN NO EVENT SHALL THE FOUNDATION OR CONTRIBUTORS
  23  * BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR
  24  * CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF
  25  * SUBSTITUTE GOODS OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS
  26  * INTERRUPTION) HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN
  27  * CONTRACT, STRICT LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE)
  28  * ARISING IN ANY WAY OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE
  29  * POSSIBILITY OF SUCH DAMAGE.
  30  */
  31
  32 /*-
  33  * Copyright (c) 1990 The Regents of the University of California.
  34  * All rights reserved.
  35  *
  36  * This code is derived from software contributed to Berkeley by
  37  * the Systems Programming Group of the University of Utah Computer
  38  * Science Department.
  39  *
  40  * Redistribution and use in source and binary forms, with or without
  41  * modification, are permitted provided that the following conditions
  42  * are met:
  43  * 1. Redistributions of source code must retain the above copyright
  44  *    notice, this list of conditions and the following disclaimer.
  45  * 2. Redistributions in binary form must reproduce the above copyright
  46  *    notice, this list of conditions and the following disclaimer in the
  47  *    documentation and/or other materials provided with the distribution.
  48  * 3. Neither the name of the University nor the names of its contributors
  49  *    may be used to endorse or promote products derived from this software
  50  *    without specific prior written permission.
  51  *
  52  * THIS SOFTWARE IS PROVIDED BY THE REGENTS AND CONTRIBUTORS ``AS IS'' AND
  53  * ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE
  54  * IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE
  55  * ARE DISCLAIMED.  IN NO EVENT SHALL THE REGENTS OR CONTRIBUTORS BE LIABLE
  56  * FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL
  57  * DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS
  58  * OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION)
  59  * HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT
  60  * LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY
  61  * OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF
  62  * SUCH DAMAGE.
  63  */
  64
  65 #include <machine/asm.h>
  66
  67 #if defined(LIBC_SCCS) && !defined(lint)
  68 #if 0
  69         RCSID("from: @(#)bzero.s        5.1 (Berkeley) 5/12/90")
  70 #else
  71         RCSID("$NetBSD: bzero.S,v 1.2 2008/04/28 20:22:52 martin Exp $")
  72 #endif
  73 #endif /* LIBC_SCCS and not lint */
  74
  75 ENTRY(bzero)
  76         movl    %d2,%sp@-
  77         movl    %sp@(8),%a0             | destination
  78         movl    %sp@(12),%d1            | count
  79
  80         movql   #0,%d2
  81
  82         /*
  83          * It isn't worth the overhead of aligning to {long}word boundries
  84          * if the string is too short.
  85          */
  86         cmpl    #8,%d1
  87         jlt     Lbzbyte
  88
  89         /* word align */
  90         movl    %a0,%d0
  91         btst    #0,%d0                  | if (dst & 1)
  92         jeq     Lbzalgndw               |
  93         movb    %d2,%a0@+               |       *(char *)dst++ = 0
  94         subql   #1,%d1                  |       len--
  95 Lbzalgndw:
  96         /* long word align */
  97         btst    #1,%d0                  | if (dst & 2)
  98         jeq     Lbzalgndl               |
  99         movw    %d2,%a0@+               |       *(short *)dst++ = 0
 100         subql   #2,%d1                  |       len -= 2
 101 Lbzalgndl:
 102         /* zero by 8 longwords */
 103         movel   %d1,%d0
 104         lsrl    #5,%d0                  | cnt = len / 32
 105         jeq     Lbzlong                 | if (cnt)
 106         andl    #31,%d1                 |       len %= 32
 107         subql   #1,%d0                  |       set up for dbf
 108 Lbz32loop:
 109         movl    %d2,%a0@+               |       zero 8 long words
 110         movl    %d2,%a0@+
 111         movl    %d2,%a0@+
 112         movl    %d2,%a0@+
 113         movl    %d2,%a0@+
 114         movl    %d2,%a0@+
 115         movl    %d2,%a0@+
 116         movl    %d2,%a0@+
 117         dbf     %d0,Lbz32loop           |       till done
 118         clrw    %d0
 119         subql   #1,%d0
 120         jcc     Lbz32loop
 121
 122 Lbzlong:
 123         /* copy by longwords */
 124         movel   %d1,%d0
 125         lsrl    #2,%d0                  | cnt = len / 4
 126         jeq     Lbzbyte                 | if (cnt)
 127         subql   #1,%d0                  |       set up for dbf
 128 Lbzlloop:
 129         movl    %d2,%a0@+               |       clear longwords
 130         dbf     %d0,Lbzlloop            |       till done
 131         andl    #3,%d1                  |       len %= 4
 132         jeq     Lbzdone
 133
 134         subql   #1,%d1                  | set up for dbf
 135 Lbzbloop:
 136         movb    %d2,%a0@+               | zero bytes
 137 Lbzbyte:
 138         dbf     %d1,Lbzbloop            | till done
 139 Lbzdone:
 140         movl    %sp@+,%d2
 141         rts