gl/m4/locale-ja.m4

   1 # locale-ja.m4
   2 # serial 18
   3 dnl Copyright (C) 2003, 2005-2024 Free Software Foundation, Inc.
   4 dnl This file is free software; the Free Software Foundation
   5 dnl gives unlimited permission to copy and/or distribute it,
   6 dnl with or without modifications, as long as this notice is preserved.
   7
   8 dnl From Bruno Haible.
   9
  10 dnl Determine the name of a japanese locale with EUC-JP encoding.
  11 AC_DEFUN_ONCE([gt_LOCALE_JA],
  12 [
  13   AC_REQUIRE([AC_CANONICAL_HOST])
  14   AC_REQUIRE([AM_LANGINFO_CODESET])
  15   AC_CACHE_CHECK([for a traditional japanese locale], [gt_cv_locale_ja], [
  16     AC_LANG_CONFTEST([AC_LANG_SOURCE([[
  17 #include <locale.h>
  18 #include <time.h>
  19 #if HAVE_LANGINFO_CODESET
  20 # include <langinfo.h>
  21 #endif
  22 #include <stdlib.h>
  23 #include <string.h>
  24 struct tm t;
  25 char buf[16];
  26 int main ()
  27 {
  28   /* On BeOS and Haiku, locales are not implemented in libc.  Rather, libintl
  29      imitates locale dependent behaviour by looking at the environment
  30      variables, and all locales use the UTF-8 encoding.  */
  31 #if defined __BEOS__ || defined __HAIKU__
  32   return 1;
  33 #else
  34   /* Check whether the given locale name is recognized by the system.  */
  35 # if defined _WIN32 && !defined __CYGWIN__
  36   /* On native Windows, setlocale(category, "") looks at the system settings,
  37      not at the environment variables.  Also, when an encoding suffix such
  38      as ".65001" or ".54936" is specified, it succeeds but sets the LC_CTYPE
  39      category of the locale to "C".  */
  40   if (setlocale (LC_ALL, getenv ("LC_ALL")) == NULL
  41       || strcmp (setlocale (LC_CTYPE, NULL), "C") == 0)
  42     return 1;
  43 # else
  44   if (setlocale (LC_ALL, "") == NULL) return 1;
  45 # endif
  46   /* Check whether nl_langinfo(CODESET) is nonempty and not "ASCII" or "646".
  47      On Mac OS X 10.3.5 (Darwin 7.5) in the fr_FR locale, nl_langinfo(CODESET)
  48      is empty, and the behaviour of Tcl 8.4 in this locale is not useful.
  49      On OpenBSD 4.0, when an unsupported locale is specified, setlocale()
  50      succeeds but then nl_langinfo(CODESET) is "646". In this situation,
  51      some unit tests fail.
  52      On MirBSD 10, when an unsupported locale is specified, setlocale()
  53      succeeds but then nl_langinfo(CODESET) is "UTF-8".  */
  54 # if HAVE_LANGINFO_CODESET
  55   {
  56     const char *cs = nl_langinfo (CODESET);
  57     if (cs[0] == '\0' || strcmp (cs, "ASCII") == 0 || strcmp (cs, "646") == 0
  58         || strcmp (cs, "UTF-8") == 0)
  59       return 1;
  60   }
  61 # endif
  62 # ifdef __CYGWIN__
  63   /* On Cygwin, avoid locale names without encoding suffix, because the
  64      locale_charset() function relies on the encoding suffix.  Note that
  65      LC_ALL is set on the command line.  */
  66   if (strchr (getenv ("LC_ALL"), '.') == NULL) return 1;
  67 # endif
  68   /* Check whether MB_CUR_MAX is > 1.  This excludes the dysfunctional locales
  69      on Cygwin 1.5.x.  */
  70   if (MB_CUR_MAX == 1)
  71     return 1;
  72   /* Check whether in a month name, no byte in the range 0x80..0x9F occurs.
  73      This excludes the UTF-8 encoding (except on MirBSD).  */
  74   {
  75     const char *p;
  76     t.tm_year = 1975 - 1900; t.tm_mon = 2 - 1; t.tm_mday = 4;
  77     if (strftime (buf, sizeof (buf), "%B", &t) < 2) return 1;
  78     for (p = buf; *p != '\0'; p++)
  79       if ((unsigned char) *p >= 0x80 && (unsigned char) *p < 0xa0)
  80         return 1;
  81   }
  82   return 0;
  83 #endif
  84 }
  85       ]])])
  86     if AC_TRY_EVAL([ac_link]) && test -s conftest$ac_exeext; then
  87       case "$host_os" in
  88         # Handle native Windows specially, because there setlocale() interprets
  89         # "ar" as "Arabic" or "Arabic_Saudi Arabia.1256",
  90         # "fr" or "fra" as "French" or "French_France.1252",
  91         # "ge"(!) or "deu"(!) as "German" or "German_Germany.1252",
  92         # "ja" as "Japanese" or "Japanese_Japan.932",
  93         # and similar.
  94         mingw* | windows*)
  95           # Note that on native Windows, the Japanese locale is
  96           # Japanese_Japan.932, and CP932 is very different from EUC-JP, so we
  97           # cannot use it here.
  98           gt_cv_locale_ja=none
  99           ;;
 100         *)
 101           # Setting LC_ALL is not enough. Need to set LC_TIME to empty, because
 102           # otherwise on Mac OS X 10.3.5 the LC_TIME=C from the beginning of the
 103           # configure script would override the LC_ALL setting. Likewise for
 104           # LC_CTYPE, which is also set at the beginning of the configure script.
 105           # Test for the AIX locale name.
 106           if (LC_ALL=ja_JP LC_TIME= LC_CTYPE= ./conftest; exit) 2>/dev/null; then
 107             gt_cv_locale_ja=ja_JP
 108           else
 109             # Test for the locale name with explicit encoding suffix.
 110             if (LC_ALL=ja_JP.EUC-JP LC_TIME= LC_CTYPE= ./conftest; exit) 2>/dev/null; then
 111               gt_cv_locale_ja=ja_JP.EUC-JP
 112             else
 113               # Test for the HP-UX, OSF/1, NetBSD locale name.
 114               if (LC_ALL=ja_JP.eucJP LC_TIME= LC_CTYPE= ./conftest; exit) 2>/dev/null; then
 115                 gt_cv_locale_ja=ja_JP.eucJP
 116               else
 117                 # Test for the IRIX, FreeBSD locale name.
 118                 if (LC_ALL=ja_JP.EUC LC_TIME= LC_CTYPE= ./conftest; exit) 2>/dev/null; then
 119                   gt_cv_locale_ja=ja_JP.EUC
 120                 else
 121                   # Test for the Solaris 10 locale name.
 122                   if (LC_ALL=ja LC_TIME= LC_CTYPE= ./conftest; exit) 2>/dev/null; then
 123                     gt_cv_locale_ja=ja
 124                   else
 125                     # Special test for NetBSD 1.6.
 126                     if test -f /usr/share/locale/ja_JP.eucJP/LC_CTYPE; then
 127                       gt_cv_locale_ja=ja_JP.eucJP
 128                     else
 129                       # None found.
 130                       gt_cv_locale_ja=none
 131                     fi
 132                   fi
 133                 fi
 134               fi
 135             fi
 136           fi
 137           ;;
 138       esac
 139     fi
 140     rm -fr conftest*
 141   ])
 142   LOCALE_JA=$gt_cv_locale_ja
 143   case $LOCALE_JA in #(
 144     '' | *[[[:space:]\"\$\'*@<:@]]*)
 145       dnl This locale name might cause trouble with sh or make.
 146       AC_MSG_WARN([invalid locale "$LOCALE_JA"; assuming "none"])
 147       LOCALE_JA=none;;
 148   esac
 149   AC_SUBST([LOCALE_JA])
 150 ])