lib/libc/arch/mips/gen/modf.S

   1 /*      $NetBSD: modf.S,v 1.11 2009/12/14 01:07:42 matt Exp $   */
   2
   3 /*-
   4  * Copyright (c) 1991, 1993, 1995
   5  *      The Regents of the University of California.  All rights reserved.
   6  *
   7  * This code is derived from software contributed to Berkeley by
   8  * Ralph Campbell.
   9  *
  10  * Redistribution and use in source and binary forms, with or without
  11  * modification, are permitted provided that the following conditions
  12  * are met:
  13  * 1. Redistributions of source code must retain the above copyright
  14  *    notice, this list of conditions and the following disclaimer.
  15  * 2. Redistributions in binary form must reproduce the above copyright
  16  *    notice, this list of conditions and the following disclaimer in the
  17  *    documentation and/or other materials provided with the distribution.
  18  * 3. Neither the name of the University nor the names of its contributors
  19  *    may be used to endorse or promote products derived from this software
  20  *    without specific prior written permission.
  21  *
  22  * THIS SOFTWARE IS PROVIDED BY THE REGENTS AND CONTRIBUTORS ``AS IS'' AND
  23  * ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE
  24  * IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE
  25  * ARE DISCLAIMED.  IN NO EVENT SHALL THE REGENTS OR CONTRIBUTORS BE LIABLE
  26  * FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL
  27  * DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS
  28  * OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION)
  29  * HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT
  30  * LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY
  31  * OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF
  32  * SUCH DAMAGE.
  33  */
  34
  35 #include <mips/asm.h>
  36
  37 #if defined(LIBC_SCCS) && !defined(lint)
  38 #if 0
  39         RCSID("from: @(#)modf.s 8.1 (Berkeley) 6/4/93")
  40 #else
  41         RCSID("$NetBSD: modf.S,v 1.11 2009/12/14 01:07:42 matt Exp $")
  42 #endif
  43 #endif /* LIBC_SCCS and not lint */
  44
  45 /*
  46  * double modf(val, iptr)
  47  *      double val, *iptr;
  48  * returns: xxx and n (in *iptr) where val == n.xxx
  49  */
  50 LEAF(modf)
  51         cfc1    t0, $31                 # get the control register
  52         li.d    $f2, 4503599627370496e0 # f2 <- 2^52
  53
  54         or      t1, t0, 0x3             # set rounding mode to round to zero
  55         xor     t1, t1, 0x2             #  (i.e., 01)
  56         ctc1    t1, $31
  57
  58         mov.d   $f0, $f12               # f0 <- f12
  59         abs.d   $f4, $f12               # f4 <- |f12|
  60         c.olt.d $f4, $f2                # f4 ? < f2
  61         bc1f    1f                      # leave f0 alone if Nan, infinity
  62                                         # or >=2^52
  63         c.eq.d  $f12,$f4                # was f12 positive ?
  64         add.d   $f4,$f2,$f4             # round off to integer
  65         bc1f    2f                      # No -> will have to negate result
  66         sub.d   $f0,$f4,$f2             # Remove fudge factor
  67         j       1f                      # integer fraction got
  68 2:
  69         sub.d   $f0,$f2,$f4             # Remove fudge factor and negate
  70 1:
  71         ctc1    t0, $31                 # restore old rounding mode
  72         s.d     $f0, 0(a2)              # save the integer part
  73         sub.d   $f0, $f12, $f0          # subtract val - integer part
  74         j       ra
  75 END(modf)