minix/kernel/arch/earm/phys_memset.S

   1 /*      $NetBSD: memset.S,v 1.1 2005/12/20 19:28:49 christos Exp $      */
   2
   3 /*
   4  * Copyright 2003 Wasabi Systems, Inc.
   5  * All rights reserved.
   6  *
   7  * Written by Steve C. Woodford for Wasabi Systems, Inc.
   8  *
   9  * Redistribution and use in source and binary forms, with or without
  10  * modification, are permitted provided that the following conditions
  11  * are met:
  12  * 1. Redistributions of source code must retain the above copyright
  13  *    notice, this list of conditions and the following disclaimer.
  14  * 2. Redistributions in binary form must reproduce the above copyright
  15  *    notice, this list of conditions and the following disclaimer in the
  16  *    documentation and/or other materials provided with the distribution.
  17  * 3. All advertising materials mentioning features or use of this software
  18  *    must display the following acknowledgement:
  19  *      This product includes software developed for the NetBSD Project by
  20  *      Wasabi Systems, Inc.
  21  * 4. The name of Wasabi Systems, Inc. may not be used to endorse
  22  *    or promote products derived from this software without specific prior
  23  *    written permission.
  24  *
  25  * THIS SOFTWARE IS PROVIDED BY WASABI SYSTEMS, INC. ``AS IS'' AND
  26  * ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED
  27  * TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR
  28  * PURPOSE ARE DISCLAIMED.  IN NO EVENT SHALL WASABI SYSTEMS, INC
  29  * BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR
  30  * CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF
  31  * SUBSTITUTE GOODS OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS
  32  * INTERRUPTION) HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN
  33  * CONTRACT, STRICT LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE)
  34  * ARISING IN ANY WAY OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE
  35  * POSSIBILITY OF SUCH DAMAGE.
  36  */
  37 /*
  38  * Copyright (c) 1995 Mark Brinicombe.
  39  * All rights reserved.
  40  *
  41  * Redistribution and use in source and binary forms, with or without
  42  * modification, are permitted provided that the following conditions
  43  * are met:
  44  * 1. Redistributions of source code must retain the above copyright
  45  *    notice, this list of conditions and the following disclaimer.
  46  * 2. Redistributions in binary form must reproduce the above copyright
  47  *    notice, this list of conditions and the following disclaimer in the
  48  *    documentation and/or other materials provided with the distribution.
  49  * 3. All advertising materials mentioning features or use of this software
  50  *    must display the following acknowledgement:
  51  *      This product includes software developed by Mark Brinicombe.
  52  * 4. The name of the company nor the name of the author may be used to
  53  *    endorse or promote products derived from this software without specific
  54  *    prior written permission.
  55  *
  56  * THIS SOFTWARE IS PROVIDED BY THE AUTHOR ``AS IS'' AND ANY EXPRESS OR IMPLIED
  57  * WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE IMPLIED WARRANTIES OF
  58  * MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE ARE DISCLAIMED.
  59  * IN NO EVENT SHALL THE AUTHOR OR CONTRIBUTORS BE LIABLE FOR ANY DIRECT,
  60  * INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES
  61  * (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR
  62  * SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION)
  63  * HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT
  64  * LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY
  65  * OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF
  66  * SUCH DAMAGE.
  67  */
  68
  69 #include <machine/asm.h>
  70
  71 /*
  72  * memset: Sets a block of memory to the specified value
  73  *
  74  * On entry:
  75  *   r0 - dest address
  76  *   r1 - byte to write
  77  *   r2 - number of bytes to write
  78  *
  79  * On exit:
  80  *   r0 - dest address
  81  */
  82 #ifdef _BZERO
  83 /* LINTSTUB: Func: void bzero(void *, size_t) */
  84 ENTRY(bzero)
  85         mov     r3, #0x00
  86 #else
  87 #if defined(__minix)
  88 /* LINTSTUB: Func: void *phys_memset(void *, int, size_t) */
  89 ENTRY(phys_memset)
  90 #else
  91 /* LINTSTUB: Func: void *memset(void *, int, size_t) */
  92 ENTRY(memset)
  93 #endif
  94         and     r3, r1, #0xff           /* We deal with bytes */
  95         mov     r1, r2
  96 #endif
  97         cmp     r1, #0x04               /* Do we have less than 4 bytes */
  98         mov     ip, r0
  99         blt     .Lmemset_lessthanfour
 100
 101         /* Ok first we will word align the address */
 102         ands    r2, ip, #0x03           /* Get the bottom two bits */
 103         bne     .Lmemset_wordunaligned  /* The address is not word aligned */
 104
 105         /* We are now word aligned */
 106 .Lmemset_wordaligned:
 107 #ifndef _BZERO
 108         orr     r3, r3, r3, lsl #8      /* Extend value to 16-bits */
 109 #endif
 110 #ifdef __XSCALE__
 111         tst     ip, #0x04               /* Quad-align for Xscale */
 112 #else
 113         cmp     r1, #0x10
 114 #endif
 115 #ifndef _BZERO
 116         orr     r3, r3, r3, lsl #16     /* Extend value to 32-bits */
 117 #endif
 118 #ifdef __XSCALE__
 119         subne   r1, r1, #0x04           /* Quad-align if necessary */
 120         strne   r3, [ip], #0x04
 121         cmp     r1, #0x10
 122 #endif
 123         blt     .Lmemset_loop4          /* If less than 16 then use words */
 124         mov     r2, r3                  /* Duplicate data */
 125         cmp     r1, #0x80               /* If < 128 then skip the big loop */
 126         blt     .Lmemset_loop32
 127
 128         /* Do 128 bytes at a time */
 129 .Lmemset_loop128:
 130         subs    r1, r1, #0x80
 131 #ifdef __XSCALE__
 132         strged  r2, [ip], #0x08
 133         strged  r2, [ip], #0x08
 134         strged  r2, [ip], #0x08
 135         strged  r2, [ip], #0x08
 136         strged  r2, [ip], #0x08
 137         strged  r2, [ip], #0x08
 138         strged  r2, [ip], #0x08
 139         strged  r2, [ip], #0x08
 140         strged  r2, [ip], #0x08
 141         strged  r2, [ip], #0x08
 142         strged  r2, [ip], #0x08
 143         strged  r2, [ip], #0x08
 144         strged  r2, [ip], #0x08
 145         strged  r2, [ip], #0x08
 146         strged  r2, [ip], #0x08
 147         strged  r2, [ip], #0x08
 148 #else
 149         stmgeia ip!, {r2-r3}
 150         stmgeia ip!, {r2-r3}
 151         stmgeia ip!, {r2-r3}
 152         stmgeia ip!, {r2-r3}
 153         stmgeia ip!, {r2-r3}
 154         stmgeia ip!, {r2-r3}
 155         stmgeia ip!, {r2-r3}
 156         stmgeia ip!, {r2-r3}
 157         stmgeia ip!, {r2-r3}
 158         stmgeia ip!, {r2-r3}
 159         stmgeia ip!, {r2-r3}
 160         stmgeia ip!, {r2-r3}
 161         stmgeia ip!, {r2-r3}
 162         stmgeia ip!, {r2-r3}
 163         stmgeia ip!, {r2-r3}
 164         stmgeia ip!, {r2-r3}
 165 #endif
 166         bgt     .Lmemset_loop128
 167 #if defined(__minix)
 168         moveq   r0, #0
 169 #endif
 170         RETc(eq)                        /* Zero length so just exit */
 171
 172         add     r1, r1, #0x80           /* Adjust for extra sub */
 173
 174         /* Do 32 bytes at a time */
 175 .Lmemset_loop32:
 176         subs    r1, r1, #0x20
 177 #ifdef __XSCALE__
 178         strged  r2, [ip], #0x08
 179         strged  r2, [ip], #0x08
 180         strged  r2, [ip], #0x08
 181         strged  r2, [ip], #0x08
 182 #else
 183         stmgeia ip!, {r2-r3}
 184         stmgeia ip!, {r2-r3}
 185         stmgeia ip!, {r2-r3}
 186         stmgeia ip!, {r2-r3}
 187 #endif
 188         bgt     .Lmemset_loop32
 189 #if defined(__minix)
 190         moveq   r0, #0
 191 #endif
 192         RETc(eq)                        /* Zero length so just exit */
 193
 194         adds    r1, r1, #0x10           /* Partially adjust for extra sub */
 195
 196         /* Deal with 16 bytes or more */
 197 #ifdef __XSCALE__
 198         strged  r2, [ip], #0x08
 199         strged  r2, [ip], #0x08
 200 #else
 201         stmgeia ip!, {r2-r3}
 202         stmgeia ip!, {r2-r3}
 203 #endif
 204 #if defined(__minix)
 205         moveq   r0, #0
 206 #endif
 207         RETc(eq)                        /* Zero length so just exit */
 208
 209         addlt   r1, r1, #0x10           /* Possibly adjust for extra sub */
 210
 211         /* We have at least 4 bytes so copy as words */
 212 .Lmemset_loop4:
 213         subs    r1, r1, #0x04
 214         strge   r3, [ip], #0x04
 215         bgt     .Lmemset_loop4
 216 #if defined(__minix)
 217         moveq   r0, #0
 218 #endif
 219         RETc(eq)                        /* Zero length so just exit */
 220
 221 #ifdef __XSCALE__
 222         /* Compensate for 64-bit alignment check */
 223         adds    r1, r1, #0x04
 224 #if defined(__minix)
 225         moveq   r0, #0
 226 #endif
 227         RETc(eq)
 228         cmp     r1, #2
 229 #else
 230         cmp     r1, #-2
 231 #endif
 232
 233         strb    r3, [ip], #0x01         /* Set 1 byte */
 234         strgeb  r3, [ip], #0x01         /* Set another byte */
 235         strgtb  r3, [ip]                /* and a third */
 236 #if defined(__minix)
 237         mov     r0, #0
 238 #endif
 239         RET                             /* Exit */
 240
 241 .Lmemset_wordunaligned:
 242         rsb     r2, r2, #0x004
 243         strb    r3, [ip], #0x01         /* Set 1 byte */
 244         cmp     r2, #0x02
 245         strgeb  r3, [ip], #0x01         /* Set another byte */
 246         sub     r1, r1, r2
 247         strgtb  r3, [ip], #0x01         /* and a third */
 248         cmp     r1, #0x04               /* More than 4 bytes left? */
 249         bge     .Lmemset_wordaligned    /* Yup */
 250
 251 .Lmemset_lessthanfour:
 252         cmp     r1, #0x00
 253 #if defined(__minix)
 254         moveq   r0, #0
 255 #endif
 256         RETc(eq)                                /* Zero length so exit */
 257         strb    r3, [ip], #0x01         /* Set 1 byte */
 258         cmp     r1, #0x02
 259         strgeb  r3, [ip], #0x01         /* Set another byte */
 260         strgtb  r3, [ip]                /* and a third */
 261 #if defined(__minix)
 262         mov     r0, #0
 263 #endif
 264         RET                             /* Exit */
 265
 266 #if defined(__minix)
 267 LABEL(memset_fault)             /* kernel can send us here */
 268         mov     r0, #0
 269         RET
 270
 271 LABEL(memset_fault_in_kernel)   /* kernel can send us here */
 272         mrc     p15, 0, r0, c6, c0, 0   /* Read DFAR */
 273         RET
 274 #endif