lib/libc/arch/vax/gen/__setjmp14.S

   1 /*
   2  * Copyright (c) 1983, 1993
   3  *      The Regents of the University of California.  All rights reserved.
   4  *
   5  * Redistribution and use in source and binary forms, with or without
   6  * modification, are permitted provided that the following conditions
   7  * are met:
   8  * 1. Redistributions of source code must retain the above copyright
   9  *    notice, this list of conditions and the following disclaimer.
  10  * 2. Redistributions in binary form must reproduce the above copyright
  11  *    notice, this list of conditions and the following disclaimer in the
  12  *    documentation and/or other materials provided with the distribution.
  13  * 3. Neither the name of the University nor the names of its contributors
  14  *    may be used to endorse or promote products derived from this software
  15  *    without specific prior written permission.
  16  *
  17  * THIS SOFTWARE IS PROVIDED BY THE REGENTS AND CONTRIBUTORS ``AS IS'' AND
  18  * ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE
  19  * IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE
  20  * ARE DISCLAIMED.  IN NO EVENT SHALL THE REGENTS OR CONTRIBUTORS BE LIABLE
  21  * FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL
  22  * DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS
  23  * OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION)
  24  * HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT
  25  * LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY
  26  * OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF
  27  * SUCH DAMAGE.
  28  */
  29
  30 /*
  31  * C library -- setjmp, longjmp
  32  *
  33  *      longjmp(a,v)
  34  * will generate a "return(v)" from
  35  * the last call to
  36  *      setjmp(a)
  37  * by restoring registers from the stack,
  38  * and a struct sigcontext, see <signal.h>
  39  */
  40
  41 #include "DEFS.h"
  42 #include "assym.h"
  43
  44 #if defined(LIBC_SCCS) && !defined(lint)
  45         /* .asciz "@(#)setjmp.s 8.1 (Berkeley) 6/4/93" */
  46 RCSID("$NetBSD: __setjmp14.S,v 1.11 2011/01/25 02:38:15 matt Exp $")
  47 #endif /* LIBC_SCCS and not lint */
  48
  49 ENTRY(__setjmp14, R6)
  50         movl    4(%ap),%r2              # construct sigcontext
  51         subl2   $12,%sp                 # space for current struct sigstack
  52         pushl   %sp                     # get current values
  53         pushl   $0                      # no new values
  54         calls   $4,_C_LABEL(__sigaltstack14) # pop args plus signal stack value
  55         movl    4(%ap),%r2              # construct sigcontext
  56         movl    (%sp)+,(%r2)            # save onsigstack status of caller
  57         pushal  28(%r2)
  58         pushl   $0
  59         pushl   $0
  60         calls   $3,_C_LABEL(__sigprocmask14) # get signal mask
  61         addl3   $8,4(%ap),%r2           # point to sp in signal context
  62         clrl    %r0                     # assume no stack arguments
  63         bbc     $13,6(%fp),1f           # handle callg
  64         addl3   $1,(%ap),%r0            # get argument count +1 if calls
  65 1:      moval   24(%fp)[%r0],(%r2)+     # save sp of caller
  66         movl    12(%fp),(%r2)+          # save frame pointer of caller
  67         movl    8(%fp),(%r2)+           # save argument pointer of caller
  68         movl    16(%fp),(%r2)+          # save pc of caller
  69         movpsl  (%r2)                   # save current psl
  70         movw    4(%fp),(%r2)            # save psw of caller
  71         addl3   $SC_LEN,4(%ap),%r2      # point to past signal context
  72         movq    %r6,(%r2)+              # save r6/r7
  73         movq    %r8,(%r2)+              # save r8/r9
  74         movq    %r10,(%r2)+             # save r10/r11
  75         clrl    %r0
  76         ret
  77 END(__setjmp14)