lib/libc/arch/powerpc/gen/swapcontext.S

   1 /*      $NetBSD: swapcontext.S,v 1.7 2013/09/12 15:36:15 joerg Exp $    */
   2
   3 /*-
   4  * Copyright (c) 2001 The NetBSD Foundation, Inc.
   5  * All rights reserved.
   6  *
   7  * This code is derived from software contributed to The NetBSD Foundation
   8  * by Klaus Klein.
   9  *
  10  * Redistribution and use in source and binary forms, with or without
  11  * modification, are permitted provided that the following conditions
  12  * are met:
  13  * 1. Redistributions of source code must retain the above copyright
  14  *    notice, this list of conditions and the following disclaimer.
  15  * 2. Redistributions in binary form must reproduce the above copyright
  16  *    notice, this list of conditions and the following disclaimer in the
  17  *    documentation and/or other materials provided with the distribution.
  18  *
  19  * THIS SOFTWARE IS PROVIDED BY THE NETBSD FOUNDATION, INC. AND CONTRIBUTORS
  20  * ``AS IS'' AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED
  21  * TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR
  22  * PURPOSE ARE DISCLAIMED.  IN NO EVENT SHALL THE FOUNDATION OR CONTRIBUTORS
  23  * BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR
  24  * CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF
  25  * SUBSTITUTE GOODS OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS
  26  * INTERRUPTION) HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN
  27  * CONTRACT, STRICT LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE)
  28  * ARISING IN ANY WAY OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE
  29  * POSSIBILITY OF SUCH DAMAGE.
  30  */
  31
  32 #include "SYS.h"
  33 #include "assym.h"
  34
  35 __RCSID("$NetBSD: swapcontext.S,v 1.7 2013/09/12 15:36:15 joerg Exp $")
  36
  37 #define XCALLFRAMELEN   (((2+3)*SZREG + CALLFRAMELEN - 1) & -CALLFRAMELEN)
  38 #define XCALLFRAME_R30  (XCALLFRAMELEN-1*SZREG)
  39 #define XCALLFRAME_UCP  (XCALLFRAMELEN-2*SZREG)
  40 #define XCALLFRAME_OUCP (XCALLFRAMELEN-3*SZREG)
  41
  42 ENTRY(swapcontext)
  43         stwu    %r1,-XCALLFRAMELEN(%r1)         # set up new stack frame
  44         mflr    %r0
  45         stw     %r0,XCALLFRAMELEN+CALLFRAME_LR(%r1)     # save link register
  46         stw     %r3,XCALLFRAME_OUCP(%r1)        # must save oucp
  47         stw     %r4,XCALLFRAME_UCP(%r1)         # must save ucp
  48 #ifdef __PIC__
  49         stw     %r30,XCALLFRAME_R30(%r1)        # must save r30
  50         PIC_TOCSETUP(swapcontext,%r30)          # setup toc pointer
  51 #endif
  52         bl      PIC_PLT(_C_LABEL(_getcontext))  # getcontext(oucp)
  53         cmpwi   %r3,0
  54         bne     1f
  55         lwz     %r11,XCALLFRAME_OUCP(%r1)       # load oucp for adjustment
  56         lwz     %r0,XCALLFRAMELEN+CALLFRAME_LR(%r1)
  57         stw     %r0,UC_GREGS_PC(%r11)           # pc <- lr
  58         addi    %r0,%r1,XCALLFRAMELEN
  59         stw     %r0,UC_GREGS_R1(%r11)           # adjust sp
  60         lwz     %r3,XCALLFRAME_UCP(%r1)         # load ucp
  61         bl      PIC_PLT(_C_LABEL(setcontext))   # setcontext(ucp)
  62 1:
  63         lwz     %r0,XCALLFRAMELEN+CALLFRAME_LR(%r1)
  64 #ifdef __PIC__
  65         lwz     %r30,XCALLFRAME_R30(%r1)
  66 #endif
  67         mtlr    %r0
  68         addi    %r1,%r1,XCALLFRAMELEN
  69         blr
  70 END(swapcontext)