lib/libm/arch/vax/n_tan.S

   1 /*      $NetBSD: n_tan.S,v 1.7 2014/03/06 10:59:52 martin Exp $ */
   2 /*
   3  * Copyright (c) 1985, 1993
   4  *      The Regents of the University of California.  All rights reserved.
   5  *
   6  * Redistribution and use in source and binary forms, with or without
   7  * modification, are permitted provided that the following conditions
   8  * are met:
   9  * 1. Redistributions of source code must retain the above copyright
  10  *    notice, this list of conditions and the following disclaimer.
  11  * 2. Redistributions in binary form must reproduce the above copyright
  12  *    notice, this list of conditions and the following disclaimer in the
  13  *    documentation and/or other materials provided with the distribution.
  14  * 3. Neither the name of the University nor the names of its contributors
  15  *    may be used to endorse or promote products derived from this software
  16  *    without specific prior written permission.
  17  *
  18  * THIS SOFTWARE IS PROVIDED BY THE REGENTS AND CONTRIBUTORS ``AS IS'' AND
  19  * ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE
  20  * IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE
  21  * ARE DISCLAIMED.  IN NO EVENT SHALL THE REGENTS OR CONTRIBUTORS BE LIABLE
  22  * FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL
  23  * DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS
  24  * OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION)
  25  * HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT
  26  * LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY
  27  * OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF
  28  * SUCH DAMAGE.
  29  *
  30  *      @(#)tan.s       8.1 (Berkeley) 6/4/93
  31  */
  32
  33 #include <machine/asm.h>
  34
  35 /*  This is the implementation of Peter Tang's double precision
  36  *  tangent for the VAX using Bob Corbett's argument reduction.
  37  *
  38  *  Notes:
  39  *       under 1,024,000 random arguments testing on [0,2*pi]
  40  *       tan() observed maximum error = 2.15 ulps
  41  *
  42  * double tan(arg)
  43  * double arg;
  44  * method: true range reduction to [-pi/4,pi/4], P. Tang  &  B. Corbett
  45  * S. McDonald, April 4,  1985
  46  */
  47 ENTRY(tan, 0x0fc0)              # save %r6-%r11
  48         movq    4(%ap),%r0
  49         bicw3   $0x807f,%r0,%r2
  50         beql    1f              # if x is zero or reserved operand then return x
  51 /*
  52  * Save the PSL's IV & FU bits on the stack.
  53  */
  54         movpsl  %r2
  55         bicw3   $0xff9f,%r2,-(%sp)
  56 /*
  57  *  Clear the IV & FU bits.
  58  */
  59         bicpsw  $0x0060
  60         jsb     _C_LABEL(__libm_argred)+2
  61 /*
  62  *  At this point,
  63  *         %r0  contains the quadrant number, 0, 1, 2, or 3;
  64  *      %r2/%r1  contains the reduced argument as a D-format number;
  65  *         %r3  contains a F-format extension to the reduced argument;
  66  *
  67  *  Save  %r3/%r0  so that we can call cosine after calling sine.
  68  */
  69         movq    %r2,-(%sp)
  70         movq    %r0,-(%sp)
  71 /*
  72  *  Call sine.  %r4 = 0  implies sine.
  73  */
  74         movl    $0,%r4
  75         jsb     _C_LABEL(__libm_sincos)+2
  76 /*
  77  *  Save  sin(x)  in  %r11/%r10 .
  78  */
  79         movd    %r0,%r10
  80 /*
  81  *  Call cosine.  %r4 = 1  implies cosine.
  82  */
  83         movq    (%sp)+,%r0
  84         movq    (%sp)+,%r2
  85         movl    $1,%r4
  86         jsb     _C_LABEL(__libm_sincos)+2
  87         divd3   %r0,%r10,%r0
  88         bispsw  (%sp)+
  89 1:      ret
  90
  91
  92 ENTRY(tanf, 0)
  93         cvtfd   4(%ap),-(%sp)
  94         calls   $2,_C_LABEL(tan)
  95         cvtdf   %r0,%r0
  96         ret
  97