lib/libc/arch/mips/gen/setjmp.S

   1 /*      $NetBSD: setjmp.S,v 1.19 2010/09/03 17:22:51 matt Exp $ */
   2
   3 /*-
   4  * Copyright (c) 1991, 1993
   5  *      The Regents of the University of California.  All rights reserved.
   6  *
   7  * This code is derived from software contributed to Berkeley by
   8  * Ralph Campbell.
   9  *
  10  * Redistribution and use in source and binary forms, with or without
  11  * modification, are permitted provided that the following conditions
  12  * are met:
  13  * 1. Redistributions of source code must retain the above copyright
  14  *    notice, this list of conditions and the following disclaimer.
  15  * 2. Redistributions in binary form must reproduce the above copyright
  16  *    notice, this list of conditions and the following disclaimer in the
  17  *    documentation and/or other materials provided with the distribution.
  18  * 3. Neither the name of the University nor the names of its contributors
  19  *    may be used to endorse or promote products derived from this software
  20  *    without specific prior written permission.
  21  *
  22  * THIS SOFTWARE IS PROVIDED BY THE REGENTS AND CONTRIBUTORS ``AS IS'' AND
  23  * ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE
  24  * IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE
  25  * ARE DISCLAIMED.  IN NO EVENT SHALL THE REGENTS OR CONTRIBUTORS BE LIABLE
  26  * FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL
  27  * DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS
  28  * OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION)
  29  * HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT
  30  * LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY
  31  * OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF
  32  * SUCH DAMAGE.
  33  */
  34
  35 #include <sys/syscall.h>
  36 #include <mips/asm.h>
  37
  38 #include "assym.h"
  39
  40 #if defined(LIBC_SCCS) && !defined(lint)
  41 #if 0
  42         RCSID("from: @(#)setjmp.s       8.1 (Berkeley) 6/4/93")
  43 #else
  44         RCSID("$NetBSD: setjmp.S,v 1.19 2010/09/03 17:22:51 matt Exp $")
  45 #endif
  46 #endif /* LIBC_SCCS and not lint */
  47
  48 /*
  49  * C library -- setjmp, longjmp
  50  *
  51  *      longjmp(a,v)
  52  * will generate a "return(v)" from
  53  * the last call to
  54  *      setjmp(a)
  55  * by restoring registers from the stack,
  56  * and a struct sigcontext, see <signal.h>
  57  */
  58
  59 #define SETJMP_FRAME_SIZE       (CALLFRAME_SIZ + STACK_T_SIZE)
  60
  61 NON_LEAF(__setjmp14, SETJMP_FRAME_SIZE, ra)
  62         .mask   0x80010000, (CALLFRAME_RA - CALLFRAME_SIZ)
  63         SETUP_GP
  64         PTR_SUBU        sp, sp, SETJMP_FRAME_SIZE       # allocate stack frame
  65         SAVE_GP(CALLFRAME_GP)
  66         SETUP_GP64(CALLFRAME_GP, __setjmp14)
  67
  68         REG_S           ra, CALLFRAME_RA(sp)            # save RA
  69         REG_S           s0, CALLFRAME_S0(sp)            # save S0
  70         move            s0, a0                          # save sigcontext
  71
  72         /* Get the signal mask. */
  73         PTR_ADDU        a2, a0, _OFFSETOF_SC_MASK       # &sc.sc_mask
  74         move            a1, zero
  75         jal             _C_LABEL(__sigprocmask14)       # get current signal mask
  76
  77         /* Get the signal stack. */
  78         move            a0, zero
  79         PTR_ADDU        a1, sp, CALLFRAME_SIZ           # pointer to stack_t
  80         jal             _C_LABEL(__sigaltstack14)
  81
  82         move            a0, s0                          # restore jmpbuf
  83         INT_L           v1, CALLFRAME_SIZ+_OFFSETOF_STACK_T_FLAGS(sp)
  84                                                         # get old ss_onstack
  85         and             v1, v1, SS_ONSTACK              # extract onstack flag
  86         INT_S           v1, _OFFSETOF_SC_ONSTACK(a0)    # save it in sc_onstack
  87
  88         REG_L           s0, CALLFRAME_S0(sp)            # restore S0
  89         REG_L           ra, CALLFRAME_RA(sp)            # restore RA
  90         blt             v0, zero, botch         # check for sigaltstack() error
  91         nop
  92         /*
  93          * We know we won't need this routine's GP anymore.
  94          */
  95         RESTORE_GP64
  96         PTR_ADDU        sp, sp, SETJMP_FRAME_SIZE       # pop stack frame
  97
  98
  99         REG_PROLOGUE
 100         REG_S   ra, _OFFSETOF_SC_PC(a0)         # sc_pc = return address
 101         REG_LI  v0, 0xACEDBADE                  # sigcontext magic number
 102         REG_S   v0, _OFFSETOF_SC_REGS(a0)       #   saved in sc_regs[0]
 103         REG_S   s0, _OFFSETOF_SC_REGS_S0(a0)
 104         REG_S   s1, _OFFSETOF_SC_REGS_S1(a0)
 105         REG_S   s2, _OFFSETOF_SC_REGS_S2(a0)
 106         REG_S   s3, _OFFSETOF_SC_REGS_S3(a0)
 107         REG_S   s4, _OFFSETOF_SC_REGS_S4(a0)
 108         REG_S   s5, _OFFSETOF_SC_REGS_S5(a0)
 109         REG_S   s6, _OFFSETOF_SC_REGS_S6(a0)
 110         REG_S   s7, _OFFSETOF_SC_REGS_S7(a0)
 111         REG_S   gp, _OFFSETOF_SC_REGS_GP(a0)
 112         REG_S   sp, _OFFSETOF_SC_REGS_SP(a0)
 113         REG_S   s8, _OFFSETOF_SC_REGS_S8(a0)
 114 #ifdef SOFTFLOAT_FOR_GCC
 115         INT_S   zero, _OFFSETOF_SC_FPUSED(a0)   # sc_fpused = 0
 116 #else
 117         li      v0, 1                           # be nice if we could tell
 118         INT_S   v0, _OFFSETOF_SC_FPUSED(a0)     # sc_fpused = 1
 119         cfc1    v0, $31
 120         INT_S   v0, _OFFSETOF_SC_FPREGS_FCSR(a0)
 121 #if defined(__mips_o32) || defined(__mips_o64) || defined(__mips_n32)
 122         FP_S    $f20, _OFFSETOF_SC_FPREGS_F20(a0)
 123         FP_S    $f22, _OFFSETOF_SC_FPREGS_F22(a0)
 124 #endif
 125 #if defined(__mips_o32) || defined(__mips_o64)
 126         FP_S    $f21, _OFFSETOF_SC_FPREGS_F21(a0)
 127         FP_S    $f23, _OFFSETOF_SC_FPREGS_F23(a0)
 128 #endif
 129 #if defined(__mips_n32) || defined(__mips_n64)
 130         FP_S    $f24, _OFFSETOF_SC_FPREGS_F24(a0)
 131         FP_S    $f26, _OFFSETOF_SC_FPREGS_F26(a0)
 132         FP_S    $f28, _OFFSETOF_SC_FPREGS_F28(a0)
 133         FP_S    $f30, _OFFSETOF_SC_FPREGS_F30(a0)
 134 #endif
 135 #if defined(__mips_n64)
 136         FP_S    $f25, _OFFSETOF_SC_FPREGS_F25(a0)
 137         FP_S    $f27, _OFFSETOF_SC_FPREGS_F27(a0)
 138         FP_S    $f29, _OFFSETOF_SC_FPREGS_F29(a0)
 139         FP_S    $f31, _OFFSETOF_SC_FPREGS_F31(a0)
 140 #endif
 141 #endif  /* SOFTFLOAT_FOR_GCC */
 142         REG_EPILOGUE
 143         move    v0, zero
 144         j       ra
 145
 146 botch:
 147         jal     _C_LABEL(abort)
 148 END(__setjmp14)