lib/libc/arch/sparc64/gen/setjmp.S

   1 /*      $NetBSD: setjmp.S,v 1.10 2013/09/12 15:36:16 joerg Exp $        */
   2
   3 /*
   4  * Copyright (c) 1992, 1993
   5  *      The Regents of the University of California.  All rights reserved.
   6  *
   7  * This software was developed by the Computer Systems Engineering group
   8  * at Lawrence Berkeley Laboratory under DARPA contract BG 91-66 and
   9  * contributed to Berkeley.
  10  *
  11  * Redistribution and use in source and binary forms, with or without
  12  * modification, are permitted provided that the following conditions
  13  * are met:
  14  * 1. Redistributions of source code must retain the above copyright
  15  *    notice, this list of conditions and the following disclaimer.
  16  * 2. Redistributions in binary form must reproduce the above copyright
  17  *    notice, this list of conditions and the following disclaimer in the
  18  *    documentation and/or other materials provided with the distribution.
  19  * 3. Neither the name of the University nor the names of its contributors
  20  *    may be used to endorse or promote products derived from this software
  21  *    without specific prior written permission.
  22  *
  23  * THIS SOFTWARE IS PROVIDED BY THE REGENTS AND CONTRIBUTORS ``AS IS'' AND
  24  * ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE
  25  * IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE
  26  * ARE DISCLAIMED.  IN NO EVENT SHALL THE REGENTS OR CONTRIBUTORS BE LIABLE
  27  * FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL
  28  * DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS
  29  * OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION)
  30  * HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT
  31  * LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY
  32  * OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF
  33  * SUCH DAMAGE.
  34  *
  35  * from: Header: setjmp.s,v 1.2 92/06/25 03:18:43 torek Exp
  36  */
  37
  38 #define _LOCORE
  39 #include <machine/asm.h>
  40 #include <machine/frame.h>
  41 #if defined(LIBC_SCCS) && !defined(lint)
  42 #if 0
  43         .asciz "@(#)setjmp.s    8.1 (Berkeley) 6/4/93"
  44 #else
  45         RCSID("$NetBSD: setjmp.S,v 1.10 2013/09/12 15:36:16 joerg Exp $")
  46 #endif
  47 #endif /* LIBC_SCCS and not lint */
  48
  49 /*
  50  * C library -- setjmp
  51  *
  52  *      __longjmp14(a,v)
  53  * will generate a "return(v)" from
  54  * the last call to
  55  *      setjmp(a)
  56  * by restoring registers from the stack,
  57  * and a struct sigcontext, see <signal.h>
  58  */
  59
  60 #include "SYS.h"
  61
  62         .register %g2,#ignore
  63         .register %g3,#ignore
  64         .register %g6,#ignore
  65
  66 ENTRY(__setjmp14)
  67         save    %sp, -CC64FSZ, %sp
  68
  69         /* save globals into locals */
  70         mov     %g1, %l1
  71         mov     %g2, %l2
  72         mov     %g3, %l3
  73         mov     %g4, %l4
  74         mov     %g5, %l5
  75         mov     %g6, %l6
  76         mov     %g7, %l7
  77
  78 #ifdef __PIC__
  79         PIC_PROLOGUE(%i1, %o4)
  80 #endif
  81
  82         /* now get sigmask and onstack flag */
  83         add     %i0, 0x38, %o2          /* build sigcontext in [%o2]->sc.sc_mask */
  84         mov     1, %o0                  /* SIG_BLOCK */
  85                                         /* sigprocmask(SIG_BLOCK, (sigset_t *)NULL, (sigset_t *)a) */
  86 #if __PIC__ - 0 >= 2
  87         set     _C_LABEL(__sigprocmask14), %o4
  88         ldx     [%i1 + %o4], %g2
  89         call    %g2
  90 #elif __PIC__ - 0 >= 1
  91         ldx     [%i1 + _C_LABEL(__sigprocmask14)], %g2
  92         call    %g2
  93 #else
  94         call    _C_LABEL(__sigprocmask14)
  95 #endif
  96          clr    %o1
  97
  98         clr     %o0                     /* sigstack(NULL, &foo) */
  99 #if __PIC__ - 0 >= 2
 100         set     _C_LABEL(__sigaltstack14), %o4
 101         ldx     [%i1 + %o4], %g2
 102         call    %g2
 103 #elif __PIC__ - 0 >= 1
 104         ldx     [%i1 + _C_LABEL(__sigaltstack14)], %g2
 105         call    %g2
 106 #else
 107         call    _C_LABEL(__sigaltstack14)
 108 #endif
 109          add    %i0, 8, %o1             /* (foo being part of the sigcontext we're overwriting) */
 110
 111         lduw    [%i0 + 8 + 0x10], %o0   /* foo.ss_flags */
 112         and     %o0, 1, %o1             /* onstack = foo.ss_flags & SS_ONSTACK; */
 113         st      %o1, [%i0 + 0x00]       /* sc.sc_onstack = current onstack; */
 114
 115         /* store essential state */
 116         stx     %fp, [%i0 + 0x08]       /* sc.sc_sp = sp */
 117         add     %i7, 8, %o0
 118         stx     %o0, [%i0 + 0x10]       /* sc.sc_pc = return_pc */
 119         stx     %g0, [%i0 + 0x20]       /* sc.sc_tstate = (clean ccr) */
 120         stx     %l1, [%i0 + 0x28]       /* sc.sc_g1 */
 121         stx     %l2, [%i0 + 0x30]       /* sc.sc_o0, set in longjmp, use as %g2 */
 122         /* 0x38: 4x32bit */             /* sc.sc_mask was already saved above */
 123
 124         /* save additional registers needed to fill a complete mcontext */
 125         stx     %l3, [%i0 + 0x48]       /* adjust asserts in longjmp.c */
 126         stx     %l6, [%i0 + 0x50]       /* if you change any of these */
 127         stx     %l7, [%i0 + 0x58]       /* offsets! */
 128
 129         ret                             /* return 0 */
 130          restore %g0, 0, %o0