lib/libc/arch/or1k/gen/swapcontext.S

   1 /*      $NetBSD: swapcontext.S,v 1.1 2014/09/03 19:34:25 matt Exp $     */
   2
   3 /*-
   4  * Copyright (c) 2001 The NetBSD Foundation, Inc.
   5  * All rights reserved.
   6  *
   7  * This code is derived from software contributed to The NetBSD Foundation
   8  * by Klaus Klein.
   9  *
  10  * Redistribution and use in source and binary forms, with or without
  11  * modification, are permitted provided that the following conditions
  12  * are met:
  13  * 1. Redistributions of source code must retain the above copyright
  14  *    notice, this list of conditions and the following disclaimer.
  15  * 2. Redistributions in binary form must reproduce the above copyright
  16  *    notice, this list of conditions and the following disclaimer in the
  17  *    documentation and/or other materials provided with the distribution.
  18  *
  19  * THIS SOFTWARE IS PROVIDED BY THE NETBSD FOUNDATION, INC. AND CONTRIBUTORS
  20  * ``AS IS'' AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED
  21  * TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR
  22  * PURPOSE ARE DISCLAIMED.  IN NO EVENT SHALL THE FOUNDATION OR CONTRIBUTORS
  23  * BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR
  24  * CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF
  25  * SUBSTITUTE GOODS OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS
  26  * INTERRUPTION) HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN
  27  * CONTRACT, STRICT LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE)
  28  * ARISING IN ANY WAY OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE
  29  * POSSIBILITY OF SUCH DAMAGE.
  30  */
  31
  32 #include "SYS.h"
  33 #include "assym.h"
  34
  35 __RCSID("$NetBSD: swapcontext.S,v 1.1 2014/09/03 19:34:25 matt Exp $")
  36
  37 #define CALLFRAME_LR    (-1*4)
  38 #define CALLFRAME_UCP   (-2*4)
  39 #define CALLFRAME_OUCP  (-3*4)
  40 #define CALLFRAME_GP    (-4*4)
  41 #define CALLFRAME_SP    (-5*4)
  42 #define CALLFRAME_LEN   (-CALLFRAME_SP)
  43
  44 ENTRY(swapcontext)
  45         l.sw    CALLFRAME_LR(r1),lr             # save link register
  46         l.sw    CALLFRAME_OUCP(r1),r3           # save oucp
  47         l.sw    CALLFRAME_UCP(r1),r4            # save ucp
  48         l.sw    CALLFRAME_SP(r1),r1             # set up stack chain
  49 #ifdef __PIC__
  50         l.sw    CALLFRAME_GP(r1),r16            # save r16
  51         PIC_GOTSETUP(r16)                       # setup got pointer
  52 #endif
  53         l.addi  r1,r1,-CALLFRAME_LEN            # adjust stack
  54         l.jal   PLT(_C_LABEL(_getcontext))      # getcontext(oucp)
  55         l.nop                                   # -- delay slot --
  56         l.sfeqi r11,0                           # error?
  57         l.bnf   1f                              #   yes, cleanup
  58         l.nop                                   #   -- delay slot --
  59         l.addi  r5,r1,CALLFRAME_LEN             # adjust stack
  60         l.lwz   r4,CALLFRAME_OUCP(r5)           # load oucp for adjustment
  61         l.sw    UC_GREGS_PC(r4),lr              # pc <- lr
  62         l.sw    UC_GREGS_SP(r4),r1              # adjust sp
  63         l.lwz   r3,CALLFRAME_UCP(r5)            # load ucp
  64         # can't do a tail call due to needing r16 for PLT
  65         l.jal   PLT(_C_LABEL(setcontext))       # setcontext(ucp)
  66         l.nop                                   # -- delay slot --
  67 1:
  68         l.addi  r1,r1,CALLFRAME_LEN             # restore stack
  69 #ifdef __PIC__
  70         l.lwz   r16,CALLFRAME_GP(r1)            # restore r16
  71 #endif
  72         l.lwz   lr,CALLFRAME_LR(r1)             # refetch lr
  73         l.jr    lr                              # simply return
  74         l.nop                                   # -- delay slot --
  75 END(swapcontext)