external/bsd/flex/dist/tests/test-bison-yylval/scanner.l

   1 /*
   2  * This file is part of flex.
   3  *
   4  * Redistribution and use in source and binary forms, with or without
   5  * modification, are permitted provided that the following conditions
   6  * are met:
   7  *
   8  * 1. Redistributions of source code must retain the above copyright
   9  *    notice, this list of conditions and the following disclaimer.
  10  * 2. Redistributions in binary form must reproduce the above copyright
  11  *    notice, this list of conditions and the following disclaimer in the
  12  *    documentation and/or other materials provided with the distribution.
  13  *
  14  * Neither the name of the University nor the names of its contributors
  15  * may be used to endorse or promote products derived from this software
  16  * without specific prior written permission.
  17  *
  18  * THIS SOFTWARE IS PROVIDED ``AS IS'' AND WITHOUT ANY EXPRESS OR
  19  * IMPLIED WARRANTIES, INCLUDING, WITHOUT LIMITATION, THE IMPLIED
  20  * WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR
  21  * PURPOSE.
  22  */
  23
  24 %{
  25 /* The scanner expects to link to bison yylval . */
  26 #include <stdio.h>
  27 #include <stdlib.h>
  28 #include "parser.h"
  29 #include "config.h"
  30 static char* STRDUP(char* s1);
  31
  32 enum yesno_t { no=0, yes=1 };
  33 #define YY_EXTRA_TYPE  enum yesno_t
  34 %}
  35
  36 %option 8bit outfile="scanner.c" prefix="test"
  37 %option reentrant bison-bridge
  38 %option noyywrap nomain nounput noyy_top_state noyywrap nodefault warn
  39 %option prefix="test" header="scanner.h"
  40 %option stack
  41
  42
  43 %x IN_TAG
  44 %x DISCARD_THRU_GT
  45 %%
  46
  47     #define YY_USER_INIT yyextra = no;
  48     #define NEED_TAG_NAME yyextra
  49
  50
  51 <INITIAL>{
  52 "</"       { NEED_TAG_NAME= yes; yy_push_state( IN_TAG, yyscanner); return LTSLASH;}
  53 "<"[^[:alpha:]]  { yy_push_state(DISCARD_THRU_GT,yyscanner); }
  54 "<"        { NEED_TAG_NAME= yes; yy_push_state( IN_TAG, yyscanner); return  LT; }
  55 [^<]{1,512} { yyget_lval(yyscanner)->str = STRDUP(yytext); return TEXT;}
  56 }
  57 <IN_TAG>{
  58 ">"  { yy_pop_state( yyscanner ); return GT; }
  59 [[:alpha:]][[:alnum:]]* {
  60         if( NEED_TAG_NAME == yes){
  61             NEED_TAG_NAME=no;
  62             yylval->str = STRDUP(yytext);
  63             return TAGNAME;
  64         }
  65     }
  66
  67 .|\r|\n { }
  68 }
  69 <DISCARD_THRU_GT>{
  70 [^>]{1,512} { }
  71 ">"        { yy_pop_state(yyscanner);}
  72 }
  73 %%
  74
  75
  76 static char* STRDUP(char* s1)
  77 {
  78     char* s2 = (char*)malloc(strlen(s1)+1);
  79     sprintf(s2,"%s",s1);
  80     return s2;
  81 }