lib/libc/arch/m68k/sys/__clone.S

   1 /*      $NetBSD: __clone.S,v 1.5 2013/07/16 23:00:15 matt Exp $ */
   2
   3 /*-
   4  * Copyright (c) 2001 The NetBSD Foundation, Inc.
   5  * All rights reserved.
   6  *
   7  * This code is derived from software contributed to The NetBSD Foundation
   8  * by Steve C. Woodford.
   9  *
  10  * Redistribution and use in source and binary forms, with or without
  11  * modification, are permitted provided that the following conditions
  12  * are met:
  13  * 1. Redistributions of source code must retain the above copyright
  14  *    notice, this list of conditions and the following disclaimer.
  15  * 2. Redistributions in binary form must reproduce the above copyright
  16  *    notice, this list of conditions and the following disclaimer in the
  17  *    documentation and/or other materials provided with the distribution.
  18  *
  19  * THIS SOFTWARE IS PROVIDED BY THE NETBSD FOUNDATION, INC. AND CONTRIBUTORS
  20  * ``AS IS'' AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED
  21  * TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR
  22  * PURPOSE ARE DISCLAIMED.  IN NO EVENT SHALL THE FOUNDATION OR CONTRIBUTORS
  23  * BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR
  24  * CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF
  25  * SUBSTITUTE GOODS OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS
  26  * INTERRUPTION) HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN
  27  * CONTRACT, STRICT LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE)
  28  * ARISING IN ANY WAY OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE
  29  * POSSIBILITY OF SUCH DAMAGE.
  30  */
  31
  32 #include <sys/errno.h>
  33 #include "SYS.h"
  34
  35 #ifdef WEAK_ALIAS
  36 WEAK_ALIAS(clone, __clone)
  37 #endif
  38
  39 /*
  40  * int clone(int (*fn)(void *), void *stack, int flags, void *arg);
  41  */
  42 ENTRY(__clone)
  43         movl    4(%sp),%d0      /* NULL function pointer? */
  44         jeq     2f              /* Yup, bomb out */
  45         movl    %d0,%a1
  46         movl    8(%sp),%d0      /* NULL stack? */
  47         jeq     2f              /* Yup, bomb out */
  48         movl    %d0,%a0
  49         movl    16(%sp),-(%a0)  /* Push clone's `arg' on its new stack */
  50         lea     -12(%a0),%a0    /* Fake syscall args for the clone */
  51         movl    %a0,-(%sp)      /* Syscall arg: stack */
  52         movl    16(%sp),-(%sp)  /* Syscall arg: flags */
  53         clrl    -(%sp)          /* Fake return address */
  54         SYSTRAP(__clone)        /* Note: `fn' in (a1) is preserved */
  55         lea     12(%sp),%sp     /* Zap syscall args */
  56         jcs     3f              /* Punt if syscall failed */
  57         tstl    %d0
  58         jne     1f              /* We're the parent, just return. */
  59         jsr     (%a1)           /* We're the clone, call the function */
  60         movl    %d0,-(%sp)      /* If clone returns, invoke _exit(3) */
  61         jbsr    PIC_PLT(_C_LABEL(_exit))
  62         /* NOTREACHED */
  63 1:      rts
  64 2:      movl    #EINVAL,%d0
  65 3:      jbra    CERROR
  66 END(__clone)