tools/compat/configure.ac

   1 #       $NetBSD: configure.ac,v 1.80 2013/08/14 10:14:45 jmcneill Exp $
   2 #
   3 # Autoconf definition file for libnbcompat.
   4 #
   5 # When you edit configure.ac:
   6 # 0. Create the tools versions of autoconf and autoheader:
   7 #        cd ${SRCDIR} && build.sh -V MKMAINTAINERTOOLS=yes tools
   8 #    (This might not work if you try it after editing configure.ac.)
   9 # 1. edit configure.ac
  10 # 2. Regenerate "configure" and "nbtool_config.h.in" from "configure.ac":
  11 #        cd ${SRCDIR}/tools/compat && ${TOOLDIR}/bin/nbmake-${MACHINE} regen
  12 #    (Please don't use a non-tools version of autoconf or autoheader.)
  13 # 3. Test that the tools still build:
  14 #        mv ${TOOLDIR} ${TOOLDIR}.bak
  15 #        cd ${SRCDIR} && build.sh -V MKMAINTAINERTOOLS=yes tools
  16 # 4. cvs commit files that you edited.
  17 # 5. Regen again, to pick up changed RCS IDs from the above commit:
  18 #        cd ${SRCDIR}/tools/compat && ${TOOLDIR}/bin/nbmake-${MACHINE} regen
  19 # 6. cvs commit files that were generated.
  20 #
  21
  22 AC_INIT([libnbcompat], [noversion], [lib-bug-people@NetBSD.org])
  23 AC_CONFIG_HEADERS(nbtool_config.h)
  24 AC_CONFIG_FILES(defs.mk)
  25
  26 # Autoheader header and footer
  27 AH_TOP([/*      $][NetBSD$    */
  28
  29 #ifndef __NETBSD_NBTOOL_CONFIG_H__
  30 #define __NETBSD_NBTOOL_CONFIG_H__])
  31
  32 AH_BOTTOM([#include "compat_defs.h"
  33 #endif /* !__NETBSD_NBTOOL_CONFIG_H__ */])
  34
  35 AC_DEFUN([AC_NETBSD],
  36 [AC_BEFORE([$0], [AC_COMPILE_IFELSE])dnl
  37       AC_BEFORE([$0], [AC_RUN_IFELSE])dnl
  38       AC_MSG_CHECKING([for NetBSD or MINIX3])
  39       AC_EGREP_CPP(yes,
  40       [#if defined(__NetBSD__) || ((__minix)
  41         yes
  42         #endif
  43         ],
  44         [AC_MSG_RESULT([yes])
  45          AC_DEFINE([_POSIX_SOURCE], 1, [Define for NetBSD headers.])
  46          AC_DEFINE([_POSIX_C_SOURCE], 200112L, [Define for NetBSD headers.])
  47          AC_DEFINE([_XOPEN_SOURCE], 600, [Define for NetBSD headers.])],
  48         [AC_MSG_RESULT([no])])
  49 ])# AC_NETBSD
  50
  51 AC_NETBSD
  52 AC_PATH_PROG(BSHELL, sh, )
  53 if test x"$BSHELL" = x; then
  54         AC_MSG_ERROR([sh must be somewhere on \$PATH])
  55 fi
  56 AC_DEFINE_UNQUOTED([PATH_BSHELL], "$BSHELL", [Path to sh(1).])
  57
  58 AC_C_BIGENDIAN
  59 AC_HEADER_STDC
  60
  61 # Confirm existence of zlib.  (This is available as a default install
  62 # option on many OS's; this could be added as a reachover build in the
  63 # future.)
  64 AC_CHECK_HEADER(zlib.h,,
  65         AC_MSG_ERROR([zlib must be installed in a compiler-visible path]))
  66 AC_CHECK_LIB(z, gzdopen,,
  67         AC_MSG_ERROR([zlib must be installed in a compiler-visible path]))
  68
  69 # Make sure certain required headers are available.
  70 # These are not necessarily required by the code, but they are not
  71 # currently conditionalized.
  72 AC_CHECK_HEADERS(sys/ioctl.h sys/mman.h sys/param.h \
  73         sys/socket.h sys/stat.h sys/time.h sys/types.h sys/utsname.h \
  74         sys/wait.h assert.h ctype.h errno.h fcntl.h grp.h limits.h locale.h \
  75         netdb.h pwd.h signal.h stdarg.h stdio.h stdlib.h string.h \
  76         termios.h unistd.h,,
  77         AC_MSG_ERROR([standard system header file not found]))
  78
  79 # Find headers that may not be available.
  80 AC_HEADER_DIRENT
  81 AC_CHECK_HEADERS(sys/mtio.h sys/sysmacros.h sys/syslimits.h \
  82         getopt.h features.h malloc.h sys/poll.h pthread.h stddef.h rpc/types.h)
  83 AC_CHECK_HEADERS(sys/bswap.h machine/bswap.h sys/cdefs.h machine/endian.h \
  84         sys/endian.h sys/featuretest.h err.h inttypes.h libgen.h paths.h \
  85         stdint.h util.h resolv.h arpa/nameser.h,,
  86         [test -f include/$ac_header || touch include/$ac_header])
  87 AC_CHECK_HEADERS(rpc/types.h netconfig.h,,
  88         [echo '#include "nbtool_config.h"' >include/$ac_header.new
  89         echo '#include "'$srcdir/../../include/$ac_header'"' \
  90                 >>include/$ac_header.new
  91         if cmp include/$ac_header.new include/$ac_header >/dev/null 2>&1; then
  92                 rm -f include/$ac_header.new
  93         else
  94                 mv -f include/$ac_header.new include/$ac_header
  95         fi])
  96
  97 # Typedefs.
  98 AC_TYPE_SIZE_T
  99 AC_CHECK_TYPES([id_t, long long, u_long, u_char, u_short, u_int, u_quad_t])
 100 AC_CHECK_TYPE(socklen_t, [AC_DEFINE([HAVE_SOCKLEN_T], 1,
 101                           [Define if you have the socklen_t type.])],,
 102 [#include <sys/types.h>
 103 #ifdef HAVE_RPC_TYPES_H
 104 #include <rpc/types.h>
 105 #endif
 106 #include <sys/socket.h>])
 107
 108 dnl XXX - This is UGLY.  Need a better way to homogenize the bitsized types,
 109 dnl including use of compiler primitive types via AC_CHECK_SIZEOF.
 110 dnl
 111 define([NB_CHECK_INTTYPE], [
 112         AC_CHECK_TYPE(uint][$1][_t,, [
 113                 AC_CHECK_TYPE(u_int][$1][_t,
 114                         AC_DEFINE(uint][$1][_t, u_int][$1][_t, \
 115                                   [Define if you have u_int][$1][_t, but not uint][$1][_t.]),
 116                         AC_MSG_ERROR([cannot find a suitable type for uint][$1][_t]))
 117         ])
 118         AC_CHECK_TYPE(u_int][$1][_t,, [
 119                 AC_CHECK_TYPE(uint][$1][_t,
 120                         AC_DEFINE(u_int][$1][_t, uint][$1][_t, \
 121                                   [Define if you have uint][$1][_t, but not u_int][$1][_t.]),
 122                         AC_MSG_ERROR([cannot find a suitable type for u_int][$1][_t]))
 123         ])
 124 ])
 125
 126 NB_CHECK_INTTYPE(8)
 127 NB_CHECK_INTTYPE(16)
 128 NB_CHECK_INTTYPE(32)
 129 NB_CHECK_INTTYPE(64)
 130
 131 # Struct members.
 132 AC_CHECK_MEMBERS([DIR.dd_fd, DIR.__dd_fd, struct dirent.d_namlen],,,
 133 [#include <sys/types.h>
 134 #include <dirent.h>])
 135 AC_CHECK_MEMBERS([struct stat.st_flags, struct stat.st_gen,
 136         struct stat.st_birthtime, struct stat.st_birthtimensec,
 137         struct stat.st_atim, struct stat.st_mtimensec],,,
 138         [#include <sys/stat.h>])
 139 AC_CHECK_MEMBERS(struct statvfs.f_iosize,,, [#include <sys/statvfs.h>])
 140 AC_CHECK_MEMBERS(struct tm.tm_gmtoff,,, [#include <time.h>])
 141
 142 # Global variable decls.
 143 AC_CHECK_DECLS([optind, optreset],,, [
 144 #include <stdio.h>
 145 #include <stdlib.h>
 146 #include <unistd.h>
 147 #ifdef HAVE_GETOPT_H
 148 #include <getopt.h>
 149 #endif
 150 ])
 151 AC_CHECK_DECLS(sys_signame,,, [#include <signal.h>])
 152
 153 # Library functions (where a .h check isn't enough).
 154 AC_FUNC_ALLOCA
 155 AC_CHECK_FUNCS(atoll asprintf asnprintf basename devname dirfd dirname \
 156         dprintf esetfunc fgetln flock fpurge __fpurge futimes getline \
 157         getopt getopt_long group_from_gid gid_from_group \
 158         heapsort isblank issetugid lchflags lchmod lchown lutimes mkstemp \
 159         mkdtemp poll pread putc_unlocked pwcache_userdb pwcache_groupdb \
 160         pwrite raise_default_signal random setenv \
 161         setgroupent setprogname setpassent \
 162         snprintb_m snprintf strlcat strlcpy strmode \
 163         strndup strsep strsuftoll strtoll \
 164         user_from_uid uid_from_user vasprintf vasnprintf vsnprintf)
 165
 166 AC_CHECK_DECLS([user_from_uid, uid_from_user, pwcache_userdb],,,[
 167 #include <pwd.h>
 168 ])
 169 AC_CHECK_DECLS([group_from_gid, gid_from_group, pwcache_groupdb],,,[
 170 #include <grp.h>
 171 ])
 172 AC_CHECK_DECLS([strndup],,,[#include <string.h>])
 173 AC_CHECK_DECLS([strsuftoll],,,[#include <stdlib.h>])
 174 AC_CHECK_DECLS([lchflags, lchmod, lchown],,,[
 175 #include <sys/stat.h>
 176 #include <unistd.h>
 177 ])
 178
 179 AC_CHECK_DECLS([htobe16, htobe32, htobe64, htole16, htole32, htole64,
 180                 be16toh, be32toh, be64toh, le16toh, le32toh, le64toh],,,
 181                 [#include <sys/types.h>])
 182
 183 AC_CHECK_DECLS([bswap16, bswap32, bswap64],,, [#include <machine/bswap.h>])
 184
 185 AC_CHECK_DECLS([be16enc, le16enc, be16dec, le16dec, be32enc, le32enc,
 186                 be32dec, le32dec, be64enc, le64enc, be64dec, le64dec],,,
 187                 [#include <sys/endian.h>])
 188
 189 AC_CHECK_DECLS([fstatvfs],,, [#include <sys/statvfs.h>])
 190
 191 AC_CHECK_DECLS([setgroupent, setpassent],,, [
 192 #include <sys/types.h>
 193 #include <grp.h>
 194 #include <pwd.h>
 195 ])
 196
 197 # regcomp() and regexec() are also names of functions in the old V8
 198 # regexp package.  To avoid them, we need to find out who has regfree().
 199
 200 dnl # Cygwin: We *MUST* look at -lregex *before* the "no libs" condition.
 201 dnl # Thus AC_CHECK_LIB(regex...) comes first, and AC_SEARCHLIBS next.
 202 AC_CHECK_LIB(regex, regfree)
 203 AC_SEARCH_LIBS(regfree, rx posix)
 204
 205 AC_CHECK_LIB(rt, clock_gettime)
 206
 207 AC_CHECK_FUNCS(fparseln, [
 208     AC_MSG_CHECKING(if fparseln seems to work)
 209     AC_RUN_IFELSE(
 210         [AC_LANG_SOURCE([[
 211 #define _NETBSD_SOURCE
 212 #include <stdio.h>
 213 #include <stdlib.h>
 214 #define CONFTEST        "conftest.fparseln"
 215 #define COMMENT         '#'
 216 int
 217 main(void)
 218 {
 219         static const char delim[3] = { '\0', '\0', COMMENT };
 220         FILE *fp;
 221         char *ptr;
 222         fp = fopen(CONFTEST, "w+");
 223         if (fp != NULL) {
 224                 unlink(CONFTEST);
 225                 ungetc(COMMENT, fp);
 226                 ptr = fparseln(fp, NULL, NULL, delim,
 227                     FPARSELN_UNESCALL);
 228                 fclose(fp);
 229                 if (ptr == NULL)
 230                         exit(0);
 231         }
 232         exit(1);
 233 }
 234         ]])],
 235         [AC_MSG_RESULT(yes)],
 236         [AC_MSG_RESULT(no)
 237          AC_DEFINE(BROKEN_FPARSELN, 1,
 238             [Define to 1 if your `fparseln' function is broken.])],
 239         [AC_MSG_WARN([cross compiling: not checking farseln])]
 240     )
 241 ])
 242
 243 # Variables substituted via @VARNAME@ in defs.mk.in
 244 AC_SUBST(HAVE_PTHREAD_H, $ac_cv_header_pthread_h)
 245
 246 AC_OUTPUT