commands/ash/arith_lex.l

   1 %{
   2 /*-
   3  * Copyright (c) 1993
   4  *      The Regents of the University of California.  All rights reserved.
   5  *
   6  * This code is derived from software contributed to Berkeley by
   7  * Kenneth Almquist.
   8  *
   9  * Redistribution and use in source and binary forms, with or without
  10  * modification, are permitted provided that the following conditions
  11  * are met:
  12  * 1. Redistributions of source code must retain the above copyright
  13  *    notice, this list of conditions and the following disclaimer.
  14  * 2. Redistributions in binary form must reproduce the above copyright
  15  *    notice, this list of conditions and the following disclaimer in the
  16  *    documentation and/or other materials provided with the distribution.
  17  * 4. Neither the name of the University nor the names of its contributors
  18  *    may be used to endorse or promote products derived from this software
  19  *    without specific prior written permission.
  20  *
  21  * THIS SOFTWARE IS PROVIDED BY THE REGENTS AND CONTRIBUTORS ``AS IS'' AND
  22  * ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE
  23  * IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE
  24  * ARE DISCLAIMED.  IN NO EVENT SHALL THE REGENTS OR CONTRIBUTORS BE LIABLE
  25  * FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL
  26  * DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS
  27  * OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION)
  28  * HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT
  29  * LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY
  30  * OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF
  31  * SUCH DAMAGE.
  32  */
  33
  34 #if 0
  35 #ifndef lint
  36 static char sccsid[] = "@(#)arith_lex.l 8.3 (Berkeley) 5/4/95";
  37 #endif
  38 #endif /* not lint */
  39 /*
  40 #include <sys/cdefs.h>
  41 __FBSDID("$FreeBSD: src/bin/sh/arith_lex.l,v 1.22 2004/04/06 20:06:51 markm Exp $");
  42 */
  43
  44 #include <string.h>
  45
  46 #include "shell.h"
  47 #include "arith.h"
  48 #include "error.h"
  49 #include "memalloc.h"
  50 #include "var.h"
  51
  52 extern char *arith_buf, *arith_startbuf;
  53 #undef YY_INPUT
  54 #define YY_INPUT(buf,result,max) \
  55         result = (*buf = *arith_buf++) ? 1 : YY_NULL;
  56 #define YY_NO_UNPUT
  57 %}
  58
  59 %%
  60 [ \t\n] { ; }
  61
  62 0x[a-fA-F0-9]+  {
  63                         yylval.l_value = strtoarith_t(yytext, NULL, 16);
  64                         return ARITH_NUM;
  65                 }
  66
  67 0[0-7]+         {
  68                         yylval.l_value = strtoarith_t(yytext, NULL, 8);
  69                         return ARITH_NUM;
  70                 }
  71
  72 [0-9]+          {
  73                         yylval.l_value = strtoarith_t(yytext, NULL, 10);
  74                         return ARITH_NUM;
  75                 }
  76
  77 [A-Za-z][A-Za-z0-9_]*   {
  78                         /*
  79                          * If variable doesn't exist, we should initialize
  80                          * it to zero.
  81                          */
  82                         char *temp;
  83                         if (lookupvar(yytext) == NULL)
  84                                 setvarsafe(yytext, "0", 0);
  85                         temp = (char *)ckmalloc(strlen(yytext) + 1);
  86                         yylval.s_value = strcpy(temp, yytext);
  87
  88                         return ARITH_VAR;
  89                 }
  90
  91 "("             {       return ARITH_LPAREN;    }
  92 ")"             {       return ARITH_RPAREN;    }
  93 "||"            {       return ARITH_OR;        }
  94 "&&"            {       return ARITH_AND;       }
  95 "|"             {       return ARITH_BOR;       }
  96 "^"             {       return ARITH_BXOR;      }
  97 "&"             {       return ARITH_BAND;      }
  98 "=="            {       return ARITH_EQ;        }
  99 "!="            {       return ARITH_NE;        }
 100 ">"             {       return ARITH_GT;        }
 101 ">="            {       return ARITH_GE;        }
 102 "<"             {       return ARITH_LT;        }
 103 "<="            {       return ARITH_LE;        }
 104 "<<"            {       return ARITH_LSHIFT;    }
 105 ">>"            {       return ARITH_RSHIFT;    }
 106 "*"             {       return ARITH_MUL;       }
 107 "/"             {       return ARITH_DIV;       }
 108 "%"             {       return ARITH_REM;       }
 109 "+"             {       return ARITH_ADD;       }
 110 "-"             {       return ARITH_SUB;       }
 111 "~"             {       return ARITH_BNOT;      }
 112 "!"             {       return ARITH_NOT;       }
 113 "="             {       return ARITH_ASSIGN;    }
 114 "+="            {       return ARITH_ADDASSIGN; }
 115 "-="            {       return ARITH_SUBASSIGN; }
 116 "*="            {       return ARITH_MULASSIGN; }
 117 "/="            {       return ARITH_DIVASSIGN; }
 118 "%="            {       return ARITH_REMASSIGN; }
 119 ">>="           {       return ARITH_RSHASSIGN; }
 120 "<<="           {       return ARITH_LSHASSIGN; }
 121 "&="            {       return ARITH_BANDASSIGN; }
 122 "^="            {       return ARITH_BXORASSIGN; }
 123 "|="            {       return ARITH_BORASSIGN; }
 124 .               {
 125                         error("arith: syntax error: \"%s\"\n", arith_startbuf);
 126                 }
 127 %%
 128
 129 void
 130 arith_lex_reset(void)
 131 {
 132         YY_NEW_FILE;
 133 }