lib/libc/arch/m68k/gen/setjmp.S

   1 /*      $NetBSD: setjmp.S,v 1.12 2006/03/09 16:20:27 christos Exp $     */
   2
   3 /*-
   4  * Copyright (c) 1990 The Regents of the University of California.
   5  * All rights reserved.
   6  *
   7  * This code is derived from software contributed to Berkeley by
   8  * the Systems Programming Group of the University of Utah Computer
   9  * Science Department.
  10  *
  11  * Redistribution and use in source and binary forms, with or without
  12  * modification, are permitted provided that the following conditions
  13  * are met:
  14  * 1. Redistributions of source code must retain the above copyright
  15  *    notice, this list of conditions and the following disclaimer.
  16  * 2. Redistributions in binary form must reproduce the above copyright
  17  *    notice, this list of conditions and the following disclaimer in the
  18  *    documentation and/or other materials provided with the distribution.
  19  * 3. Neither the name of the University nor the names of its contributors
  20  *    may be used to endorse or promote products derived from this software
  21  *    without specific prior written permission.
  22  *
  23  * THIS SOFTWARE IS PROVIDED BY THE REGENTS AND CONTRIBUTORS ``AS IS'' AND
  24  * ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE
  25  * IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE
  26  * ARE DISCLAIMED.  IN NO EVENT SHALL THE REGENTS OR CONTRIBUTORS BE LIABLE
  27  * FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL
  28  * DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS
  29  * OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION)
  30  * HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT
  31  * LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY
  32  * OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF
  33  * SUCH DAMAGE.
  34  */
  35
  36 #include <machine/asm.h>
  37
  38 #if defined(LIBC_SCCS) && !defined(lint)
  39 #if 0
  40         RCSID("from: @(#)setjmp.s       5.1 (Berkeley) 5/12/90")
  41 #else
  42         RCSID("$NetBSD: setjmp.S,v 1.12 2006/03/09 16:20:27 christos Exp $")
  43 #endif
  44 #endif /* LIBC_SCCS and not lint */
  45
  46 /*
  47  * C library -- setjmp, longjmp
  48  *
  49  *      longjmp(a,v)
  50  * will generate a "return(v)" from
  51  * the last call to
  52  *      setjmp(a)
  53  * by restoring registers from the stack,
  54  * and a struct sigcontext, see <signal.h>
  55  */
  56
  57 ENTRY(__setjmp14)
  58         /* Get signal stack info.  Note overlay of ss_sp and ss_size! */
  59         lea     %sp@(-12),%sp   /* sizeof(stack_t) */
  60         clrl    %sp@            /* ss = NULL */
  61         movl    %sp,%sp@(4)     /* oss = stack_t on stack */
  62         jbsr    PIC_PLT(_C_LABEL(__sigaltstack14))
  63
  64         movl    %sp@(8),%d0     /* ss_flags */
  65         andl    #1,%d0          /* extract SS_ONSTACK */
  66         lea     %sp@(12),%sp    /* pop stack_t */
  67
  68         /* Get pointer to jmp_buf; a sigcontext is at the beginning. */
  69         movl    %sp@(4),%a0
  70         movl    %d0,%a0@        /* store onstack */
  71         clrl    %a0@(4)         /* unused word (old style signal mask) */
  72
  73         /* Get the signal mask. */
  74         pea     %a0@(28)        /* oset = &sc.sc_mask */
  75         movl    #0,%sp@-        /* set = NULL */
  76         movl    #0,%sp@-        /* action = 0 <ignored> */
  77         jbsr    PIC_PLT(_C_LABEL(__sigprocmask14))
  78         addl    #12,%sp
  79
  80         movl    %sp@(4),%a0     /* get jmp_buf pointer again */
  81         lea     %sp@(4),%a1     /* adjust SP since we won't rts */
  82         movl    %a1,%a0@(8)     /* save SP */
  83         movl    %a6,%a0@(12)    /* save FP */
  84         clrl    %a0@(16)        /* no AP */
  85         movl    %sp@,%a0@(20)   /* save return PC */
  86         clrl    %a0@(24)        /* clear PS */
  87
  88         /* Save remaining non-scratch regs after signal mask. */
  89         moveml  #0x3CFC,%a0@(44)
  90
  91         clrl    %d0             /* return 0 */
  92         rts
  93