lib/libc/arch/vax/gen/_setjmp.S

   1 /*
   2  * Copyright (c) 1980, 1993
   3  *      The Regents of the University of California.  All rights reserved.
   4  *
   5  * Redistribution and use in source and binary forms, with or without
   6  * modification, are permitted provided that the following conditions
   7  * are met:
   8  * 1. Redistributions of source code must retain the above copyright
   9  *    notice, this list of conditions and the following disclaimer.
  10  * 2. Redistributions in binary form must reproduce the above copyright
  11  *    notice, this list of conditions and the following disclaimer in the
  12  *    documentation and/or other materials provided with the distribution.
  13  * 3. Neither the name of the University nor the names of its contributors
  14  *    may be used to endorse or promote products derived from this software
  15  *    without specific prior written permission.
  16  *
  17  * THIS SOFTWARE IS PROVIDED BY THE REGENTS AND CONTRIBUTORS ``AS IS'' AND
  18  * ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE
  19  * IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE
  20  * ARE DISCLAIMED.  IN NO EVENT SHALL THE REGENTS OR CONTRIBUTORS BE LIABLE
  21  * FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL
  22  * DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS
  23  * OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION)
  24  * HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT
  25  * LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY
  26  * OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF
  27  * SUCH DAMAGE.
  28  */
  29
  30 #if defined(LIBC_SCCS) && !defined(lint)
  31         /* .asciz "@(#)_setjmp.s        8.1 (Berkeley) 6/4/93" */
  32         .asciz "$NetBSD: _setjmp.S,v 1.9 2003/08/07 16:42:31 agc Exp $"
  33 #endif /* LIBC_SCCS and not lint */
  34
  35 /*
  36  * C library -- _setjmp, _longjmp
  37  *
  38  *      _longjmp(a,v)
  39  * will generate a "return(v)" from
  40  * the last call to
  41  *      _setjmp(a)
  42  * by restoring registers from the stack,
  43  * The previous signal state is NOT restored.
  44  *
  45  * Even though we don't use sigreturn14, we still store things in a sigcontext
  46  * in order to be consistent.
  47  */
  48
  49 #include "DEFS.h"
  50
  51 ENTRY(_setjmp, R6)
  52         movl    4(%ap),%r0
  53         movl    12(%fp),12(%r0)         # save frame pointer of caller
  54         movl    16(%fp),20(%r0)         # save pc of caller
  55 #ifdef __ELF__
  56         movl    8(%fp),16(%r0)          # save ap of caller
  57         clrl    %r1                     # clear arg count
  58         bbc     $13,6(%fp),1f           # was this a callg?
  59         addl3   $1,(%ap),%r1            # get real arg count+1 for calls
  60 1:      moval   24(%fp)[%r1],8(%r0)     # save sp of caller
  61         movpsl  24(%r0)                 # save current psl
  62         movw    4(%fp),24(%r0)          # save psw of caller
  63         movq    %r6,44(%r0)             # save r6/r7
  64         movq    %r8,52(%r0)             # save r8/r9
  65         movq    %r10,60(%r0)            # save r10/r11
  66 #endif
  67         clrl    %r0
  68         ret
  69
  70 ENTRY(_longjmp, 0)
  71         movl    8(%ap),%r0              # return(v)
  72         movl    4(%ap),%r1              # fetch buffer
  73         tstl    12(%r1)                 # is fp null
  74         beql    botch
  75 #ifdef __ELF__
  76         movq    44(%r1),%r6             # restore r6/r7
  77         movq    52(%r1),%r8             # restore r8/r9
  78         movq    60(%r1),%r10            # restore r10/r11
  79         movl    16(%r1),%ap             # restore ap
  80         movl    8(%r1),%sp              # restore sp
  81         movl    12(%r1),%fp             # restore fp
  82         movq    20(%r1),-(%sp)          # save pc/psl to new stack
  83         rei                             # and go back to saved pc/psl
  84 #else
  85 loop:
  86         bitw    $1,6(%fp)               # %r0 saved?
  87         beql    1f
  88         movl    %r0,20(%fp)
  89         bitw    $2,6(%fp)               # was %r1 saved?
  90         beql    2f
  91         movl    %r1,24(%fp)
  92         brb     2f
  93 1:
  94         bitw    $2,6(%fp)               # was %r1 saved?
  95         beql    2f
  96         movl    %r1,20(%fp)
  97 2:
  98         cmpl    12(%r1),12(%fp)
  99         beql    done
 100         blssu   botch
 101         movab   loop,16(%fp)
 102         ret                             # pop another frame
 103
 104 done:
 105         cmpb    *16(%fp),$2             # returning to an "rei"?
 106         bneq    1f
 107         movab   3f,16(%fp)              # do return w/ psl-pc pop
 108         brw     2f
 109 1:
 110         movab   4f,16(%fp)              # do standard return
 111 2:
 112         ret                             # unwind stack before signals enabled
 113 3:
 114         addl2   $8,%sp                  # compensate for PSL-PC push
 115 4:
 116         jmp     *20(%r1)                # done, return....
 117 #endif /* !__ELF__ */
 118
 119 botch:
 120         calls   $0,_C_LABEL(longjmperror)
 121         halt