common/lib/libc/arch/m68k/string/memcmp.S

   1 /*      $NetBSD: memcmp.S,v 1.1 2005/12/20 19:28:49 christos Exp $      */
   2
   3 /*-
   4  * Copyright (c) 1990 The Regents of the University of California.
   5  * All rights reserved.
   6  *
   7  * This code is derived from software contributed to Berkeley by
   8  * the Systems Programming Group of the University of Utah Computer
   9  * Science Department.
  10  *
  11  * Redistribution and use in source and binary forms, with or without
  12  * modification, are permitted provided that the following conditions
  13  * are met:
  14  * 1. Redistributions of source code must retain the above copyright
  15  *    notice, this list of conditions and the following disclaimer.
  16  * 2. Redistributions in binary form must reproduce the above copyright
  17  *    notice, this list of conditions and the following disclaimer in the
  18  *    documentation and/or other materials provided with the distribution.
  19  * 3. Neither the name of the University nor the names of its contributors
  20  *    may be used to endorse or promote products derived from this software
  21  *    without specific prior written permission.
  22  *
  23  * THIS SOFTWARE IS PROVIDED BY THE REGENTS AND CONTRIBUTORS ``AS IS'' AND
  24  * ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE
  25  * IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE
  26  * ARE DISCLAIMED.  IN NO EVENT SHALL THE REGENTS OR CONTRIBUTORS BE LIABLE
  27  * FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL
  28  * DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS
  29  * OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION)
  30  * HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT
  31  * LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY
  32  * OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF
  33  * SUCH DAMAGE.
  34  */
  35
  36 #include <machine/asm.h>
  37
  38 #if defined(LIBC_SCCS) && !defined(lint)
  39 #if 0
  40         RCSID("from: @(#)bcmp.s 5.1 (Berkeley) 5/12/90")
  41 #else
  42         RCSID("$NetBSD: memcmp.S,v 1.1 2005/12/20 19:28:49 christos Exp $")
  43 #endif
  44 #endif /* LIBC_SCCS and not lint */
  45
  46 /* memcmp(s1, s2, n) */
  47
  48 /*
  49  * This is probably not the best we can do, but it is still 2-10 times
  50  * faster than the C version in the portable gen directory.
  51  *
  52  * Things that might help:
  53  *      - longword align when possible (only on the 68020)
  54  *      - use nested DBcc instructions or use one and limit size to 64K
  55  */
  56 ENTRY(memcmp)
  57         movl    %sp@(4),%a0             | string 1
  58         movl    %sp@(8),%a1             | string 2
  59         movl    %sp@(12),%d0            | length
  60         jeq     bcdone                  | if zero, nothing to do
  61         movl    %a0,%d1
  62         btst    #0,%d1                  | string 1 address odd?
  63         jeq     bceven                  | no, skip alignment
  64         cmpmb   %a0@+,%a1@+             | yes, compare a byte
  65         jne     bcnoteq                 | not equal, return non-zero
  66         subql   #1,%d0                  | adjust count
  67         jeq     bcdone                  | count 0, reutrn zero
  68 bceven:
  69         movl    %a1,%d1
  70         btst    #0,%d1                  | string 2 address odd?
  71         jne     bcbloop                 | yes, no hope for alignment, compare bytes
  72         movl    %d0,%d1                 | no, both even
  73         lsrl    #2,%d1                  | convert count to longword count
  74         jeq     bcbloop                 | count 0, skip longword loop
  75 bclloop:
  76         cmpml   %a0@+,%a1@+             | compare a longword
  77         jne     bcnoteql                | not equal, return non-zero
  78         subql   #1,%d1                  | adjust count
  79         jne     bclloop                 | still more, keep comparing
  80         andl    #3,%d0                  | what remains
  81         jeq     bcdone                  | nothing, all done
  82 bcbloop:
  83         cmpmb   %a0@+,%a1@+             | compare a byte
  84         jne     bcnoteq                 | not equal, return non-zero
  85         subql   #1,%d0                  | adjust count
  86         jne     bcbloop                 | still more, keep going
  87         rts
  88 bcnoteql:
  89         subql   #4,%a0
  90         subql   #4,%a1
  91         movl    #4,%d0
  92         jra     bcbloop
  93 bcnoteq:
  94         clrl    %d0
  95         clrl    %d1
  96         movb    %a0@-,%d0
  97         movb    %a1@-,%d1
  98         subl    %d1,%d0
  99 bcdone:
 100         rts