lib/libc/compat/arch/sparc64/gen/compat_setjmp.S

   1 /*      $NetBSD: compat_setjmp.S,v 1.1 2005/10/16 04:41:34 christos Exp $       */
   2
   3 /*
   4  * Copyright (c) 1992, 1993
   5  *      The Regents of the University of California.  All rights reserved.
   6  *
   7  * This software was developed by the Computer Systems Engineering group
   8  * at Lawrence Berkeley Laboratory under DARPA contract BG 91-66 and
   9  * contributed to Berkeley.
  10  *
  11  * Redistribution and use in source and binary forms, with or without
  12  * modification, are permitted provided that the following conditions
  13  * are met:
  14  * 1. Redistributions of source code must retain the above copyright
  15  *    notice, this list of conditions and the following disclaimer.
  16  * 2. Redistributions in binary form must reproduce the above copyright
  17  *    notice, this list of conditions and the following disclaimer in the
  18  *    documentation and/or other materials provided with the distribution.
  19  * 3. Neither the name of the University nor the names of its contributors
  20  *    may be used to endorse or promote products derived from this software
  21  *    without specific prior written permission.
  22  *
  23  * THIS SOFTWARE IS PROVIDED BY THE REGENTS AND CONTRIBUTORS ``AS IS'' AND
  24  * ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE
  25  * IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE
  26  * ARE DISCLAIMED.  IN NO EVENT SHALL THE REGENTS OR CONTRIBUTORS BE LIABLE
  27  * FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL
  28  * DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS
  29  * OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION)
  30  * HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT
  31  * LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY
  32  * OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF
  33  * SUCH DAMAGE.
  34  *
  35  * from: Header: setjmp.s,v 1.2 92/06/25 03:18:43 torek Exp
  36  */
  37
  38 #define _LOCORE
  39 #include <machine/asm.h>
  40 #include <machine/frame.h>
  41 #if defined(LIBC_SCCS) && !defined(lint)
  42 #if 0
  43         .asciz "@(#)setjmp.s    8.1 (Berkeley) 6/4/93"
  44 #else
  45         RCSID("$NetBSD: compat_setjmp.S,v 1.1 2005/10/16 04:41:34 christos Exp $")
  46 #endif
  47 #endif /* LIBC_SCCS and not lint */
  48
  49 /*
  50  * C library -- setjmp, longjmp
  51  *
  52  *      longjmp(a,v)
  53  * will generate a "return(v)" from
  54  * the last call to
  55  *      setjmp(a)
  56  * by restoring registers from the stack,
  57  * and a struct sigcontext, see <signal.h>
  58  */
  59
  60 #include "SYS.h"
  61
  62 #define STACK_T_SZ
  63 ENTRY(setjmp)
  64         /*
  65          * We use the part of the sigcontext structure, the sp, pc, and npc fields,
  66          * for the sigstack call so we don't need to get our own stackframe.  It
  67          * won't be filled out till later anyway.
  68          */
  69         mov     %o0, %o3                /* Save our jmp_buf in %o3 */
  70         mov     %o0, %o2                /* build sigcontext in [%o2] */
  71         mov     1, %o0                  /* SIG_BLOCK */
  72         mov     SYS_compat_13_sigprocmask13, %g1
  73         clr     %o1                     /* sigprocmask(SIG_BLOCK, (sigset_t *)NULL, (sigset_t *)a) */
  74         t       ST_SYSCALL
  75
  76         st      %o0, [%o3 + 0x04]       /* sc.sc_mask = current mask; */
  77         mov     SYS___sigaltstack14, %g1
  78         clr     %o0                     /* sigstack(NULL, &foo) */
  79         add     %o3, 0x38, %o1          /* (foo being the sigcontext14 sc_mask) */
  80         t       ST_SYSCALL
  81
  82         lduw    [%o3 + 0x38+0x10], %o0  /* foo.ss_flags */
  83         and     %o0, 1, %o1             /* onstack = foo.ss_flags & 1; */
  84         st      %o0, [%o3 + 0x00]       /* sc.sc_onstack = current onstack; */
  85         stx     %sp, [%o3 + 0x08]       /* sc.sc_sp = sp (both ours and caller's) */
  86         add     %o7, 8, %o0
  87         stx     %o0, [%o3 + 0x10]       /* sc.sc_pc = return_pc */
  88         add     %o7, 12, %o0
  89         stx     %o0, [%o3 + 0x18]       /* sc.sc_npc = return_pc + 4 */
  90         stx     %g0, [%o3 + 0x20]       /* sc.sc_psr = (clean psr) */
  91         stx     %fp, [%o3 + 0x28]       /* sc.sc_g1 = %fp (misuse, but what the heck) */
  92                                         /* sc.sc_o0 = random(), set in longjmp */
  93         retl                            /* return 0 */
  94          clr    %o0
  95
  96 /*
  97  * All we need to do here is force sigreturn to load a new stack pointer,
  98  * new <pc,npc>, and appropriate %o0 return value from the sigcontext built
  99  * in setjmp.  The %i and %l registers will be reloaded from the place to
 100  * which %sp points, due to sigreturn() semantics (sigreturn does not modify
 101  * the window pointer in the psr, hence it must force all windows to reload).
 102  */
 103 ENTRY(longjmp)
 104         save    %sp, -CC64FSZ, %sp
 105         ldx     [%i0 + 0x08], %o2       /* make sure sc->sc_sp, sc->sc_fp nonzero */
 106         ldx     [%i0 + 0x28], %o3
 107         orcc    %o2, %o3, %g0
 108         bz,pn   %xcc, Lbotch
 109          movrz  %i1, 1, %i1             /* if (v == 0) v = 1; */
 110         st      %i1, [%i0 + 0x30]       /* sc.sc_o0 = v; */
 111         mov     SYS_compat_13_sigreturn13, %g1
 112         mov     %i0, %o0
 113         t       ST_SYSCALL              /* sigreturn(scp); */
 114
 115 Lbotch:
 116         /* oops, caller botched it */
 117         call    _C_LABEL(longjmperror)
 118          nop
 119         unimp   0