lib/libc/arch/x86_64/gen/_setjmp.S

   1 /*      $NetBSD: _setjmp.S,v 1.2 2014/05/22 15:01:56 uebayasi Exp $     */
   2
   3 /*
   4  * Copyright (c) 2001 Wasabi Systems, Inc.
   5  * All rights reserved.
   6  *
   7  * Written by Frank van der Linden for Wasabi Systems, Inc.
   8  *
   9  * Redistribution and use in source and binary forms, with or without
  10  * modification, are permitted provided that the following conditions
  11  * are met:
  12  * 1. Redistributions of source code must retain the above copyright
  13  *    notice, this list of conditions and the following disclaimer.
  14  * 2. Redistributions in binary form must reproduce the above copyright
  15  *    notice, this list of conditions and the following disclaimer in the
  16  *    documentation and/or other materials provided with the distribution.
  17  * 3. All advertising materials mentioning features or use of this software
  18  *    must display the following acknowledgement:
  19  *      This product includes software developed for the NetBSD Project by
  20  *      Wasabi Systems, Inc.
  21  * 4. The name of Wasabi Systems, Inc. may not be used to endorse
  22  *    or promote products derived from this software without specific prior
  23  *    written permission.
  24  *
  25  * THIS SOFTWARE IS PROVIDED BY WASABI SYSTEMS, INC. ``AS IS'' AND
  26  * ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED
  27  * TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR
  28  * PURPOSE ARE DISCLAIMED.  IN NO EVENT SHALL WASABI SYSTEMS, INC
  29  * BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR
  30  * CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF
  31  * SUBSTITUTE GOODS OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS
  32  * INTERRUPTION) HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN
  33  * CONTRACT, STRICT LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE)
  34  * ARISING IN ANY WAY OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE
  35  * POSSIBILITY OF SUCH DAMAGE.
  36  */
  37
  38
  39 #include <machine/asm.h>
  40 #include <machine/setjmp.h>
  41 #if defined(LIBC_SCCS)
  42         RCSID("$NetBSD: _setjmp.S,v 1.2 2014/05/22 15:01:56 uebayasi Exp $")
  43 #endif
  44
  45 /*
  46  * C library -- _setjmp, _longjmp
  47  *
  48  *      _longjmp(a,v)
  49  * will generate a "return(v)" from the last call to
  50  *      _setjmp(a)
  51  * by restoring registers from the stack.
  52  * The previous signal state is NOT restored.
  53  */
  54
  55 ENTRY(_setjmp)
  56         movq    (%rsp),%r11
  57         movq    %rbx,(_JB_RBX * 8)(%rdi)
  58         movq    %rbp,(_JB_RBP * 8)(%rdi)
  59         movq    %r12,(_JB_R12 * 8)(%rdi)
  60         movq    %r13,(_JB_R13 * 8)(%rdi)
  61         movq    %r14,(_JB_R14 * 8)(%rdi)
  62         movq    %r15,(_JB_R15 * 8)(%rdi)
  63         movq    %rsp,(_JB_RSP * 8)(%rdi)
  64         movq    %r11,(_JB_PC  * 8)(%rdi)
  65
  66         xorl    %eax,%eax
  67         ret
  68 END(_setjmp)
  69
  70 ENTRY(_longjmp)
  71         movq    (_JB_RBX * 8)(%rdi),%rbx
  72         movq    (_JB_RBP * 8)(%rdi),%rbp
  73         movq    (_JB_R12 * 8)(%rdi),%r12
  74         movq    (_JB_R13 * 8)(%rdi),%r13
  75         movq    (_JB_R14 * 8)(%rdi),%r14
  76         movq    (_JB_R15 * 8)(%rdi),%r15
  77         movq    (_JB_RSP * 8)(%rdi),%rsp
  78         movq    (_JB_PC  * 8)(%rdi),%r11
  79
  80         movl    %esi,%eax
  81         testl   %eax,%eax
  82         jnz     1f
  83         incl    %eax
  84 1:      movq    %r11,0(%rsp)
  85         ret
  86 END(_longjmp)