common/lib/libc/arch/m68k/string/strncpy.S

   1 /*      $NetBSD: strncpy.S,v 1.1 2005/12/20 19:28:49 christos Exp $     */
   2
   3 /*-
   4  * Copyright (c) 1990 The Regents of the University of California.
   5  * All rights reserved.
   6  *
   7  * This code is derived from software contributed to Berkeley by
   8  * the Systems Programming Group of the University of Utah Computer
   9  * Science Department.
  10  *
  11  * Redistribution and use in source and binary forms, with or without
  12  * modification, are permitted provided that the following conditions
  13  * are met:
  14  * 1. Redistributions of source code must retain the above copyright
  15  *    notice, this list of conditions and the following disclaimer.
  16  * 2. Redistributions in binary form must reproduce the above copyright
  17  *    notice, this list of conditions and the following disclaimer in the
  18  *    documentation and/or other materials provided with the distribution.
  19  * 3. Neither the name of the University nor the names of its contributors
  20  *    may be used to endorse or promote products derived from this software
  21  *    without specific prior written permission.
  22  *
  23  * THIS SOFTWARE IS PROVIDED BY THE REGENTS AND CONTRIBUTORS ``AS IS'' AND
  24  * ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE
  25  * IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE
  26  * ARE DISCLAIMED.  IN NO EVENT SHALL THE REGENTS OR CONTRIBUTORS BE LIABLE
  27  * FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL
  28  * DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS
  29  * OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION)
  30  * HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT
  31  * LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY
  32  * OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF
  33  * SUCH DAMAGE.
  34  */
  35
  36 #include <machine/asm.h>
  37
  38 #if defined(LIBC_SCCS) && !defined(lint)
  39 #if 0
  40         RCSID("from: @(#)strncpy.s      5.1 (Berkeley) 5/12/90")
  41 #else
  42         RCSID("$NetBSD: strncpy.S,v 1.1 2005/12/20 19:28:49 christos Exp $")
  43 #endif
  44 #endif /* LIBC_SCCS and not lint */
  45
  46 ENTRY(strncpy)
  47         movl    %sp@(4),%d0             | return value is toaddr
  48         movl    %sp@(12),%d1            | count
  49         jeq     Lscdone                 | nothing to do
  50         movl    %sp@(8),%a0             | a0 = fromaddr
  51         movl    %d0,%a1                 | a1 = toaddr
  52         subql   #1,%d1
  53 Lscloop:
  54         movb    %a0@+,%a1@+             | copy a byte
  55         dbeq    %d1,Lscloop             | loop through low word of d1
  56         jeq     Lscpadding              | copied null, padding if necessary
  57         clrw    %d1                     | clear low word of d1
  58         subql   #1,%d1                  | adjust count for long copies
  59         jcc     Lscloop                 | more room, keep going
  60 Lscdone:
  61 #ifdef __SVR4_ABI__
  62         moveal  %d0,%a0
  63 #endif
  64         rts
  65
  66 Lscploop:
  67         clrb    %a1@+                   | clear a byte
  68         dbra    %d1,Lscploop            | keep going
  69         clrw    %d1
  70 Lscpadding:
  71         subql   #1,%d1
  72         jcc     Lscploop
  73         jra     Lscdone