wl/wl-e21.el

   1 ;;; wl-e21.el --- Wanderlust modules for Emacs 21.
   2
   3 ;; Copyright (C) 2000,2001 Katsumi Yamaoka <yamaoka@jpl.org>
   4 ;; Copyright (C) 2000,2001 Yuuichi Teranishi <teranisi@gohome.org>
   5
   6 ;; Author: Katsumi Yamaoka <yamaoka@jpl.org>
   7 ;; Keywords: mail, net news
   8
   9 ;; This file is part of Wanderlust (Yet Another Message Interface on Emacsen).
  10
  11 ;; This program is free software; you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation; either version 2, or (at your option)
  14 ;; any later version.
  15 ;;
  16 ;; This program is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20 ;;
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  23 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  24 ;; Boston, MA 02111-1307, USA.
  25 ;;
  26
  27 ;;; Commentary:
  28 ;;
  29 ;; This module uses `before-string' overlay property to show icon
  30 ;; images instead of `insert-image', so don't delete such overlays
  31 ;; sloppily.  Here is a sample code to show icons in the buffer.
  32 ;;
  33 ;;(let (image icon from to overlay)
  34 ;;  ;; The function `find-image' will look for an image first on `load-path'
  35 ;;  ;; and then in `data-directory'.
  36 ;;  (let ((load-path (cons wl-icon-directory load-path)))
  37 ;;    (setq image (find-image (list (list :type 'xpm :file wl-nntp-folder-icon
  38 ;;                                      :ascent 'center)))))
  39 ;;  ;; `propertize' is a convenient function in such a case.
  40 ;;  ;; String must have one or more length to wear an image.
  41 ;;  (setq icon (propertize "any string" 'display image))
  42 ;;  (pop-to-buffer (get-buffer-create "*wl-e21-demo*"))
  43 ;;  (erase-buffer)
  44 ;;  (insert "   ")
  45 ;;  (setq from (point))
  46 ;;  (insert "-fj.wanderlust:0/0/0")
  47 ;;  (setq to (point))
  48 ;;  (insert "\n")
  49 ;;  (setq overlay (make-overlay from to))
  50 ;;  ;; Put an image.
  51 ;;  (overlay-put overlay 'before-string icon)
  52 ;;  ;; Put a mark to indicate that this overlay is made by `wl-e21'.
  53 ;;  ;; It is not always necessarily.
  54 ;;  (overlay-put overlay 'wl-e21-icon t)
  55 ;;  ;; Make it to be removable.
  56 ;;  (overlay-put overlay 'evaporate t))
  57 ;;
  58 ;; Note that a port of Emacs to some platforms (e.g. MS-Windoze) does
  59 ;; not yet support images.  It is a pity that neither icons nor tool-
  60 ;; bars will not be displayed in such systems.
  61
  62 ;;; Code:
  63 ;;
  64
  65 (require 'elmo)
  66 (eval-when-compile
  67   (require 'wl-folder)
  68   (require 'wl-summary)
  69   (require 'wl-draft)
  70   (require 'wl-message)
  71   (require 'wl-highlight)
  72   (defvar-maybe wl-draft-mode-map (make-sparse-keymap)))
  73
  74 (add-hook 'wl-folder-mode-hook 'wl-setup-folder)
  75 (add-hook 'wl-folder-mode-hook 'wl-folder-init-icons)
  76
  77 (add-hook 'wl-init-hook 'wl-biff-init-icons)
  78 (add-hook 'wl-init-hook 'wl-plugged-init-icons)
  79
  80 (add-hook 'wl-summary-mode-hook 'wl-setup-summary)
  81
  82 (add-hook 'wl-message-display-internal-hook 'wl-setup-message)
  83
  84 (defvar wl-use-toolbar (image-type-available-p 'xpm))
  85 (defvar wl-plugged-image nil)
  86 (defvar wl-unplugged-image nil)
  87 (defvar wl-biff-mail-image nil)
  88 (defvar wl-biff-nomail-image nil)
  89
  90 (defvar wl-folder-toolbar
  91   '([wl-folder-jump-to-current-entity
  92      wl-folder-jump-to-current-entity t "Enter Current Folder"]
  93     [wl-folder-next-entity
  94      wl-folder-next-entity t "Next Folder"]
  95     [wl-folder-prev-entity
  96      wl-folder-prev-entity t "Previous Folder"]
  97     [wl-folder-check-current-entity
  98      wl-folder-check-current-entity t "Check Current Folder"]
  99     [wl-folder-sync-current-entity
 100      wl-folder-sync-current-entity t "Sync Current Folder"]
 101     [wl-draft
 102      wl-draft t "Write a New Message"]
 103     [wl-folder-goto-draft-folder
 104      wl-folder-goto-draft-folder t "Go to Draft Folder"]
 105     [wl-folder-empty-trash
 106      wl-folder-empty-trash t "Empty Trash"]
 107     [wl-exit
 108      wl-exit t "Quit Wanderlust"]
 109     )
 110   "The Folder buffer toolbar.")
 111
 112 (defvar wl-summary-toolbar
 113   '([wl-summary-read
 114      wl-summary-read t "Read Messages"]
 115     [wl-summary-next
 116      wl-summary-next t "Next Message"]
 117     [wl-summary-prev
 118      wl-summary-prev t "Previous Message"]
 119     [wl-summary-jump-to-current-message
 120      wl-summary-jump-to-current-message t "Jump to Current Message"]
 121     [wl-summary-sync-force-update
 122      wl-summary-sync-force-update t "Sync Current Folder"]
 123     [wl-summary-dispose
 124      wl-summary-dispose t "Dispose Current Message"]
 125     [wl-summary-set-flags
 126      wl-summary-set-flags t "Set Flags"]
 127     [wl-draft
 128      wl-summary-write-current-folder t "Write for Current Folder"]
 129     [wl-summary-reply
 130      wl-summary-reply t "Reply to Current Message" ]
 131     [wl-summary-reply-with-citation
 132      wl-summary-reply-with-citation t "Reply to Current Message with Citation"]
 133     [wl-summary-forward
 134      wl-summary-forward t "Forward Current Message"]
 135     [wl-summary-exit
 136      wl-summary-exit t "Exit Current Summary"]
 137     )
 138   "The Summary buffer toolbar.")
 139
 140 (defvar wl-message-toolbar
 141   '([wl-message-read
 142      wl-message-read t "Read Contents"]
 143     [wl-message-next-content
 144      wl-message-next-content t "Next Content"]
 145     [wl-message-prev-content
 146      wl-message-prev-content t "Previous Content"]
 147     [wl-message-quit
 148      wl-message-quit t "Back to Summary"]
 149     [wl-message-play-content
 150      wl-message-play-content t "Play Content"]
 151     [wl-message-extract-content
 152      wl-message-extract-content t "Extract Content"]
 153     )
 154   "The Message buffer toolbar.")
 155
 156 (defalias 'wl-draft-insert-signature 'insert-signature);; for draft toolbar.
 157
 158 (defvar wl-draft-toolbar
 159   '([wl-draft-send-from-toolbar
 160      wl-draft-send-from-toolbar t "Send Current Draft"]
 161     [wl-draft-yank-original
 162      wl-draft-yank-original t "Yank Displaying Message"]
 163     [wl-draft-insert-signature
 164      wl-draft-insert-signature t "Insert Signature"]
 165     [wl-draft-kill
 166      wl-draft-kill t "Kill Current Draft"]
 167     [wl-draft-save-and-exit
 168      wl-draft-save-and-exit t "Save Draft and Exit"]
 169     )
 170   "The Draft buffer toolbar.")
 171
 172 (eval-when-compile
 173   (defmacro wl-e21-display-image-p ()
 174     '(and wl-highlight-folder-with-icon
 175           (image-type-available-p 'xpm))))
 176
 177 (eval-and-compile
 178   (if (boundp 'image-load-path)
 179       (defun wl-e21-find-image (specs)
 180         (let ((image-load-path (cons 'wl-icon-directory image-load-path)))
 181           (find-image specs)))
 182     (defun wl-e21-find-image (specs)
 183       (let ((load-path (cons wl-icon-directory load-path)))
 184         (find-image specs)))))
 185
 186 (defun wl-e21-setup-toolbar (bar)
 187   (when (and wl-use-toolbar
 188              (wl-e21-display-image-p))
 189     (let ((props '(:type xpm :ascent center
 190                          :color-symbols (("backgroundToolBarColor" . "None"))
 191                          :file))
 192           (success t)
 193           icon up down disabled name)
 194       (while bar
 195         (setq icon (aref (pop bar) 0))
 196         (unless (boundp icon)
 197           (setq name (symbol-name icon)
 198                 up (wl-e21-find-image `((,@props ,(concat name "-up.xpm")))))
 199           (if up
 200               (progn
 201                 (setq down (wl-e21-find-image
 202                             `((,@props ,(concat name "-down.xpm"))))
 203                       disabled (wl-e21-find-image
 204                                 `((,@props ,(concat name "-disabled.xpm")))))
 205                 (set icon (vector down up disabled disabled)))
 206             (setq bar nil
 207                   success nil))))
 208       success)))
 209
 210 (defvar wl-e21-toolbar-configurations
 211   '((auto-resize-tool-bars       . t)
 212     (auto-raise-tool-bar-buttons . t)
 213     (tool-bar-button-margin      . 2)
 214     (tool-bar-button-relief      . 1)))
 215
 216 (defun wl-e21-make-toolbar-buttons (keymap defs)
 217   (let ((configs wl-e21-toolbar-configurations)
 218         config)
 219     (while (setq config (pop configs))
 220       (set (make-local-variable (car config)) (cdr config))))
 221   ;; Invalidate the default bindings.
 222   (let ((keys (cdr (key-binding [tool-bar] t)))
 223         item)
 224     (while (setq item (pop keys))
 225       (when (setq item (car-safe item))
 226         (define-key keymap (vector 'tool-bar item) 'undefined))))
 227   (let ((n (length defs))
 228         def)
 229     (while (>= n 0)
 230       (setq n (1- n)
 231             def (nth n defs))
 232       (define-key keymap (vector 'tool-bar (aref def 1))
 233         (list 'menu-item (aref def 3) (aref def 1)
 234               :enable (aref def 2)
 235               :image (symbol-value (aref def 0)))))))
 236
 237 (defun wl-e21-setup-folder-toolbar ()
 238   (when (wl-e21-setup-toolbar wl-folder-toolbar)
 239     (wl-e21-make-toolbar-buttons wl-folder-mode-map wl-folder-toolbar)))
 240
 241 (defun wl-e21-setup-summary-toolbar ()
 242   (when (wl-e21-setup-toolbar wl-summary-toolbar)
 243     (wl-e21-make-toolbar-buttons wl-summary-mode-map wl-summary-toolbar)))
 244
 245 (eval-when-compile
 246   (defsubst wl-e21-setup-draft-toolbar ()
 247     (when (wl-e21-setup-toolbar wl-draft-toolbar)
 248       (wl-e21-make-toolbar-buttons wl-draft-mode-map wl-draft-toolbar))))
 249
 250 (defun wl-e21-setup-message-toolbar ()
 251   (when (wl-e21-setup-toolbar wl-message-toolbar)
 252     (wl-e21-make-toolbar-buttons (current-local-map) wl-message-toolbar)))
 253
 254 (defvar wl-folder-toggle-icon-list
 255   '((wl-folder-opened-image       . wl-opened-group-folder-icon)
 256     (wl-folder-closed-image       . wl-closed-group-folder-icon)))
 257
 258 (eval-when-compile
 259   (defsubst wl-e21-highlight-folder-group-line (start end icon numbers)
 260     (let (image)
 261       (when (wl-e21-display-image-p)
 262         (let (overlay)
 263           (let ((overlays (overlays-in start end)))
 264             (while (and (setq overlay (pop overlays))
 265                         (not (overlay-get overlay 'wl-e21-icon)))))
 266           (unless overlay
 267             (setq overlay (make-overlay start end))
 268             (overlay-put overlay 'wl-e21-icon t)
 269             (overlay-put overlay 'evaporate t))
 270           (setq image (get icon 'image))
 271           (unless image
 272             (let ((name (symbol-value
 273                          (cdr (assq icon wl-folder-toggle-icon-list)))))
 274               (setq image (wl-e21-find-image
 275                            `((:type xpm :file ,name :ascent center))))))
 276           (overlay-put overlay 'display image)))
 277       (when (and wl-use-highlight-mouse-line (display-mouse-p))
 278         (let ((inhibit-read-only t))
 279           (put-text-property (if image
 280                                  (max (1- start) (line-beginning-position))
 281                                start)
 282                              (line-end-position)
 283                              'mouse-face 'highlight)))))
 284
 285   (defsubst wl-e21-highlight-folder-by-numbers (start end text-face numbers)
 286     (when (display-color-p)
 287       (let ((inhibit-read-only t))
 288         (if (and wl-highlight-folder-by-numbers
 289                  numbers (nth 0 numbers) (nth 1 numbers)
 290                  (re-search-forward "[-[:digit:]]+/[-[:digit:]]+/[-[:digit:]]+"
 291                                     (line-end-position) t))
 292             (let* ((unsync (nth 0 numbers))
 293                    (unread (nth 1 numbers))
 294                    (face (cond ((and unsync (zerop unsync))
 295                                 (if (and unread (zerop unread))
 296                                     'wl-highlight-folder-zero-face
 297                                   'wl-highlight-folder-unread-face))
 298                                ((and unsync
 299                                      (>= unsync
 300                                          wl-folder-many-unsync-threshold))
 301                                 'wl-highlight-folder-many-face)
 302                                (t
 303                                 'wl-highlight-folder-few-face))))
 304               (if (numberp wl-highlight-folder-by-numbers)
 305                   (progn
 306                     (put-text-property start (match-beginning 0)
 307                                        'face text-face)
 308                     (put-text-property (match-beginning 0) (match-end 0)
 309                                        'face face))
 310                 (put-text-property start (match-end 0) 'face face)))
 311           (put-text-property start (line-end-position) 'face text-face))))))
 312
 313 (defun wl-highlight-folder-current-line (&optional numbers)
 314   (interactive)
 315   (save-excursion
 316     (beginning-of-line)
 317     (let (fld-name start end)
 318       (cond
 319        (;; opened folder group
 320         (and (wl-folder-buffer-group-p)
 321              (looking-at wl-highlight-folder-opened-regexp))
 322         (setq start (match-beginning 1)
 323               end (match-end 1))
 324         (wl-e21-highlight-folder-group-line start end
 325                                             'wl-folder-opened-image
 326                                             numbers)
 327         (wl-e21-highlight-folder-by-numbers start end
 328                                             'wl-highlight-folder-opened-face
 329                                             numbers))
 330        (;; closed folder group
 331         (and (wl-folder-buffer-group-p)
 332              (looking-at wl-highlight-folder-closed-regexp))
 333         (setq start (match-beginning 1)
 334               end (match-end 1))
 335         (wl-e21-highlight-folder-group-line start end
 336                                             'wl-folder-closed-image
 337                                             numbers)
 338         (wl-e21-highlight-folder-by-numbers start end
 339                                             'wl-highlight-folder-closed-face
 340                                             numbers))
 341        (;; basic folder
 342         (and (setq fld-name (wl-folder-get-folder-name-by-id
 343                              (get-text-property (point) 'wl-folder-entity-id)))
 344              (looking-at "[[:blank:]]+\\([^[:blank:]\n]+\\)"))
 345         (setq start (match-beginning 1)
 346               end (match-end 1))
 347         (let (image)
 348           (when (wl-e21-display-image-p)
 349             (let (overlay)
 350               (let ((overlays (overlays-in start end)))
 351                 (while (and (setq overlay (pop overlays))
 352                             (not (overlay-get overlay 'wl-e21-icon)))))
 353               (unless overlay
 354                 (setq overlay (make-overlay start end))
 355                 (overlay-put overlay 'wl-e21-icon t)
 356                 (overlay-put overlay 'evaporate t))
 357               (let (type)
 358                 (unless (get (caar wl-folder-internal-icon-list) 'image)
 359                   (wl-folder-init-icons))
 360                 (setq image
 361                       (cond ((string= fld-name wl-trash-folder);; trash folder
 362                              (let ((num (nth 2 numbers)));; number of messages
 363                                (get (if (or (not num) (zerop num))
 364                                         'wl-folder-trash-empty-image
 365                                       'wl-folder-trash-image)
 366                                     'image)))
 367                             ((string= fld-name wl-draft-folder);; draft folder
 368                              (get 'wl-folder-draft-image 'image))
 369                             ((string= fld-name wl-queue-folder);; queue folder
 370                              (get 'wl-folder-queue-image 'image))
 371                             (;; and one of many other folders
 372                              (setq type (or (elmo-folder-type fld-name)
 373                                             (elmo-folder-type-internal
 374                                              (elmo-make-folder fld-name))))
 375                              (get (intern (format "wl-folder-%s-image" type))
 376                                   'image)))))
 377               (overlay-put overlay 'before-string
 378                            (propertize " " 'display image
 379                                        'invisible t))))
 380           (when (and wl-use-highlight-mouse-line (display-mouse-p))
 381             (let ((inhibit-read-only t))
 382               (put-text-property (if image
 383                                      (max (1- start)
 384                                           (line-beginning-position))
 385                                    start)
 386                                  (line-end-position)
 387                                  'mouse-face 'highlight))))
 388         (when (display-color-p)
 389           (wl-e21-highlight-folder-by-numbers
 390            start end
 391            (if (looking-at (format "^[[:blank:]]*\\(?:%s\\|%s\\)"
 392                                    wl-folder-unsubscribe-mark
 393                                    wl-folder-removed-mark))
 394                'wl-highlight-folder-killed-face
 395              'wl-highlight-folder-unknown-face)
 396            numbers)))))))
 397
 398 (defun wl-highlight-plugged-current-line ()
 399   (interactive)
 400   (when (wl-e21-display-image-p)
 401     (save-excursion
 402       (beginning-of-line)
 403       (when (looking-at "[[:blank:]]*\\(\\[\\([^]]+\\)\\]\\)")
 404         (let* ((start (match-beginning 1))
 405                (end (match-end 1))
 406                (status (match-string-no-properties 2))
 407                (image (if (string-equal wl-plugged-plug-on status)
 408                           wl-plugged-image
 409                         wl-unplugged-image)))
 410           (when image
 411             (let (overlay)
 412               (let ((overlays (overlays-in start end)))
 413                 (while (and (setq overlay (pop overlays))
 414                             (not (overlay-get overlay 'wl-e21-icon)))))
 415               (unless overlay
 416                 (setq overlay (make-overlay start end))
 417                 (overlay-put overlay 'wl-e21-icon t)
 418                 (overlay-put overlay 'evaporate t))
 419               (overlay-put overlay 'display image))))))))
 420
 421 (defun wl-plugged-set-folder-icon (folder string)
 422   (let (image type)
 423     (when (wl-e21-display-image-p)
 424       (setq image
 425             (cond ((string= folder wl-queue-folder)
 426                    (get 'wl-folder-queue-image 'image))
 427                   ((setq type (or (elmo-folder-type folder)
 428                                   (elmo-folder-type-internal
 429                                    (elmo-make-folder folder))))
 430                    (get (intern (format "wl-folder-%s-image" type))
 431                         'image)))))
 432     (if image
 433         (concat (propertize " " 'display image 'invisible t) string)
 434       string)))
 435
 436 (defvar wl-folder-internal-icon-list
 437   ;; alist of (image . icon-file)
 438   '((wl-folder-nntp-image         . wl-nntp-folder-icon)
 439     (wl-folder-imap4-image        . wl-imap-folder-icon)
 440     (wl-folder-pop3-image         . wl-pop-folder-icon)
 441     (wl-folder-localdir-image     . wl-localdir-folder-icon)
 442     (wl-folder-localnews-image    . wl-localnews-folder-icon)
 443     (wl-folder-internal-image     . wl-internal-folder-icon)
 444     (wl-folder-multi-image        . wl-multi-folder-icon)
 445     (wl-folder-filter-image       . wl-filter-folder-icon)
 446     (wl-folder-archive-image      . wl-archive-folder-icon)
 447     (wl-folder-pipe-image         . wl-pipe-folder-icon)
 448     (wl-folder-maildir-image      . wl-maildir-folder-icon)
 449     (wl-folder-search-image       . wl-search-folder-icon)
 450     (wl-folder-shimbun-image      . wl-shimbun-folder-icon)
 451     (wl-folder-file-image         . wl-file-folder-icon)
 452     (wl-folder-access-image       . wl-access-folder-icon)
 453     (wl-folder-trash-empty-image  . wl-empty-trash-folder-icon)
 454     (wl-folder-draft-image        . wl-draft-folder-icon)
 455     (wl-folder-queue-image        . wl-queue-folder-icon)
 456     (wl-folder-trash-image        . wl-trash-folder-icon)))
 457
 458 (defun wl-folder-init-icons ()
 459   (when (wl-e21-display-image-p)
 460     (let ((icons wl-folder-internal-icon-list)
 461           icon name image)
 462       (while (setq icon (pop icons))
 463         (unless (get (car icon) 'image)
 464           (setq name (symbol-value (cdr icon))
 465                 image (wl-e21-find-image
 466                        `((:type xpm :file ,name :ascent center))))
 467           (when image
 468             (put (car icon) 'image image)))))))
 469
 470 (defun wl-plugged-init-icons ()
 471   (let ((props (when (display-mouse-p)
 472                  (list 'local-map (purecopy (make-mode-line-mouse-map
 473                                              'mouse-2 #'wl-toggle-plugged))
 474                        'help-echo "mouse-2 toggles plugged status"))))
 475     (if (wl-e21-display-image-p)
 476         (progn
 477           (unless wl-plugged-image
 478             (setq wl-plugged-image (wl-e21-find-image
 479                                     `((:type xpm
 480                                              :file ,wl-plugged-icon
 481                                              :ascent center)))
 482                   wl-unplugged-image (wl-e21-find-image
 483                                       `((:type xpm
 484                                                :file ,wl-unplugged-icon
 485                                                :ascent center)))))
 486           (setq wl-modeline-plug-state-on
 487                 (apply 'propertize wl-plug-state-indicator-on
 488                        `(display ,wl-plugged-image ,@props))
 489                 wl-modeline-plug-state-off
 490                 (apply 'propertize wl-plug-state-indicator-off
 491                        `(display ,wl-unplugged-image ,@props))))
 492       (if props
 493           (setq wl-modeline-plug-state-on
 494                 (apply 'propertize wl-plug-state-indicator-on props)
 495                 wl-modeline-plug-state-off
 496                 (apply 'propertize wl-plug-state-indicator-off props))
 497         (setq wl-modeline-plug-state-on wl-plug-state-indicator-on
 498               wl-modeline-plug-state-off wl-plug-state-indicator-off)))))
 499
 500 (defun wl-biff-init-icons ()
 501   (let ((props (when (display-mouse-p)
 502                  (list 'local-map (purecopy (make-mode-line-mouse-map
 503                                              'mouse-2 #'wl-biff-check-folders))
 504                        'help-echo "mouse-2 checks new mails"))))
 505     (if (wl-e21-display-image-p)
 506         (progn
 507           (unless wl-biff-mail-image
 508             (setq wl-biff-mail-image (wl-e21-find-image
 509                                       `((:type xpm
 510                                                :file ,wl-biff-mail-icon
 511                                                :ascent center)))
 512                   wl-biff-nomail-image (wl-e21-find-image
 513                                         `((:type xpm
 514                                                  :file ,wl-biff-nomail-icon
 515                                                  :ascent center)))))
 516           (setq wl-modeline-biff-state-on
 517                 (apply 'propertize wl-biff-state-indicator-on
 518                        `(display ,wl-biff-mail-image ,@props))
 519                 wl-modeline-biff-state-off
 520                 (apply 'propertize wl-biff-state-indicator-off
 521                        `(display ,wl-biff-nomail-image ,@props))))
 522       (if props
 523           (setq wl-modeline-biff-state-on
 524                 (apply 'propertize wl-biff-state-indicator-on props)
 525                 wl-modeline-biff-state-off
 526                 (apply 'propertize wl-biff-state-indicator-off props))
 527         (setq wl-modeline-biff-state-on wl-biff-state-indicator-on
 528               wl-modeline-biff-state-off wl-biff-state-indicator-off)))))
 529
 530 (defun wl-make-date-string ()
 531   (let ((system-time-locale "C"))
 532     (format-time-string "%a, %d %b %Y %T %z")))
 533
 534 (defalias 'wl-setup-folder 'wl-e21-setup-folder-toolbar)
 535
 536 (defalias 'wl-setup-summary 'wl-e21-setup-summary-toolbar)
 537
 538 (defun wl-message-define-keymap ()
 539   (let ((keymap (make-sparse-keymap)))
 540     (define-key keymap "D" 'wl-message-delete-current-part)
 541     (define-key keymap "l" 'wl-message-toggle-disp-summary)
 542     (define-key keymap "\C-c:d" 'wl-message-decrypt-pgp-nonmime)
 543     (define-key keymap "\C-c:v" 'wl-message-verify-pgp-nonmime)
 544     (define-key keymap "w" 'wl-draft)
 545     (define-key keymap [mouse-4] 'wl-message-wheel-down)
 546     (define-key keymap [mouse-5] 'wl-message-wheel-up)
 547     (define-key keymap [S-mouse-4] 'wl-message-wheel-down)
 548     (define-key keymap [S-mouse-5] 'wl-message-wheel-up)
 549     ;; Meadow2
 550     (define-key keymap [mouse-wheel1] 'wl-message-wheel-dispatcher)
 551     (define-key keymap [S-mouse-wheel1] 'wl-message-wheel-dispatcher)
 552     (set-keymap-parent wl-message-button-map keymap)
 553     (define-key wl-message-button-map
 554       [mouse-2] 'wl-message-button-dispatcher)
 555     keymap))
 556
 557 (defalias 'wl-setup-message 'wl-e21-setup-message-toolbar)
 558
 559 ;; Wheel handling for Meadow2
 560 (defun wl-message-wheel-dispatcher (event)
 561   (interactive "e")
 562   (if (< (nth 4 (nth 1 event)) 0)
 563       (wl-message-wheel-up event)
 564     (wl-message-wheel-down event)))
 565
 566 (defun wl-summary-wheel-dispatcher (event)
 567   (interactive "e")
 568   (if (< (nth 4 (nth 1 event)) 0)
 569       (if (memq 'shift (event-modifiers event))
 570           (wl-summary-down)
 571         (wl-summary-next))
 572     (if (memq 'shift (event-modifiers event))
 573         (wl-summary-up)
 574       (wl-summary-prev))))
 575
 576 (defun wl-message-wheel-up (event)
 577   (interactive "e")
 578   (if (string-match (regexp-quote wl-message-buffer-name)
 579                     (regexp-quote (buffer-name)))
 580       (wl-message-next-page)
 581     (let ((cur-buf (current-buffer))
 582           proceed)
 583       (save-selected-window
 584         (select-window (posn-window (event-start event)))
 585         (set-buffer cur-buf)
 586         (setq proceed (wl-message-next-page)))
 587       (if proceed
 588           (if (memq 'shift (event-modifiers event))
 589               (wl-summary-down t)
 590             (wl-summary-next t))))))
 591
 592 (defun wl-message-wheel-down (event)
 593   (interactive "e")
 594   (if (string-match (regexp-quote wl-message-buffer-name)
 595                     (regexp-quote (buffer-name)))
 596       (wl-message-prev-page)
 597     (let ((cur-buf (current-buffer))
 598           proceed)
 599       (save-selected-window
 600         (select-window (posn-window (event-start event)))
 601         (set-buffer cur-buf)
 602         (setq proceed (wl-message-prev-page)))
 603       (if proceed
 604           (if (memq 'shift (event-modifiers event))
 605               (wl-summary-up t)
 606             (wl-summary-prev t))))))
 607
 608 (defun wl-draft-overload-menubar ()
 609   (let ((keymap (current-local-map)))
 610     (define-key keymap [menu-bar mail send]
 611       '("Send Message" . wl-draft-send-and-exit))
 612     (define-key keymap [menu-bar mail send-stay]
 613       '("Send, Keep Editing" . wl-draft-send))
 614     (define-key-after (lookup-key keymap [menu-bar mail])
 615       [mail-sep-send] '("--")
 616       'send-stay)
 617     (define-key keymap [menu-bar mail cancel]
 618       '("Kill Current Draft" . wl-draft-kill))
 619     (define-key-after (lookup-key keymap [menu-bar mail])
 620       [save] '("Save Draft and Exit" . wl-draft-save-and-exit)
 621       'cancel)
 622     (define-key-after (lookup-key keymap [menu-bar mail])
 623       [mail-sep-exit] '("--")
 624       'save)
 625     (define-key-after (lookup-key keymap [menu-bar mail])
 626       [preview] '("Preview Message" . wl-draft-preview-message)
 627       'mail-sep-exit)
 628     (define-key keymap [menu-bar mail yank]
 629       '("Cite Message" . wl-draft-yank-original))
 630     (define-key keymap [menu-bar mail signature]
 631       '("Insert Signature" . insert-signature))
 632     (define-key keymap [menu-bar headers fcc]
 633       '("Fcc" . wl-draft-fcc))))
 634
 635 (defun wl-draft-mode-setup ()
 636   (require 'derived)
 637   (define-derived-mode wl-draft-mode mail-mode "Draft"
 638     "draft mode for Wanderlust derived from mail mode.
 639 See info under Wanderlust for full documentation.
 640
 641 Special commands:
 642 \\{wl-draft-mode-map}"
 643     (setq font-lock-defaults nil)))
 644
 645 (defun wl-draft-key-setup ()
 646   (define-key wl-draft-mode-map "\C-c\C-y" 'wl-draft-yank-original)
 647   (define-key wl-draft-mode-map "\C-c\C-s" 'wl-draft-send)
 648   (define-key wl-draft-mode-map "\C-c\C-c" 'wl-draft-send-and-exit)
 649   (define-key wl-draft-mode-map "\C-c\C-z" 'wl-draft-save-and-exit)
 650   (define-key wl-draft-mode-map "\C-c\C-k" 'wl-draft-kill)
 651   (define-key wl-draft-mode-map "\C-l" 'wl-draft-highlight-and-recenter)
 652   (define-key wl-draft-mode-map "\C-i" 'wl-complete-field-body-or-tab)
 653   (define-key wl-draft-mode-map "\C-c\C-r" 'wl-draft-caesar-region)
 654   (define-key wl-draft-mode-map "\M-t" 'wl-toggle-plugged)
 655   (define-key wl-draft-mode-map "\C-c\C-o" 'wl-jump-to-draft-buffer)
 656   (define-key wl-draft-mode-map "\C-c\C-e" 'wl-draft-config-exec)
 657   (define-key wl-draft-mode-map "\C-c\C-j" 'wl-template-select)
 658   (define-key wl-draft-mode-map "\C-c\C-p" 'wl-draft-preview-message)
 659   (define-key wl-draft-mode-map "\C-c\C-a" 'wl-addrmgr)
 660 ;;  (define-key wl-draft-mode-map "\C-x\C-s" 'wl-draft-save)
 661   (define-key wl-draft-mode-map "\C-xk"    'wl-draft-mimic-kill-buffer)
 662   (define-key wl-draft-mode-map "\C-c\C-d" 'wl-draft-elide-region)
 663   (define-key wl-draft-mode-map "\C-a" 'wl-draft-beginning-of-line)
 664   (define-key wl-draft-mode-map "\M-p" 'wl-draft-previous-history-element)
 665   (define-key wl-draft-mode-map "\M-n" 'wl-draft-next-history-element))
 666
 667 (defun wl-draft-overload-functions ()
 668   (wl-mode-line-buffer-identification)
 669 ;;  (local-set-key "\C-c\C-s" 'wl-draft-send);; override
 670   (wl-e21-setup-draft-toolbar)
 671   (wl-draft-overload-menubar))
 672
 673 (defalias 'wl-defface 'defface)
 674
 675 (defun wl-read-event-char (&optional prompt)
 676   "Get the next event."
 677   (let ((event (read-event prompt)))
 678     (cons (and (numberp event) event) event)))
 679
 680 (put 'wl-modeline-biff-state-on 'risky-local-variable t)
 681 (put 'wl-modeline-biff-state-off 'risky-local-variable t)
 682 (put 'wl-modeline-plug-state-on 'risky-local-variable t)
 683 (put 'wl-modeline-plug-state-off 'risky-local-variable t)
 684
 685 (require 'product)
 686 (product-provide (provide 'wl-e21) (require 'wl-version))
 687
 688 ;;; wl-e21.el ends here