lib/libc/arch/i386/gen/sigsetjmp.S

   1 /*      $NetBSD: sigsetjmp.S,v 1.18 2014/05/23 02:34:19 uebayasi Exp $  */
   2
   3 /*-
   4  * Copyright (c) 1990 The Regents of the University of California.
   5  * All rights reserved.
   6  *
   7  * This code is derived from software contributed to Berkeley by
   8  * William Jolitz.
   9  *
  10  * Redistribution and use in source and binary forms, with or without
  11  * modification, are permitted provided that the following conditions
  12  * are met:
  13  * 1. Redistributions of source code must retain the above copyright
  14  *    notice, this list of conditions and the following disclaimer.
  15  * 2. Redistributions in binary form must reproduce the above copyright
  16  *    notice, this list of conditions and the following disclaimer in the
  17  *    documentation and/or other materials provided with the distribution.
  18  * 3. Neither the name of the University nor the names of its contributors
  19  *    may be used to endorse or promote products derived from this software
  20  *    without specific prior written permission.
  21  *
  22  * THIS SOFTWARE IS PROVIDED BY THE REGENTS AND CONTRIBUTORS ``AS IS'' AND
  23  * ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE
  24  * IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE
  25  * ARE DISCLAIMED.  IN NO EVENT SHALL THE REGENTS OR CONTRIBUTORS BE LIABLE
  26  * FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL
  27  * DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS
  28  * OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION)
  29  * HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT
  30  * LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY
  31  * OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF
  32  * SUCH DAMAGE.
  33  *
  34  *      from: @(#)setjmp.s      5.1 (Berkeley) 4/23/90"
  35  */
  36
  37 #include <machine/asm.h>
  38 #if defined(LIBC_SCCS)
  39         RCSID("$NetBSD: sigsetjmp.S,v 1.18 2014/05/23 02:34:19 uebayasi Exp $")
  40 #endif
  41
  42 ENTRY(__sigsetjmp14)
  43         movl    4(%esp),%ecx
  44         movl    0(%esp),%edx
  45         movl    %edx, 0(%ecx)
  46         movl    %ebx, 4(%ecx)
  47         movl    %esp, 8(%ecx)
  48         movl    %ebp,12(%ecx)
  49         movl    %esi,16(%ecx)
  50         movl    %edi,20(%ecx)
  51
  52         /* Check if we should save the signal mask, and remember it. */
  53         movl    8(%esp),%eax
  54         movl    %eax,40(%ecx)
  55         testl   %eax,%eax
  56         jz      2f                      /* no, skip */
  57
  58         /* Get the signal mask. */
  59         leal    24(%ecx),%edx
  60
  61         PIC_PROLOGUE
  62         pushl   %edx
  63         pushl   $0
  64         pushl   $0
  65 #ifdef __PIC__
  66         call    PIC_PLT(_C_LABEL(__sigprocmask14))
  67 #else
  68         call    _C_LABEL(__sigprocmask14)
  69 #endif
  70         addl    $12,%esp
  71         PIC_EPILOGUE
  72
  73 2:      xorl    %eax,%eax
  74         ret
  75 END(__sigsetjmp14)
  76
  77 ENTRY(__siglongjmp14)
  78         /* Check to see if we need to restore the signal mask. */
  79         movl    4(%esp),%ecx
  80         cmpl    $0,40(%ecx)
  81         jz      2f                      /* no, skip */
  82
  83         /* Restore the signal mask. */
  84         leal    24(%ecx),%edx
  85
  86         PIC_PROLOGUE
  87         pushl   $0
  88         pushl   %edx
  89         pushl   $3                      /* SIG_SETMASK */
  90 #ifdef __PIC__
  91         call    PIC_PLT(_C_LABEL(__sigprocmask14))
  92 #else
  93         call    _C_LABEL(__sigprocmask14)
  94 #endif
  95         addl    $12,%esp
  96         PIC_EPILOGUE
  97
  98 2:      movl    4(%esp),%edx
  99         movl    8(%esp),%eax
 100         movl    0(%edx),%ecx
 101         movl    4(%edx),%ebx
 102         movl    8(%edx),%esp
 103         movl    12(%edx),%ebp
 104         movl    16(%edx),%esi
 105         movl    20(%edx),%edi
 106         testl   %eax,%eax
 107         jnz     3f
 108         incl    %eax
 109 3:      movl    %ecx,0(%esp)
 110         ret
 111 END(__siglongjmp14)