utils/rfc2368.el

   1 ;;; rfc2368.el --- support for rfc2368
   2
   3 ;; Author: Sen Nagata <sen@eccosys.com>
   4 ;; Keywords: mail
   5
   6 ;; Copyright (C) 1998, 2000 Free Software Foundation, Inc.
   7
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software; you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation; either version 2, or (at your option)
  13 ;; any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  22 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  23 ;; Boston, MA 02111-1307, USA.
  24
  25 ;;; Commentary:
  26 ;;
  27 ;; notes:
  28 ;;
  29 ;;   -repeat after me: "the colon is not part of the header name..."
  30 ;;   -if w3 becomes part of emacs, then it may make sense to have this
  31 ;;    file depend on w3 -- the maintainer of w3 says merging w/ Emacs
  32 ;;    is planned!
  33 ;;
  34 ;; historical note:
  35 ;;
  36 ;;   this is intended as a replacement for mailto.el
  37 ;;
  38 ;; acknowledgements:
  39 ;;
  40 ;;   the functions that deal w/ unhexifying in this file were basically
  41 ;; taken from w3 -- i hope to replace them w/ something else soon OR
  42 ;; perhaps if w3 becomes a part of emacs soon, use the functions from w3.
  43
  44 ;;; History:
  45 ;;
  46 ;; 0.3:
  47 ;;
  48 ;;  added the constant rfc2368-version
  49 ;;  implemented first potential fix for a bug in rfc2368-mailto-regexp
  50 ;;  implemented first potential fix for a bug in rfc2368-parse-mailto
  51 ;;  (both bugs reported by Kenichi OKADA)
  52 ;;
  53 ;; 0.2:
  54 ;;
  55 ;;  started to use checkdoc
  56 ;;
  57 ;; 0.1:
  58 ;;
  59 ;;  initial implementation
  60
  61 ;;; Code:
  62
  63 ;; only an approximation?
  64 ;; see rfc 1738
  65 (defconst rfc2368-mailto-regexp
  66   "^\\(mailto:\\)\\([^?]+\\)*\\(\\?\\(.*\\)\\)*"
  67   "Regular expression to match and aid in parsing a mailto url.")
  68
  69 ;; describes 'mailto:'
  70 (defconst rfc2368-mailto-scheme-index 1
  71   "Describes the 'mailto:' portion of the url.")
  72 ;; i'm going to call this part the 'prequery'
  73 (defconst rfc2368-mailto-prequery-index 2
  74   "Describes the portion of the url between 'mailto:' and '?'.")
  75 ;; i'm going to call this part the 'query'
  76 (defconst rfc2368-mailto-query-index 4
  77   "Describes the portion of the url after '?'.")
  78
  79 (defun rfc2368-unhexify-string (string)
  80   "Unhexify STRING -- e.g. 'hello%20there' -> 'hello there'."
  81   (let ((start 0)
  82         (buf))
  83     (while (string-match "+\\|%\\(0D%0A\\|\\([0-9a-fA-F][0-9a-fA-F]\\)\\)"
  84                          string start)
  85       (push (substring string start (match-beginning 0)) buf)
  86       (push (cond
  87              ((match-beginning 2)
  88               (vector (string-to-number (match-string 2 string) 16)))
  89              ((match-beginning 1) "\n")
  90              (t " "))
  91             buf)
  92       (setq start (match-end 0)))
  93     (apply 'concat (nreverse (cons (substring string start) buf)))))
  94
  95 (defun rfc2368-parse-mailto-url (mailto-url)
  96   "Parse MAILTO-URL, and return an alist of header-name, header-value pairs.
  97 MAILTO-URL should be a RFC 2368 (mailto) compliant url.  A cons cell w/ a
  98 key of 'Body' is a special case and is considered a header for this purpose.
  99 The returned alist is intended for use w/ the `compose-mail' interface.
 100 Note: make sure MAILTO-URL has been 'unhtmlized' (e.g. &amp; -> &), before
 101 calling this function."
 102   (let ((case-fold-search t)
 103         prequery query headers-alist)
 104     ;; Remove newline
 105     (setq mailto-url
 106           (with-temp-buffer
 107             (insert mailto-url)
 108             (goto-char (point-min))
 109             (while (re-search-forward "\n" nil t)
 110               (replace-match ""))
 111             (buffer-string)))
 112     (if (string-match rfc2368-mailto-regexp mailto-url)
 113         (progn
 114
 115           (setq prequery
 116                 (match-string rfc2368-mailto-prequery-index mailto-url))
 117
 118           (setq query
 119                 (match-string rfc2368-mailto-query-index mailto-url))
 120
 121           ;; build alist of header name-value pairs
 122           (if (not (null query))
 123               (setq headers-alist
 124                     (mapcar
 125                      (lambda (x)
 126                        (let* ((temp-list (split-string x "="))
 127                               (header-name (car temp-list))
 128                               (header-value (cadr temp-list)))
 129                          ;; return ("Header-Name" . "header-value")
 130                          (cons
 131                           (capitalize (rfc2368-unhexify-string header-name))
 132                           (rfc2368-unhexify-string header-value))))
 133                      (split-string query "&"))))
 134
 135           ;; deal w/ multiple 'To' recipients
 136           (if prequery
 137               (progn
 138                 (setq prequery (rfc2368-unhexify-string prequery))
 139                 (if (assoc "To" headers-alist)
 140                     (let* ((our-cons-cell
 141                             (assoc "To" headers-alist))
 142                            (our-cdr
 143                             (cdr our-cons-cell)))
 144                       (setcdr our-cons-cell (concat prequery ", " our-cdr)))
 145                   (setq headers-alist
 146                         (cons (cons "To" prequery) headers-alist)))))
 147
 148           headers-alist)
 149
 150       (error "Failed to match a mailto: url"))
 151     ))
 152
 153 (provide 'rfc2368)
 154
 155 ;;; rfc2368.el ends here