lib/libc/arch/i386/sys/__clone.S

   1 /*      $NetBSD: __clone.S,v 1.5 2013/09/12 15:36:15 joerg Exp $        */
   2
   3 /*
   4  * Copyright (c) 2001 Wasabi Systems, Inc.
   5  * All rights reserved.
   6  *
   7  * Written by Frank van der Linden for Wasabi Systems, Inc.
   8  *
   9  * Redistribution and use in source and binary forms, with or without
  10  * modification, are permitted provided that the following conditions
  11  * are met:
  12  * 1. Redistributions of source code must retain the above copyright
  13  *    notice, this list of conditions and the following disclaimer.
  14  * 2. Redistributions in binary form must reproduce the above copyright
  15  *    notice, this list of conditions and the following disclaimer in the
  16  *    documentation and/or other materials provided with the distribution.
  17  * 3. All advertising materials mentioning features or use of this software
  18  *    must display the following acknowledgement:
  19  *      This product includes software developed for the NetBSD Project by
  20  *      Wasabi Systems, Inc.
  21  * 4. The name of Wasabi Systems, Inc. may not be used to endorse
  22  *    or promote products derived from this software without specific prior
  23  *    written permission.
  24  *
  25  * THIS SOFTWARE IS PROVIDED BY WASABI SYSTEMS, INC. ``AS IS'' AND
  26  * ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED
  27  * TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR
  28  * PURPOSE ARE DISCLAIMED.  IN NO EVENT SHALL WASABI SYSTEMS, INC
  29  * BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR
  30  * CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF
  31  * SUBSTITUTE GOODS OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS
  32  * INTERRUPTION) HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN
  33  * CONTRACT, STRICT LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE)
  34  * ARISING IN ANY WAY OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE
  35  * POSSIBILITY OF SUCH DAMAGE.
  36  */
  37
  38 #include <machine/asm.h>
  39 #include <sys/errno.h>
  40 #include "SYS.h"
  41
  42 #ifdef WEAK_ALIAS
  43 WEAK_ALIAS(clone, __clone)
  44 #endif
  45         .text
  46
  47 /*
  48  * int clone(int (*fn)(void *), void *stack, int flags, void *arg);
  49  */
  50 ENTRY(__clone)
  51         pushl   %ebp
  52
  53         /*
  54          * Sanity checks: func and stack may not be NULL.
  55          */
  56         movl    8(%esp), %ebp
  57         cmpl    $0,%ebp         /* function */
  58         je      3f
  59         movl    12(%esp),%eax   /* stack */
  60         cmpl    $0,%eax
  61         je      3f
  62
  63         /*
  64          * Set up the stack for the clone.
  65          */
  66         movl    20(%esp),%ecx
  67         movl    %ecx,-4(%eax)   /* argument */
  68         leal    -4(%eax),%eax   /* sp points to arg */
  69
  70         pushl   %eax            /* stack */
  71         pushl   20(%esp)        /* flags */
  72         pushl   $0              /* dummy return address */
  73
  74         SYSTRAP(__clone)
  75         jc      4f
  76         cmpl    $0,%eax
  77         jne     2f              /* we're the parent */
  78         call    *%ebp           /* this is the clone, call the function */
  79
  80 #ifdef __PIC__
  81         PIC_PROLOGUE
  82         pushl   %eax            /* clone does _exit(func(arg)); */
  83         call    PIC_PLT(_C_LABEL(_exit))
  84         addl    $4,%esp
  85         PIC_EPILOGUE
  86 #else
  87         pushl   %eax
  88         call    _C_LABEL(_exit)
  89         addl    $4,%esp
  90 #endif
  91
  92 2:
  93         addl    $12,%esp
  94         popl    %ebp
  95         ret
  96 3:
  97         movl    $EINVAL,%eax
  98         jmp     5f
  99 4:
 100         addl    $12,%esp
 101 5:
 102         popl    %ebp
 103         jmp     CERROR