lib/libc/arch/powerpc/sys/__clone.S

   1 /*      $NetBSD: __clone.S,v 1.5 2013/09/12 15:36:15 joerg Exp $        */
   2
   3 /*-
   4  * Copyright (c) 2001 Tsubai Masanari.  All rights reserved.
   5  *
   6  * Redistribution and use in source and binary forms, with or without
   7  * modification, are permitted provided that the following conditions
   8  * are met:
   9  * 1. Redistributions of source code must retain the above copyright
  10  *    notice, this list of conditions and the following disclaimer.
  11  * 2. Redistributions in binary form must reproduce the above copyright
  12  *    notice, this list of conditions and the following disclaimer in the
  13  *    documentation and/or other materials provided with the distribution.
  14  * 3. The name of the author may not be used to endorse or promote products
  15  *    derived from this software without specific prior written permission.
  16  *
  17  * THIS SOFTWARE IS PROVIDED BY THE AUTHOR ``AS IS'' AND ANY EXPRESS OR
  18  * IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE IMPLIED WARRANTIES
  19  * OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE ARE DISCLAIMED.
  20  * IN NO EVENT SHALL THE AUTHOR BE LIABLE FOR ANY DIRECT, INDIRECT,
  21  * INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT
  22  * NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE,
  23  * DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY
  24  * THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT
  25  * (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE
  26  * OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.
  27  */
  28
  29 #include <sys/errno.h>
  30 #include "SYS.h"
  31
  32 #if defined(LIBC_SCCS) && !defined(lint)
  33 __RCSID("$NetBSD: __clone.S,v 1.5 2013/09/12 15:36:15 joerg Exp $")
  34 #endif /* LIBC_SCCS && !lint */
  35
  36 #ifdef WEAK_ALIAS
  37 WEAK_ALIAS(clone, __clone)
  38 #endif
  39
  40 /*
  41  * int __clone(int (*fn)(void *), void *stack, int flags, void *arg);
  42  */
  43 ENTRY(__clone)
  44         /*
  45          * Sanity checks: func and stack may not be NULL.
  46          */
  47         cmpwi   %r3,0
  48         beq     1f
  49         cmpwi   %r4,0
  50         beq     1f
  51
  52         mr      %r7,%r3         /* Save fn in r7. */
  53         mr      %r3,%r5
  54         _DOSYSCALL(__clone)     /* (flags, stack) */
  55         bso     2f              /* error... */
  56
  57         cmpwi   %r3,0
  58         bnelr                   /* We're the parent, just return. */
  59
  60         mtlr    %r7             /* fn */
  61         mr      %r3,%r6         /* arg */
  62         blrl                    /* Call the clone's entry point. */
  63
  64 #ifdef __PIC__
  65         PIC_TOCSETUP(__clone, %r30)     /* exit won't return so blow away r30 */
  66 #endif
  67         bl      PIC_PLT(_C_LABEL(_exit))
  68
  69 1:
  70         li      %r3,EINVAL
  71 2:
  72         b       _C_LABEL(__cerror)
  73 END(__clone)