usr.bin/mkesdb/lex.l

   1 /*      $NetBSD: lex.l,v 1.5 2009/10/29 14:49:03 christos Exp $ */
   2
   3 %{
   4 /*-
   5  * Copyright (c)2003 Citrus Project,
   6  * All rights reserved.
   7  *
   8  * Redistribution and use in source and binary forms, with or without
   9  * modification, are permitted provided that the following conditions
  10  * are met:
  11  * 1. Redistributions of source code must retain the above copyright
  12  *    notice, this list of conditions and the following disclaimer.
  13  * 2. Redistributions in binary form must reproduce the above copyright
  14  *    notice, this list of conditions and the following disclaimer in the
  15  *    documentation and/or other materials provided with the distribution.
  16  *
  17  * THIS SOFTWARE IS PROVIDED BY THE AUTHOR AND CONTRIBUTORS ``AS IS'' AND
  18  * ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE
  19  * IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE
  20  * ARE DISCLAIMED.  IN NO EVENT SHALL THE AUTHOR OR CONTRIBUTORS BE LIABLE
  21  * FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL
  22  * DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS
  23  * OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION)
  24  * HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT
  25  * LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY
  26  * OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF
  27  * SUCH DAMAGE.
  28  */
  29
  30 #if HAVE_NBTOOL_CONFIG_H
  31 #include "nbtool_config.h"
  32 #endif
  33
  34 #include <sys/cdefs.h>
  35 #if !defined(lint)
  36 __RCSID("$NetBSD: lex.l,v 1.5 2009/10/29 14:49:03 christos Exp $");
  37 #endif /* not lint */
  38
  39 #include <assert.h>
  40 #include <errno.h>
  41 #include <limits.h>
  42 #include <stdio.h>
  43 #include <stdlib.h>
  44 #include <string.h>
  45 #include <machine/endian.h>
  46 #include <sys/queue.h>
  47
  48 #include "ldef.h"
  49 #include "yacc.h"
  50
  51 int line_number = 1;
  52
  53 %}
  54
  55 %option noinput nounput
  56 %x      COMMENT
  57
  58 %%
  59
  60 [ \t]+  { }
  61 #.*[\n]|"//".*[\n]|[\n] { line_number++; return (R_LN); }
  62
  63 "/*"            { BEGIN COMMENT; }
  64 <COMMENT>"*/"   { BEGIN 0; }
  65 <COMMENT>[\n]   { line_number++; }
  66 <COMMENT>.      { }
  67 <COMMENT><<EOF>>        {
  68                 yyerror("unexpected file end (unterminate comment)\n");
  69                 exit(1);
  70         }
  71
  72 ([1-9][0-9]*)|(0[0-9]*)|(0[xX][0-9A-Fa-f]+)     {
  73                 yylval.i_value = strtoul(yytext, NULL, 0);
  74                 return L_IMM;
  75         }
  76
  77 "NAME"          { return R_NAME; }
  78 "ENCODING"      { return R_ENCODING; }
  79 "VARIABLE"      { return R_VARIABLE; }
  80 "DEFCSID"       { return R_DEFCSID; }
  81 "INVALID"       { return R_INVALID; }
  82
  83 \"([^\"\n]*(\\\")?)*\"|\'([^\'\n]*(\\\')?)*\'   {
  84                 size_t len;
  85                 len = strlen(yytext);
  86                 yylval.s_value = malloc(len-1);
  87                 strlcpy(yylval.s_value, yytext+1, len-1);
  88                 return L_STRING;
  89         }
  90 [^ =/\-0-9\t\n][^ \t\n]*        {
  91                 yylval.s_value = strdup(yytext);
  92                 return L_STRING;
  93         }
  94
  95 %%
  96
  97 #ifndef yywrap
  98 int
  99 yywrap(void)
 100 {
 101         return (1);
 102 }
 103 #endif