lib/libc/arch/sparc/gen/setjmp.S

   1 /*      $NetBSD: setjmp.S,v 1.12 2011/04/30 23:41:13 martin Exp $       */
   2
   3 /*
   4  * Copyright (c) 1992, 1993
   5  *      The Regents of the University of California.  All rights reserved.
   6  *
   7  * This software was developed by the Computer Systems Engineering group
   8  * at Lawrence Berkeley Laboratory under DARPA contract BG 91-66 and
   9  * contributed to Berkeley.
  10  *
  11  * Redistribution and use in source and binary forms, with or without
  12  * modification, are permitted provided that the following conditions
  13  * are met:
  14  * 1. Redistributions of source code must retain the above copyright
  15  *    notice, this list of conditions and the following disclaimer.
  16  * 2. Redistributions in binary form must reproduce the above copyright
  17  *    notice, this list of conditions and the following disclaimer in the
  18  *    documentation and/or other materials provided with the distribution.
  19  * 3. Neither the name of the University nor the names of its contributors
  20  *    may be used to endorse or promote products derived from this software
  21  *    without specific prior written permission.
  22  *
  23  * THIS SOFTWARE IS PROVIDED BY THE REGENTS AND CONTRIBUTORS ``AS IS'' AND
  24  * ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE
  25  * IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE
  26  * ARE DISCLAIMED.  IN NO EVENT SHALL THE REGENTS OR CONTRIBUTORS BE LIABLE
  27  * FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL
  28  * DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS
  29  * OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION)
  30  * HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT
  31  * LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY
  32  * OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF
  33  * SUCH DAMAGE.
  34  *
  35  * from: Header: setjmp.s,v 1.2 92/06/25 03:18:43 torek Exp
  36  */
  37
  38 #include <machine/asm.h>
  39 #if defined(LIBC_SCCS) && !defined(lint)
  40 #if 0
  41         .asciz "@(#)setjmp.s    8.1 (Berkeley) 6/4/93"
  42 #else
  43         RCSID("$NetBSD: setjmp.S,v 1.12 2011/04/30 23:41:13 martin Exp $")
  44 #endif
  45 #endif /* LIBC_SCCS and not lint */
  46
  47 /*
  48  * C library -- setjmp, longjmp
  49  *
  50  *      longjmp(a,v)
  51  * will generate a "return(v)" from
  52  * the last call to
  53  *      setjmp(a)
  54  * by restoring registers from the stack,
  55  * and a struct sigcontext, see <signal.h>
  56  */
  57
  58 #include "SYS.h"
  59
  60 ENTRY(__setjmp14)
  61         save    %sp, -CCFSZ, %sp
  62         /*
  63          * local vars on stack: struct sigstack foo @ offset 0x48
  64          * Note: sc_g1 is not used; sc_o0 is set in longjmp()
  65          */
  66         mov     1, %o0          /* SIG_BLOCK */
  67         add     %i0, 32, %o2    /* build sigcontext sc.sc_mask */
  68         call    _C_LABEL(__sigprocmask14)
  69          clr    %o1             /* sigprocmask(SIG_BLOCK, NULL, &sc.sc_mask) */
  70
  71         add     %sp, 0x48, %o1  /* (foo being in arg dump area) */
  72         call    _C_LABEL(__sigaltstack14)
  73          clr    %o0             /* sigstack(NULL, &foo) */
  74
  75         ld      [%sp + 0x48 + 8], %o0   /* foo.ss_flags */
  76         and     %o0, 1, %o1     /* onstack = foo.ss_flags & 1; */
  77         st      %o1, [%i0 + 0]  /* sc.sc_onstack = current onstack; */
  78         st      %fp, [%i0 + 8]  /* sc.sc_sp = (caller's) sp */
  79         add     %i7, 8, %o0
  80         st      %o0, [%i0 + 12] /* sc.sc_pc = return_pc */
  81         st      %g3, [%i0 + 16] /* sc.sc_npc */
  82         st      %g0, [%i0 + 20] /* sc.sc_psr = (clean psr) */
  83         st      %g2, [%i0 + 24]
  84         st      %g4, [%i0 + 48]
  85         st      %g7, [%i0 + 52]
  86         ret                     /* return 0 */
  87          restore        %g0, %g0, %o0
  88