lib/libc/arch/sparc64/gen/fixunsdfsi.S

   1 /*      $NetBSD: fixunsdfsi.S,v 1.5 2013/09/12 15:36:16 joerg Exp $     */
   2
   3 /*
   4  * Copyright (c) 1992, 1993
   5  *      The Regents of the University of California.  All rights reserved.
   6  *
   7  * This software was developed by the Computer Systems Engineering group
   8  * at Lawrence Berkeley Laboratory under DARPA contract BG 91-66 and
   9  * contributed to Berkeley.
  10  *
  11  * Redistribution and use in source and binary forms, with or without
  12  * modification, are permitted provided that the following conditions
  13  * are met:
  14  * 1. Redistributions of source code must retain the above copyright
  15  *    notice, this list of conditions and the following disclaimer.
  16  * 2. Redistributions in binary form must reproduce the above copyright
  17  *    notice, this list of conditions and the following disclaimer in the
  18  *    documentation and/or other materials provided with the distribution.
  19  * 3. Neither the name of the University nor the names of its contributors
  20  *    may be used to endorse or promote products derived from this software
  21  *    without specific prior written permission.
  22  *
  23  * THIS SOFTWARE IS PROVIDED BY THE REGENTS AND CONTRIBUTORS ``AS IS'' AND
  24  * ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE
  25  * IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE
  26  * ARE DISCLAIMED.  IN NO EVENT SHALL THE REGENTS OR CONTRIBUTORS BE LIABLE
  27  * FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL
  28  * DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS
  29  * OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION)
  30  * HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT
  31  * LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY
  32  * OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF
  33  * SUCH DAMAGE.
  34  *
  35  * from: Header: fixunsdfsi.s,v 1.3 91/10/08 00:03:15 torek Exp
  36  */
  37
  38 #include <machine/asm.h>
  39 #define _LOCORE
  40 #include <machine/frame.h>
  41 #if defined(LIBC_SCCS) && !defined(lint)
  42 #if 0
  43         .asciz "@(#)fixunsdfsi.s        8.1 (Berkeley) 6/4/93"
  44 #else
  45         RCSID("$NetBSD: fixunsdfsi.S,v 1.5 2013/09/12 15:36:16 joerg Exp $")
  46 #endif
  47 #endif /* LIBC_SCCS and not lint */
  48
  49 /*
  50  * Convert double to unsigned integer (for gcc).
  51  *
  52  * I have made the output for NaN agree with the Sun compiler, not
  53  * that it really matters, by using `fbul,a'.
  54  */
  55
  56
  57         .align  8
  58 Lbig:
  59         .word   0x43e00000              ! .double 2^63
  60         .word   0                       ! (who me, not trust the assembler?)
  61
  62 /*
  63  * Same as above but to unsigned long
  64  */
  65 ENTRY(__dtoul)
  66         sub     %sp, 16, %sp
  67         std     %f2, [%sp + 64 + BIAS + 8]
  68 #ifdef __PIC__
  69         PICCY_SET(Lbig, %g1, %o0)
  70         ldd     [%g1], %f2
  71 #else
  72         sethi   %hi(Lbig), %g1
  73         ldd     [%g1 + %lo(Lbig)], %f2
  74 #endif
  75         fcmped  %f0, %f2                ! d < 2^63, or NaN, or -Inf?
  76         nop                             ! (fpop2 delay)
  77         fbul,a  1f                      ! if so, use fdtoi to convert to int
  78          fdtox  %f0, %f0                !        (this includes negatives!)
  79
  80         ! d does not fit in an int, so subtract 2^63, convert,
  81         ! and add 2^63 again (sigh).  Just hope the intermediate
  82         ! fits (if not, the result is undefined anyway).
  83
  84         fsubd   %f0, %f2, %f0           ! d -= 2^63
  85         fdtox   %f0, %f0                ! convert to int
  86         std     %f0, [%sp + 64 + BIAS]  ! move into return reg
  87         ldx     [%sp + 64 + BIAS], %o0
  88         sethi   %hi(0x80000000), %o1
  89         sllx    %o1, 32, %o1
  90         add     %o0, %o1, %o0           ! add 2^63
  91         ldd     [%sp + 64 + BIAS + 8], %f2
  92         retl
  93          add    %sp, 16, %sp
  94
  95 1:
  96         std     %f0, [%sp + 64 + BIAS]  ! return result
  97         ldx     [%sp + 64 + BIAS], %o0
  98         ldd     [%sp + 64 + BIAS + 8], %f2
  99         retl
 100          add    %sp, 16, %sp