distrib/sets/join.awk

   1 #       $NetBSD: join.awk,v 1.6 2014/10/24 22:19:44 riz Exp $
   2 #
   3 # Copyright (c) 2002 The NetBSD Foundation, Inc.
   4 # All rights reserved.
   5 #
   6 # This code is derived from software contributed to The NetBSD Foundation
   7 # by Luke Mewburn of Wasabi Systems.
   8 #
   9 # Redistribution and use in source and binary forms, with or without
  10 # modification, are permitted provided that the following conditions
  11 # are met:
  12 # 1. Redistributions of source code must retain the above copyright
  13 #    notice, this list of conditions and the following disclaimer.
  14 # 2. Redistributions in binary form must reproduce the above copyright
  15 #    notice, this list of conditions and the following disclaimer in the
  16 #    documentation and/or other materials provided with the distribution.
  17 #
  18 # THIS SOFTWARE IS PROVIDED BY THE NETBSD FOUNDATION, INC. AND CONTRIBUTORS
  19 # ``AS IS'' AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED
  20 # TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR
  21 # PURPOSE ARE DISCLAIMED.  IN NO EVENT SHALL THE FOUNDATION OR CONTRIBUTORS
  22 # BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR
  23 # CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF
  24 # SUBSTITUTE GOODS OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS
  25 # INTERRUPTION) HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN
  26 # CONTRACT, STRICT LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE)
  27 # ARISING IN ANY WAY OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE
  28 # POSSIBILITY OF SUCH DAMAGE.
  29 #
  30 # join.awk F1 F2
  31 #       Similar to join(1), this reads a list of words from F1
  32 #       and outputs lines in F2 with a first word that is in F1.
  33 #       Neither file needs to be sorted
  34
  35 function unvis(s) \
  36 {
  37         # XXX: We don't handle the complete range of vis encodings
  38         unvis_result = ""
  39         while (length(s) > 0) {
  40                 unvis_pos = match(s, "\\\\.")
  41                 if (unvis_pos == 0) {
  42                         unvis_result = unvis_result "" s
  43                         s = ""
  44                         break
  45                 }
  46                 # copy the part before the next backslash
  47                 unvis_result = unvis_result "" substr(s, 1, unvis_pos - 1)
  48                 s = substr(s, unvis_pos)
  49                 # process the backslash and next few chars
  50                 if (substr(s, 1, 2) == "\\\\") {
  51                         # double backslash -> single backslash
  52                         unvis_result = unvis_result "\\"
  53                         s = substr(s, 3)
  54                 } else if (match(s, "\\\\[0-7][0-7][0-7]") == 1) {
  55                         # \ooo with three octal digits.
  56                         # XXX: use strnum() is that is available
  57                         unvis_result = unvis_result "" sprintf("%c", \
  58                                 0+substr(s, 2, 1) * 64 + \
  59                                 0+substr(s, 3, 1) * 8 + \
  60                                 0+substr(s, 4, 1))
  61                         s = substr(s, 5)
  62                 } else {
  63                         # unrecognised escape: keep the literal backslash
  64                         printf "%s: %s:%s: unrecognised escape %s\n", \
  65                                 ARGV[0], (FILENAME ? FILENAME : "stdin"), FNR, \
  66                                 substr(s, 1, 2) \
  67                                 >"/dev/stderr"
  68                         unvis_result = unvis_result "" substr(s, 1, 1)
  69                         s = substr(s, 2)
  70                 }
  71         }
  72         return unvis_result
  73 }
  74
  75 BEGIN \
  76 {
  77         if (ARGC != 3) {
  78                 printf("Usage: join file1 file2\n") >"/dev/stderr"
  79                 exit 1
  80         }
  81         while ( (getline < ARGV[1]) > 0) {
  82                 $1 = unvis($1)
  83                 words[$1] = $0
  84         }
  85         delete ARGV[1]
  86 }
  87
  88 // { $1 = unvis($1) }
  89
  90 $1 in words \
  91 {
  92         f1=$1
  93         $1=""
  94         print words[f1] $0
  95 }