kernel/arch/earm/kernel.lds

   1 OUTPUT_ARCH("arm")
   2 ENTRY(__k_unpaged_MINIX)
   3
   4 _kern_phys_base = 0x80200000;   /* phys 4MB aligned for convenient remapping */
   5 _kern_vir_base =  0xF0400000;   /* map kernel high for max. user vir space */
   6 _kern_offset = (_kern_vir_base - _kern_phys_base);
   7
   8 __k_unpaged__kern_offset = _kern_offset;
   9 __k_unpaged__kern_vir_base = _kern_vir_base;
  10 __k_unpaged__kern_phys_base = _kern_phys_base;
  11
  12 SECTIONS
  13 {
  14         . = _kern_phys_base;
  15         __k_unpaged__kern_unpaged_start = .;
  16
  17         .unpaged_text ALIGN(4096) : { unpaged_*.o(.text) }
  18         .unpaged_data ALIGN(4096) : { unpaged_*.o(.data .rodata*) }
  19         __k_unpaged__kern_unpaged__edata = .;
  20         __k_unpaged__edata = .;
  21         .unpaged_bss  ALIGN(4096) : { unpaged_*.o(.bss COMMON) }
  22         __k_unpaged__kern_unpaged_end = .;
  23         __k_unpaged__end = .;
  24
  25         . += _kern_offset;
  26
  27         . = ALIGN(4096); usermapped_start = .;
  28         .usermapped_glo : AT(ADDR(.usermapped_glo) - _kern_offset) { usermapped_glo*.o(*) }
  29         . = ALIGN(4096); usermapped_nonglo_start = .;
  30         .usermapped : AT(ADDR(.usermapped) - _kern_offset) { usermapped_*.o(*) }
  31         . = ALIGN(4096); usermapped_end = .;
  32         .text             : AT(ADDR(.text) - _kern_offset) { *(.text*) }
  33         _etext = .;
  34         .data ALIGN(4096) : AT(ADDR(.data) - _kern_offset) { *(.data .rodata* ) }
  35         . = ALIGN(4096);
  36         _edata = .;
  37         .bss ALIGN(4096)  : AT(ADDR(.bss) - _kern_offset) { *(.bss* COMMON)
  38                 __k_unpaged__kern_size = . - _kern_vir_base;
  39                 _kern_size = __k_unpaged__kern_size;
  40                 . += 4096;
  41         }
  42         _end = .;
  43
  44       /DISCARD/ :
  45        {
  46                *(.ARM.exidx*)
  47        }
  48
  49 }