MPUI_Setup.nsi

   1 ; ///////////////////////////////////////////////////////////////////////////////
   2 ; // MPlayer for Windows - Install Script
   3 ; // Copyright (C) 2004-2016 LoRd_MuldeR <MuldeR2@GMX.de>
   4 ; //
   5 ; // This program is free software; you can redistribute it and/or modify
   6 ; // it under the terms of the GNU General Public License as published by
   7 ; // the Free Software Foundation; either version 2 of the License, or
   8 ; // (at your option) any later version.
   9 ; //
  10 ; // This program is distributed in the hope that it will be useful,
  11 ; // but WITHOUT ANY WARRANTY; without even the implied warranty of
  12 ; // MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  13 ; // GNU General Public License for more details.
  14 ; //
  15 ; // You should have received a copy of the GNU General Public License along
  16 ; // with this program; if not, write to the Free Software Foundation, Inc.,
  17 ; // 51 Franklin Street, Fifth Floor, Boston, MA 02110-1301 USA.
  18 ; //
  19 ; // http://www.gnu.org/licenses/gpl-2.0.txt
  20 ; ///////////////////////////////////////////////////////////////////////////////
  21
  22
  23 ;--------------------------------------------------------------------------------
  24 ; BASIC DEFINES
  25 ;--------------------------------------------------------------------------------
  26
  27 !ifndef NSIS_UNICODE
  28   !error "NSIS_UNICODE is undefined, please compile with Unicode NSIS !!!"
  29 !endif
  30
  31 !ifndef MPLAYER_BUILDNO
  32   !error "MPLAYER_BUILDNO is not defined !!!"
  33 !endif
  34
  35 !ifndef MPLAYER_REVISION
  36   !error "MPLAYER_REVISION is not defined !!!"
  37 !endif
  38
  39 !ifndef MPLAYER_DATE
  40   !error "MPLAYER_DATE is not defined !!!"
  41 !endif
  42
  43 !ifndef SMPLAYER_VERSION
  44   !error "SMPLAYER_VERSION is not defined !!!"
  45 !endif
  46
  47 !ifndef MPUI_VERSION
  48   !error "MPUI_VERSION is not defined !!!"
  49 !endif
  50
  51 !ifndef CODECS_DATE
  52   !error "CODECS_DATE is not defined !!!"
  53 !endif
  54
  55 !ifndef MPLAYER_OUTFILE
  56   !error "MPLAYER_OUTFILE is not defined !!!"
  57 !endif
  58
  59 !ifndef UPX_PATH
  60   !error "UPX_PATH is not defined !!!"
  61 !endif
  62
  63 ; UUID
  64 !define MPlayerRegPath "SOFTWARE\Microsoft\Windows\CurrentVersion\Uninstall\{97D341C8-B0D1-4E4A-A49A-C30B52F168E9}"
  65
  66 ; Web-Site
  67 !define MPlayerWebSite "http://mplayerhq.hu/"
  68
  69
  70 ;--------------------------------------------------------------------------------
  71 ; INSTALLER ATTRIBUTES
  72 ;--------------------------------------------------------------------------------
  73
  74 RequestExecutionLevel admin
  75 ShowInstDetails show
  76 ShowUninstDetails show
  77
  78 Name "$(MPLAYER_LANG_MPLAYER_WIN32) ${MPLAYER_DATE} (Build #${MPLAYER_BUILDNO})"
  79 Caption "$(MPLAYER_LANG_MPLAYER_WIN32) ${MPLAYER_DATE} (Build #${MPLAYER_BUILDNO})"
  80 BrandingText "MPlayer-Win32 (Build #${MPLAYER_BUILDNO})"
  81 InstallDir "$PROGRAMFILES\MPlayer for Windows"
  82 InstallDirRegKey HKLM "${MPlayerRegPath}" "InstallLocation"
  83 OutFile "${MPLAYER_OUTFILE}"
  84
  85
  86 ;--------------------------------------------------------------------------------
  87 ; COMPRESSOR
  88 ;--------------------------------------------------------------------------------
  89
  90 SetCompressor /SOLID /FINAL LZMA
  91 SetCompressorDictSize 112
  92
  93 !tempfile PACKHDRTEMP
  94 !packhdr "${PACKHDRTEMP}" '"Utils\MT.exe" -manifest "Resources\Setup.manifest" -outputresource:"${PACKHDRTEMP};1"'
  95
  96 #!packhdr "$%TEMP%\exehead.tmp" '"${UPX_PATH}\upx.exe" --brute "$%TEMP%\exehead.tmp"'
  97
  98
  99 ;--------------------------------------------------------------------------------
 100 ; RESERVE FILES
 101 ;--------------------------------------------------------------------------------
 102
 103 ReserveFile "${NSISDIR}\Plugins\Aero.dll"
 104 ReserveFile "${NSISDIR}\Plugins\Banner.dll"
 105 ReserveFile "${NSISDIR}\Plugins\CPUFeatures.dll"
 106 ReserveFile "${NSISDIR}\Plugins\InstallOptions.dll"
 107 ReserveFile "${NSISDIR}\Plugins\LangDLL.dll"
 108 ReserveFile "${NSISDIR}\Plugins\LockedList.dll"
 109 ReserveFile "${NSISDIR}\Plugins\LockedList64.dll"
 110 ReserveFile "${NSISDIR}\Plugins\nsDialogs.dll"
 111 ReserveFile "${NSISDIR}\Plugins\nsExec.dll"
 112 ReserveFile "${NSISDIR}\Plugins\StartMenu.dll"
 113 ReserveFile "${NSISDIR}\Plugins\StdUtils.dll"
 114 ReserveFile "${NSISDIR}\Plugins\System.dll"
 115 ReserveFile "${NSISDIR}\Plugins\UserInfo.dll"
 116 ReserveFile "Dialogs\Page_CPU.ini"
 117 ReserveFile "Resources\Splash.gif"
 118
 119
 120 ;--------------------------------------------------------------------------------
 121 ; INCLUDES
 122 ;--------------------------------------------------------------------------------
 123
 124 !include `MUI2.nsh`
 125 !include `InstallOptions.nsh`
 126 !include `WinVer.nsh`
 127 !include `x64.nsh`
 128 !include `StrFunc.nsh`
 129 !include `StdUtils.nsh`
 130 !include `CPUFeatures.nsh`
 131 !include `MPUI_Common.nsh`
 132
 133 ; Enable functions
 134 ${StrRep}
 135
 136
 137 ;--------------------------------------------------------------------------------
 138 ; GLOBAL VARIABLES
 139 ;--------------------------------------------------------------------------------
 140
 141 Var StartMenuFolder
 142 Var DetectedCPUType
 143 Var DetectedCPUCores
 144 Var SelectedCPUType
 145 Var SelectedTweaks
 146 Var NotUpdateInstall
 147
 148
 149 ;--------------------------------------------------------------------------------
 150 ; VERSION INFO
 151 ;--------------------------------------------------------------------------------
 152
 153 !searchreplace PRODUCT_VERSION_DATE "${MPLAYER_DATE}" "-" "."
 154 VIProductVersion "${PRODUCT_VERSION_DATE}.${MPLAYER_BUILDNO}"
 155
 156 VIAddVersionKey "Author" "LoRd_MuldeR <mulder2@gmx.de>"
 157 VIAddVersionKey "Comments" "This program is free software; you can redistribute it and/or modify it under the terms of the GNU General Public License as published by the Free Software Foundation; either version 2 of the License, or (at your option) any later version."
 158 VIAddVersionKey "CompanyName" "Free Software Foundation"
 159 VIAddVersionKey "FileDescription" "MPlayer for Windows (Build #${MPLAYER_BUILDNO})"
 160 VIAddVersionKey "FileVersion" "${PRODUCT_VERSION_DATE}.${MPLAYER_BUILDNO}"
 161 VIAddVersionKey "LegalCopyright" "Copyright 2000-2016 The MPlayer Project"
 162 VIAddVersionKey "LegalTrademarks" "GNU"
 163 VIAddVersionKey "OriginalFilename" "MPUI-Setup.exe"
 164 VIAddVersionKey "ProductName" "MPlayer for Windows"
 165 VIAddVersionKey "ProductVersion" "Build #${MPLAYER_BUILDNO} (${MPLAYER_DATE})"
 166 VIAddVersionKey "Website" "${MPlayerWebSite}"
 167
 168
 169 ;--------------------------------------------------------------------------------
 170 ; MUI2 INTERFACE SETTINGS
 171 ;--------------------------------------------------------------------------------
 172
 173 !define MUI_ABORTWARNING
 174 !define MUI_STARTMENUPAGE_REGISTRY_ROOT HKLM
 175 !define MUI_STARTMENUPAGE_REGISTRY_KEY "${MPlayerRegPath}"
 176 !define MUI_STARTMENUPAGE_REGISTRY_VALUENAME "StartmenuFolder"
 177 !define MUI_LANGDLL_REGISTRY_ROOT HKLM
 178 !define MUI_LANGDLL_REGISTRY_KEY "${MPlayerRegPath}"
 179 !define MUI_LANGDLL_REGISTRY_VALUENAME "SetupLanguage"
 180 !define MUI_STARTMENUPAGE_DEFAULTFOLDER "MPlayer for Windows"
 181 !define MUI_FINISHPAGE_NOAUTOCLOSE
 182 !define MUI_UNFINISHPAGE_NOAUTOCLOSE
 183 !define MUI_FINISHPAGE_RUN
 184 !define MUI_FINISHPAGE_RUN_FUNCTION RunAppFunction
 185 !define MUI_FINISHPAGE_SHOWREADME
 186 !define MUI_FINISHPAGE_SHOWREADME_FUNCTION ShowReadmeFunction
 187 !define MUI_FINISHPAGE_LINK ${MPlayerWebSite}
 188 !define MUI_FINISHPAGE_LINK_LOCATION ${MPlayerWebSite}
 189 !define MUI_ICON "${NSISDIR}\Contrib\Graphics\Icons\orange-install.ico"
 190 !define MUI_UNICON "${NSISDIR}\Contrib\Graphics\Icons\orange-uninstall.ico"
 191 !define MUI_WELCOMEFINISHPAGE_BITMAP "Artwork\wizard.bmp"
 192 !define MUI_UNWELCOMEFINISHPAGE_BITMAP "Artwork\wizard-un.bmp"
 193 !define MUI_HEADERIMAGE
 194 !define MUI_HEADERIMAGE_BITMAP "Artwork\header.bmp"
 195 !define MUI_HEADERIMAGE_UNBITMAP "Artwork\header-un.bmp"
 196 !define MUI_LANGDLL_ALLLANGUAGES
 197 !define MUI_CUSTOMFUNCTION_GUIINIT MyGuiInit
 198 !define MUI_CUSTOMFUNCTION_UNGUIINIT un.MyGuiInit
 199 !define MUI_LANGDLL_ALWAYSSHOW
 200 !define MUI_COMPONENTSPAGE_SMALLDESC
 201
 202
 203 ;--------------------------------------------------------------------------------
 204 ; MUI2 PAGE SETUP
 205 ;--------------------------------------------------------------------------------
 206
 207 ; Installer
 208 !define MUI_WELCOMEPAGE_TITLE_3LINES
 209 !define MUI_FINISHPAGE_TITLE_3LINES
 210 !insertmacro MUI_PAGE_WELCOME
 211 !insertmacro MUI_PAGE_LICENSE "Docs\License.txt"
 212 !define MUI_PAGE_CUSTOMFUNCTION_SHOW CheckForUpdate
 213 !insertmacro MUI_PAGE_DIRECTORY
 214 !insertmacro  MUI_PAGE_COMPONENTS
 215 !insertmacro MUI_PAGE_STARTMENU Application $StartMenuFolder
 216 Page Custom SelectCPUPage_Show SelectCPUPage_Validate
 217 Page Custom SetTweaksPage_Show
 218 Page Custom LockedListPage_Show
 219 !insertmacro MUI_PAGE_INSTFILES
 220 !insertmacro MUI_PAGE_FINISH
 221
 222 ; Un-Installer
 223 !define MUI_WELCOMEPAGE_TITLE_3LINES
 224 !define MUI_FINISHPAGE_TITLE_3LINES
 225 !insertmacro MUI_UNPAGE_WELCOME
 226 !insertmacro MUI_UNPAGE_CONFIRM
 227 UninstPage Custom un.LockedListPage_Show
 228 !insertmacro MUI_UNPAGE_INSTFILES
 229 !insertmacro MUI_UNPAGE_FINISH
 230
 231
 232 ;--------------------------------------------------------------------------------
 233 ; LANGUAGE
 234 ;--------------------------------------------------------------------------------
 235
 236 !insertmacro MUI_LANGUAGE "English"
 237 !insertmacro MUI_LANGUAGE "German"
 238
 239 ; Translation files
 240 !include "Language\MPUI_EN.nsh"
 241 !include "Language\MPUI_DE.nsh"
 242
 243
 244 ;--------------------------------------------------------------------------------
 245 ; INSTALL TYPES
 246 ;--------------------------------------------------------------------------------
 247
 248 InstType "$(MPLAYER_LANG_INSTTYPE_COMPLETE)"
 249 InstType "$(MPLAYER_LANG_INSTTYPE_MINIMAL)"
 250
 251
 252 ;--------------------------------------------------------------------------------
 253 ; INITIALIZATION
 254 ;--------------------------------------------------------------------------------
 255
 256 Function .onInit
 257         StrCpy $SelectedCPUType 0
 258         StrCpy $DetectedCPUType 0
 259         StrCpy $DetectedCPUCores 0
 260         StrCpy $SelectedTweaks 1
 261         StrCpy $NotUpdateInstall 1
 262
 263         InitPluginsDir
 264
 265         ; --------
 266
 267         System::Call 'kernel32::CreateMutexA(i 0, i 0, t "{B800490C-C100-4B12-9F09-1A54DF063049}") i .r1 ?e'
 268         Pop $0
 269         ${If} $0 <> 0
 270                 MessageBox MB_ICONSTOP|MB_TOPMOST "Oups, the installer is already running!"
 271                 Quit
 272         ${EndIf}
 273
 274         ; --------
 275
 276         # Running on Windows NT family?
 277         ${IfNot} ${IsNT}
 278                 MessageBox MB_TOPMOST|MB_ICONSTOP "Sorry, this application does *not* support Windows 9x or Windows ME!"
 279                 ExecShell "open" "http://windows.microsoft.com/"
 280                 Quit
 281         ${EndIf}
 282
 283         # Running on Windows XP or later?
 284         ${If} ${AtMostWin2000}
 285                 MessageBox MB_TOPMOST|MB_ICONSTOP "Sorry, but your operating system is *not* supported anymore.$\nInstallation will be aborted!$\n$\nThe minimum required platform is Windows XP."
 286                 ExecShell "open" "http://windows.microsoft.com/"
 287                 Quit
 288         ${EndIf}
 289
 290         ; --------
 291
 292         UserInfo::GetAccountType
 293         Pop $0
 294         ${If} $0 != "Admin"
 295                 MessageBox MB_ICONSTOP|MB_TOPMOST "Your system requires administrative permissions in order to install this software."
 296                 SetErrorLevel 740 ;ERROR_ELEVATION_REQUIRED
 297                 Quit
 298         ${EndIf}
 299
 300         ; --------
 301
 302         !insertmacro MUI_LANGDLL_DISPLAY
 303
 304         !insertmacro INSTALLOPTIONS_EXTRACT_AS "Dialogs\Page_CPU.ini"    "Page_CPU.ini"
 305         !insertmacro INSTALLOPTIONS_EXTRACT_AS "Dialogs\Page_Tweaks.ini" "Page_Tweaks.ini"
 306
 307         !ifdef PRE_RELEASE
 308                 ${IfCmd} MessageBox MB_TOPMOST|MB_ICONEXCLAMATION|MB_OKCANCEL|MB_DEFBUTTON2 "Note: This is an early pre-release version for test only!" IDCANCEL ${||} Quit ${|}
 309         !endif
 310
 311         ; --------
 312
 313         ${IfNot} ${Silent}
 314                 File "/oname=$PLUGINSDIR\Splash.gif" "Resources\Splash.gif"
 315                 newadvsplash::show 3000 1000 500 -1 /NOCANCEL "$PLUGINSDIR\Splash.gif"
 316                 Delete /REBOOTOK "$PLUGINSDIR\Splash.gif"
 317         ${EndIf}
 318 FunctionEnd
 319
 320 Function un.onInit
 321         InitPluginsDir
 322
 323         System::Call 'kernel32::CreateMutexA(i 0, i 0, t "{B800490C-C100-4B12-9F09-1A54DF063049}") i .r1 ?e'
 324         Pop $0
 325         ${If} $0 <> 0
 326                 MessageBox MB_ICONSTOP|MB_TOPMOST "Sorry, the un-installer is already running!"
 327                 Quit
 328         ${EndIf}
 329
 330         ; --------
 331
 332         UserInfo::GetAccountType
 333         Pop $0
 334         ${If} $0 != "Admin"
 335                 MessageBox MB_ICONSTOP|MB_TOPMOST "Your system requires administrative permissions in order to un-install this software."
 336                 SetErrorLevel 740 ;ERROR_ELEVATION_REQUIRED
 337                 Quit
 338         ${EndIf}
 339
 340         ; --------
 341
 342         !insertmacro MUI_LANGDLL_DISPLAY
 343 FunctionEnd
 344
 345
 346 ;--------------------------------------------------------------------------------
 347 ; GUI INITIALIZATION
 348 ;--------------------------------------------------------------------------------
 349
 350 Function MyGuiInit
 351         StrCpy $0 $HWNDPARENT
 352         System::Call "user32::SetWindowPos(i r0, i -1, i 0, i 0, i 0, i 0, i 3)"
 353         Aero::Apply
 354 FunctionEnd
 355
 356 Function un.MyGuiInit
 357         StrCpy $0 $HWNDPARENT
 358         System::Call "user32::SetWindowPos(i r0, i -1, i 0, i 0, i 0, i 0, i 3)"
 359         Aero::Apply
 360 FunctionEnd
 361
 362
 363 ;--------------------------------------------------------------------------------
 364 ; INSTALL SECTIONS
 365 ;--------------------------------------------------------------------------------
 366
 367 Section "-Clean Up"
 368         ${PrintProgress} "$(MPLAYER_LANG_STATUS_INST_CLEAN)"
 369
 370         SetShellVarContext all
 371         SetOutPath "$INSTDIR"
 372
 373         ; Uninstall old version (aka "Setup v1")
 374         ClearErrors
 375         ReadRegStr $0 HKLM "SOFTWARE\Microsoft\Windows\CurrentVersion\Uninstall\{DB9E4EAB-2717-499F-8D56-4CC8A644AB60}" "InstallLocation"
 376         ${IfNot} ${Errors}
 377                 MessageBox MB_ICONINFORMATION|MB_OK "$(MPLAYER_LANG_UNINSTALL_OLDVER)"
 378                 File "/oname=$PLUGINSDIR\Uninstall-V1.exe" "Resources\Uninstall-V1.exe"
 379                 HideWindow
 380                 ExecWait '"$PLUGINSDIR\Uninstall-V1.exe" _?=$0'
 381                 Delete /REBOOTOK "$PLUGINSDIR\Uninstall-V1.exe"
 382                 BringToFront
 383         ${EndIf}
 384
 385         ; Clean registry
 386         DeleteRegKey HKLM "SOFTWARE\Microsoft\Windows\CurrentVersion\Uninstall\{DB9E4EAB-2717-499F-8D56-4CC8A644AB60}"
 387         DeleteRegKey HKCU "SOFTWARE\Microsoft\Windows\CurrentVersion\Uninstall\{DB9E4EAB-2717-499F-8D56-4CC8A644AB60}"
 388         DeleteRegValue HKLM "SOFTWARE\Microsoft\Windows\CurrentVersion\Run" "MPlayerForWindows_UpdateReminder"
 389         DeleteRegValue HKCU "SOFTWARE\Microsoft\Windows\CurrentVersion\Run" "MPlayerForWindows_UpdateReminder"
 390
 391         ; Make sure MPlayer isn't running
 392         ${Do}
 393                 ClearErrors
 394                 Delete "$INSTDIR\MPlayer.exe"
 395                 Delete "$INSTDIR\SMPlayer.exe"
 396                 Delete "$INSTDIR\MPUI.exe"
 397                 ${If} ${Errors}
 398                         ${IfCmd} MessageBox MB_TOPMOST|MB_ICONEXCLAMATION|MB_OKCANCEL "$(MPLAYER_LANG_STILL_RUNNING)" IDCANCEL ${||} Abort ${|}
 399                 ${Else}
 400                         ${Break}
 401                 ${EndIf}
 402         ${Loop}
 403
 404         ; Clean the install folder
 405         Delete "$INSTDIR\*.exe"
 406         Delete "$INSTDIR\*.dll"
 407         Delete "$INSTDIR\*.ini"
 408         Delete "$INSTDIR\*.txt"
 409         Delete "$INSTDIR\*.html"
 410         Delete "$INSTDIR\*.htm"
 411         Delete "$INSTDIR\*.ass"
 412         Delete "$INSTDIR\*.m3u8"
 413         Delete "$INSTDIR\*.tag"
 414
 415         RMDir /r "$INSTDIR\codecs"
 416         RMDir /r "$INSTDIR\fonts"
 417         RMDir /r "$INSTDIR\imageformats"
 418         RMDir /r "$INSTDIR\legal_stuff"
 419         RMDir /r "$INSTDIR\locale"
 420         RMDir /r "$INSTDIR\mplayer"
 421         RMDir /r "$INSTDIR\platforms"
 422         RMDir /r "$INSTDIR\shortcuts"
 423         RMDir /r "$INSTDIR\themes"
 424         RMDir /r "$INSTDIR\translations"
 425
 426         ; Now deal with Virtual Store
 427         ${GetVirtualStorePath} $0 "$INSTDIR"
 428         ${If} ${FileExists} "$0\*.*"
 429                 RMDir /r "$0"
 430         ${EndIf}
 431 SectionEnd
 432
 433 Section "!MPlayer r${MPLAYER_REVISION}" SECID_MPLAYER
 434         SectionIn 1 2 RO
 435         ${PrintProgress} "$(MPLAYER_LANG_STATUS_INST_MPLAYER)"
 436         SetOutPath "$INSTDIR"
 437
 438         ; Detect
 439         ${If} ${Silent}
 440                 Call DetectCPUType
 441                 StrCpy $SelectedCPUType $DetectedCPUType
 442         ${EndIf}
 443
 444         ; MPlayer.exe
 445         ${Select} $SelectedCPUType
 446                 ${Case} "2"
 447                         DetailPrint "$(MPLAYER_LANG_SELECTED_TYPE): core2"
 448                         File "Builds\MPlayer-core2\MPlayer.exe"
 449                 ${Case} "3"
 450                         DetailPrint "$(MPLAYER_LANG_SELECTED_TYPE): corei7"
 451                         File "Builds\MPlayer-corei7\MPlayer.exe"
 452                 ${Case} "4"
 453                         DetailPrint "$(MPLAYER_LANG_SELECTED_TYPE): k8-sse3"
 454                         File "Builds\MPlayer-k8-sse3\MPlayer.exe"
 455                 ${Case} "5"
 456                         DetailPrint "$(MPLAYER_LANG_SELECTED_TYPE): generic"
 457                         File "Builds\MPlayer-generic\MPlayer.exe"
 458                 ${CaseElse}
 459                         MessageBox MB_TOPMOST|MB_ICONEXCLAMATION|MB_OK "Internal error: Invalid CPU type selection detected!"
 460                         Abort
 461         ${EndSelect}
 462
 463         ; Utilities
 464         File ".Compile\Updater.exe"
 465         File "Resources\AppRegGUI.exe"
 466
 467         ; Other MPlayer-related files
 468         File "Builds\MPlayer-generic\*.dll"
 469         ${ExtractSubDir} "Builds\MPlayer-generic" "mplayer"
 470         ${ExtractSubDir} "Builds\MPlayer-generic" "fonts"
 471
 472         ; Documents
 473         SetOutPath "$INSTDIR"
 474         File "GPL.txt"
 475         File "/oname=Manual.html" "Builds\MPlayer-generic\MPlayer.man.html"
 476         File "Docs\Readme.html"
 477         SetOutPath "$INSTDIR\legal_stuff"
 478         File "Docs\legal_stuff\*.txt"
 479
 480         ; Write version tag
 481         ${Do}
 482                 ClearErrors
 483                 Delete "$INSTDIR\version.tag"
 484                 ${If} ${Errors}
 485                         ${IfCmd} MessageBox MB_TOPMOST|MB_ICONEXCLAMATION|MB_OKCANCEL "$(MPLAYER_LANG_TAG_WRITE)" IDCANCEL ${||} Abort ${|}
 486                 ${Else}
 487                         ${Break}
 488                 ${EndIf}
 489         ${Loop}
 490         WriteINIStr "$INSTDIR\version.tag" "mplayer_version" "build_no" "${MPLAYER_BUILDNO}"
 491         WriteINIStr "$INSTDIR\version.tag" "mplayer_version" "pkg_date" "${MPLAYER_DATE}"
 492         SetFileAttributes "$INSTDIR\version.tag" FILE_ATTRIBUTE_READONLY
 493
 494         ; Set file access rights
 495         ${MakePathPublic} "$INSTDIR"
 496         ${MakeFilePublic} "$INSTDIR\mplayer\config"
 497         ${MakeFilePublic} "$INSTDIR\fonts\fonts.conf"
 498 SectionEnd
 499
 500 Section "!MPUI $(MPLAYER_LANG_FRONT_END) v${MPUI_VERSION}" SECID_MPUI
 501         SectionIn 1 2
 502         ${PrintProgress} "$(MPLAYER_LANG_STATUS_INST_MPUI)"
 503
 504         ; Extract files
 505         SetOutPath "$INSTDIR"
 506         File "MPUI\MPUI.exe"
 507
 508         ; Extract locales
 509         SetOutPath "$INSTDIR\locale"
 510         File "MPUI\locale\*.txt"
 511
 512         ; Set file access rights
 513         ${MakeFilePublic} "$INSTDIR\MPUI.ini"
 514
 515         ; Setup initial config
 516         ClearErrors
 517         WriteINIStr "$INSTDIR\MPUI.ini" "MPUI" "Params" "-vo direct3d -lavdopts threads=$DetectedCPUCores"
 518         WriteINIStr "$INSTDIR\MPUI.ini" "MPUI" "Locale" "$(MPLAYER_LANG_MPUI_DEFAULT_LANGUAGE)"
 519         ${If} ${Errors}
 520                 ${IfCmd} MessageBox MB_TOPMOST|MB_ICONSTOP|MB_DEFBUTTON2|MB_OKCANCEL "$(MPLAYER_LANG_CONFIG_MPUI)" IDCANCEL ${||} Abort ${|}
 521         ${EndIf}
 522 SectionEnd
 523
 524 Section "!SMPlayer $(MPLAYER_LANG_FRONT_END) v${SMPLAYER_VERSION}" SECID_SMPLAYER
 525         SectionIn 1
 526         ${PrintProgress} "$(MPLAYER_LANG_STATUS_INST_SMPLAYER)"
 527
 528         ; SMPlayer program files
 529         SetOutPath "$INSTDIR"
 530         File "SMPlayer\*.exe"
 531         File "SMPlayer\*.dll"
 532
 533         ; Additional SMPlayer files
 534         ${ExtractSubDir} "SMPlayer" "imageformats"
 535         ${ExtractSubDir} "SMPlayer" "platforms"
 536         ${ExtractSubDir} "SMPlayer" "shortcuts"
 537         ${ExtractSubDir} "SMPlayer" "themes"
 538         ${ExtractSubDir} "SMPlayer" "translations"
 539
 540         ; Set file access rights
 541         ${MakeFilePublic} "$INSTDIR\SMPlayer.ini"
 542         ${MakeFilePublic} "$INSTDIR\SMPlayer_files.ini"
 543         ${MakeFilePublic} "$INSTDIR\player_info.ini"
 544         ${MakeFilePublic} "$INSTDIR\playlist.ini"
 545         ${MakeFilePublic} "$INSTDIR\favorites.m3u8"
 546         ${MakeFilePublic} "$INSTDIR\radio.m3u8"
 547         ${MakeFilePublic} "$INSTDIR\tv.m3u8"
 548         ${MakeFilePublic} "$INSTDIR\styles.ass"
 549         ${MakeFilePublic} "$INSTDIR\shortcuts\default.keys"
 550
 551         ; Setup initial config
 552         ${StrRep} $0 "$INSTDIR\MPlayer.exe" "\" "/"
 553         ClearErrors
 554         WriteINIStr "$INSTDIR\SMPlayer.ini" "%General"       "autosync"                      "true"
 555         WriteINIStr "$INSTDIR\SMPlayer.ini" "%General"       "autosync_factor"               "30"
 556         WriteINIStr "$INSTDIR\SMPlayer.ini" "%General"       "config_version"                "4"
 557         WriteINIStr "$INSTDIR\SMPlayer.ini" "%General"       "driver\vo"                     "direct3d"
 558         WriteINIStr "$INSTDIR\SMPlayer.ini" "%General"       "file_settings_method"          "normal"
 559         WriteINIStr "$INSTDIR\SMPlayer.ini" "%General"       "mplayer_bin"                   "$0"
 560         WriteINIStr "$INSTDIR\SMPlayer.ini" "%General"       "osd"                           "1"
 561         WriteINIStr "$INSTDIR\SMPlayer.ini" "%General"       "use_audio_equalizer"           "false"
 562         WriteINIStr "$INSTDIR\SMPlayer.ini" "%General"       "use_scaletempo"                "0"
 563         WriteINIStr "$INSTDIR\SMPlayer.ini" "advanced"       "mplayer_additional_options"    ""
 564         WriteINIStr "$INSTDIR\SMPlayer.ini" "gui"            "gui"                           "DefaultGUI"
 565         WriteINIStr "$INSTDIR\SMPlayer.ini" "gui"            "iconset"                       "Numix-remix"
 566         WriteINIStr "$INSTDIR\SMPlayer.ini" "gui"            "style"                         "Plastique"
 567         WriteINIStr "$INSTDIR\SMPlayer.ini" "mplayer_info"   "is_mplayer2"                   "false"
 568         WriteINIStr "$INSTDIR\SMPlayer.ini" "mplayer_info"   "mplayer_detected_version"      "${MPLAYER_REVISION}"
 569         WriteINIStr "$INSTDIR\SMPlayer.ini" "mplayer_info"   "mplayer_user_supplied_version" "-1"
 570         WriteINIStr "$INSTDIR\SMPlayer.ini" "performance"    "frame_drop"                    "true"
 571         WriteINIStr "$INSTDIR\SMPlayer.ini" "performance"    "priority"                      "1"
 572         WriteINIStr "$INSTDIR\SMPlayer.ini" "performance"    "threads"                       "$DetectedCPUCores"
 573         WriteINIStr "$INSTDIR\SMPlayer.ini" "smplayer"       "check_for_new_version"         "false"
 574         WriteINIStr "$INSTDIR\SMPlayer.ini" "smplayer"       "check_if_upgraded"             "false"
 575         WriteINIStr "$INSTDIR\SMPlayer.ini" "update_checker" "enabled"                       "false"
 576
 577         ${If} ${Errors}
 578                 ${IfCmd} MessageBox MB_TOPMOST|MB_ICONSTOP|MB_DEFBUTTON2|MB_OKCANCEL "$(MPLAYER_LANG_CONFIG_SMPLAYER)" IDCANCEL ${||} Abort ${|}
 579         ${EndIf}
 580 SectionEnd
 581
 582 Section "!$(MPLAYER_LANG_BIN_CODECS) (${CODECS_DATE})"
 583         SectionIn 1
 584         ${PrintProgress} "$(MPLAYER_LANG_STATUS_INST_CODECS)"
 585
 586         SetOutPath "$INSTDIR\codecs"
 587
 588         File "Codecs\*.0"
 589         File "Codecs\*.acm"
 590         File "Codecs\*.ax"
 591         File "Codecs\*.dll"
 592         File "Codecs\*.qtx"
 593         File "Codecs\*.so"
 594         File "Codecs\*.vwp"
 595         File "Codecs\*.xa"
 596 SectionEnd
 597
 598 Section "-Write Uninstaller"
 599         ${PrintProgress} "$(MPLAYER_LANG_STATUS_MAKEUNINST)"
 600         WriteUninstaller "$INSTDIR\Uninstall.exe"
 601 SectionEnd
 602
 603 Section "-Create Shortcuts"
 604         !insertmacro MUI_STARTMENU_WRITE_BEGIN Application
 605                 ${PrintProgress} "$(MPLAYER_LANG_STATUS_SHORTCUTS)"
 606                 CreateDirectory "$SMPROGRAMS\$StartMenuFolder"
 607
 608                 SetShellVarContext current
 609                 Delete "$SMPROGRAMS\$StartMenuFolder\*.lnk"
 610                 Delete "$SMPROGRAMS\$StartMenuFolder\*.pif"
 611                 Delete "$SMPROGRAMS\$StartMenuFolder\*.url"
 612
 613                 SetShellVarContext all
 614                 Delete "$SMPROGRAMS\$StartMenuFolder\*.lnk"
 615                 Delete "$SMPROGRAMS\$StartMenuFolder\*.pif"
 616                 Delete "$SMPROGRAMS\$StartMenuFolder\*.url"
 617
 618                 ${If} ${FileExists} "$INSTDIR\MPUI.exe"
 619                         CreateShortCut "$SMPROGRAMS\$StartMenuFolder\MPUI.lnk" "$INSTDIR\MPUI.exe"
 620                         CreateShortCut "$DESKTOP\MPUI.lnk" "$INSTDIR\MPUI.exe"
 621                 ${EndIf}
 622                 ${If} ${FileExists} "$INSTDIR\SMPlayer.exe"
 623                         CreateShortCut "$SMPROGRAMS\$StartMenuFolder\SMPlayer.lnk" "$INSTDIR\SMPlayer.exe"
 624                         CreateShortCut "$DESKTOP\SMPlayer.lnk" "$INSTDIR\SMPlayer.exe"
 625                 ${EndIf}
 626
 627                 CreateShortCut "$SMPROGRAMS\$StartMenuFolder\$(MPLAYER_LANG_SHORTCUT_UPDATE).lnk" "$INSTDIR\Updater.exe" "/L=$LANGUAGE"
 628                 CreateShortCut "$SMPROGRAMS\$StartMenuFolder\$(MPLAYER_LANG_SHORTCUT_README).lnk" "$INSTDIR\Readme.html"
 629                 CreateShortCut "$SMPROGRAMS\$StartMenuFolder\$(MPLAYER_LANG_SHORTCUT_MANUAL).lnk" "$INSTDIR\Manual.html"
 630
 631                 ${If} ${AtLeastWinVista}
 632                         CreateShortCut "$SMPROGRAMS\$StartMenuFolder\$(MPLAYER_LANG_SHORTCUT_APPREG).lnk" "$INSTDIR\AppRegGUI.exe"
 633                 ${EndIf}
 634
 635                 ${CreateWebLink} "$SMPROGRAMS\$StartMenuFolder\$(MPLAYER_LANG_SHORTCUT_SITE_MULDERS).url" "http://muldersoft.com/"
 636                 ${CreateWebLink} "$SMPROGRAMS\$StartMenuFolder\$(MPLAYER_LANG_SHORTCUT_SITE_MPWIN32).url" "http://oss.netfarm.it/mplayer-win32.php"
 637                 ${CreateWebLink} "$SMPROGRAMS\$StartMenuFolder\$(MPLAYER_LANG_SHORTCUT_SITE_MPLAYER).url" "http://www.mplayerhq.hu/"
 638
 639                 ${If} ${FileExists} "$SMPROGRAMS\$StartMenuFolder\SMPlayer.lnk"
 640                         ${StdUtils.InvokeShellVerb} $R1 "$SMPROGRAMS\$StartMenuFolder" "SMPlayer.lnk" ${StdUtils.Const.ShellVerb.PinToTaskbar}
 641                         DetailPrint 'Pin: "$SMPROGRAMS\$StartMenuFolder\SMPlayer.lnk" -> $R1'
 642                 ${EndIf}
 643         !insertmacro MUI_STARTMENU_WRITE_END
 644 SectionEnd
 645
 646 Section "-ApplyTweaks"
 647         ${PrintProgress} "$(MPLAYER_LANG_STATUS_TWEAKS)"
 648         DetailPrint "$(MPLAYER_LANG_APPLYING_TWEAKS)"
 649
 650         IntOp $0 $SelectedTweaks & 1
 651         ${If} $0 != 0
 652                 ${If} ${FileExists} "$INSTDIR\SMPlayer.ini"
 653                         WriteINIStr "$INSTDIR\SMPlayer.ini" "gui" "gui"     "SkinGUI"
 654                         WriteINIStr "$INSTDIR\SMPlayer.ini" "gui" "iconset" "Gonzo"
 655                         WriteINIStr "$INSTDIR\SMPlayer.ini" "gui" "style"   "Plastique"
 656                 ${EndIf}
 657         ${EndIf}
 658
 659         IntOp $0 $SelectedTweaks & 2
 660         ${If} $0 != 0
 661                 ${If} ${FileExists} "$INSTDIR\MPUI.ini"
 662                         WriteINIStr "$INSTDIR\MPUI.ini" "MPUI" "Params" "-vo gl:yuv=3 -lavdopts threads=$DetectedCPUCores"
 663                 ${EndIf}
 664                 ${If} ${FileExists} "$INSTDIR\SMPlayer.ini"
 665                         WriteINIStr "$INSTDIR\SMPlayer.ini" "%General" "driver\vo" "gl:yuv=3"
 666                 ${EndIf}
 667         ${EndIf}
 668
 669         IntOp $0 $SelectedTweaks & 4
 670         ${If} $0 != 0
 671                 ${If} ${FileExists} "$INSTDIR\MPUI.ini"
 672                         ReadINIStr $1 "$INSTDIR\MPUI.ini" "MPUI" "Params"
 673                         WriteINIStr "$INSTDIR\MPUI.ini" "MPUI" "Params" "$1 -af volnorm=2"
 674                 ${EndIf}
 675                 ${If} ${FileExists} "$INSTDIR\SMPlayer.ini"
 676                         WriteINIStr "$INSTDIR\SMPlayer.ini" "defaults" "initial_volnorm" "true"
 677                 ${EndIf}
 678         ${EndIf}
 679 SectionEnd
 680
 681 Section "$(MPLAYER_LANG_COMPRESS_FILES)"
 682         SectionIn 1 2
 683         ${PrintProgress} "$(MPLAYER_LANG_STATUS_INST_COMPRESS)"
 684
 685         File "/oname=$PLUGINSDIR\UPX.exe" "Utils\UPX.exe"
 686
 687         ${PackAll} "$INSTDIR" "*.exe"
 688         ${PackAll} "$INSTDIR" "*.dll"
 689         ${PackAll} "$INSTDIR\codecs" "*.acm"
 690         ${PackAll} "$INSTDIR\codecs" "*.ax"
 691         ${PackAll} "$INSTDIR\codecs" "*.dll"
 692         ${PackAll} "$INSTDIR\codecs" "*.qtx"
 693
 694         Delete "$PLUGINSDIR\UPX.exe"
 695 SectionEnd
 696
 697 Section "-Update Font Cache"
 698         ${PrintProgress} "$(MPLAYER_LANG_STATUS_INST_FONTCACHE)"
 699
 700         SetShellVarContext current
 701         Delete "$APPDATA\fontconfig\cache\*.*"
 702         Delete "$LOCALAPPDATA\fontconfig\cache\*.*"
 703
 704         SetShellVarContext all
 705         Delete "$APPDATA\fontconfig\cache\*.*"
 706         Delete "$LOCALAPPDATA\fontconfig\cache\*.*"
 707
 708         File "/oname=$PLUGINSDIR\Sample.avi" "Resources\Sample.avi"
 709         DetailPrint "$(MPLAYER_LANG_UPDATING_FONTCACHE)"
 710         NsExec::Exec '"$INSTDIR\MPlayer.exe" -fontconfig -ass -vo null -ao null "$PLUGINSDIR\Sample.avi"'
 711         Delete "Resources\Sample.avi"
 712 SectionEnd
 713
 714 Section "-Update Registry"
 715         ${PrintProgress} "$(MPLAYER_LANG_STATUS_REGISTRY)"
 716         DetailPrint "$(MPLAYER_LANG_WRITING_REGISTRY)"
 717
 718         ; Clean up
 719         DeleteRegKey HKLM "${MPlayerRegPath}"
 720         DeleteRegKey HKCU "${MPlayerRegPath}"
 721         DeleteRegValue HKLM "SOFTWARE\Microsoft\Windows\CurrentVersion\Run" "MPlayerForWindows_AutoUpdateV2"
 722         DeleteRegValue HKCU "SOFTWARE\Microsoft\Windows\CurrentVersion\Run" "MPlayerForWindows_AutoUpdateV2"
 723
 724         ; Uninstaller
 725         WriteRegStr HKLM "${MPlayerRegPath}" "InstallLocation" "$INSTDIR"
 726         WriteRegStr HKLM "${MPlayerRegPath}" "UninstallString" '"$INSTDIR\Uninstall.exe"'
 727         WriteRegStr HKLM "${MPlayerRegPath}" "DisplayName" "$(MPLAYER_LANG_MPLAYER_WIN32)"
 728         WriteRegStr HKLM "${MPlayerRegPath}" "DisplayIcon" "$INSTDIR\MPlayer.exe,0"
 729         WriteRegStr HKLM "${MPlayerRegPath}" "DisplayVersion" "${MPLAYER_DATE}"
 730         WriteRegStr HKLM "${MPlayerRegPath}" "URLInfoAbout" "http://muldersoft.com/"
 731         WriteRegStr HKLM "${MPlayerRegPath}" "URLUpdateInfo" "http://muldersoft.com/"
 732         WriteRegStr HKLM "${MPlayerRegPath}" "Publisher" "The MPlayer Team"
 733         WriteRegDWORD HKLM "${MPlayerRegPath}" "NoModify" 1
 734         WriteRegDWORD HKLM "${MPlayerRegPath}" "NoRepair" 1
 735
 736         ; Shell
 737         DeleteRegKey HKCR "MPlayerForWindowsV2.File"
 738         DeleteRegKey HKLM "SOFTWARE\Classes\MPlayerForWindowsV2.File"
 739         DeleteRegKey HKCU "SOFTWARE\Classes\MPlayerForWindowsV2.File"
 740         ${If} ${FileExists} "$INSTDIR\MPUI.exe"
 741                 WriteRegStr HKLM "SOFTWARE\Classes\MPlayerForWindowsV2.File\shell\open\command" "" '"$INSTDIR\MPUI.exe" "%1"'
 742                 WriteRegStr HKLM "SOFTWARE\Classes\MPlayerForWindowsV2.File\DefaultIcon" "" "$INSTDIR\MPUI.exe,0"
 743         ${EndIf}
 744         ${If} ${FileExists} "$INSTDIR\SMPlayer.exe"
 745                 WriteRegStr HKLM "SOFTWARE\Classes\MPlayerForWindowsV2.File\shell\open\command" "" '"$INSTDIR\SMPlayer.exe" "%1"'
 746                 WriteRegStr HKLM "SOFTWARE\Classes\MPlayerForWindowsV2.File\DefaultIcon" "" "$INSTDIR\SMPlayer.exe,1"
 747         ${EndIf}
 748
 749         ; Register App
 750         DeleteRegValue HKCU "SOFTWARE\RegisteredApplications" "MPlayerForWindowsV2"
 751         WriteRegStr HKLM "SOFTWARE\RegisteredApplications" "MPlayerForWindowsV2" "${MPlayerRegPath}\Capabilities"
 752
 753         ; Capabilities
 754         WriteRegStr HKLM "${MPlayerRegPath}\Capabilities" "ApplicationName" "$(MPLAYER_LANG_MPLAYER_WIN32)"
 755         WriteRegStr HKLM "${MPlayerRegPath}\Capabilities" "ApplicationDescription" "$(MPLAYER_LANG_MPLAYER_WIN32)"
 756         WriteRegStr HKLM "${MPlayerRegPath}\Capabilities" "ApplicationDescription" "$(MPLAYER_LANG_MPLAYER_WIN32)"
 757
 758         ; File Associations
 759         ${RegisterFileExtCapability} "256"
 760         ${RegisterFileExtCapability} "3GP"
 761         ${RegisterFileExtCapability} "AAC"
 762         ${RegisterFileExtCapability} "ASF"
 763         ${RegisterFileExtCapability} "AVI"
 764         ${RegisterFileExtCapability} "BIN"
 765         ${RegisterFileExtCapability} "DAT"
 766         ${RegisterFileExtCapability} "DIVX"
 767         ${RegisterFileExtCapability} "EVO"
 768         ${RegisterFileExtCapability} "FLV"
 769         ${RegisterFileExtCapability} "M2V"
 770         ${RegisterFileExtCapability} "M2TS"
 771         ${RegisterFileExtCapability} "M4A"
 772         ${RegisterFileExtCapability} "MKA"
 773         ${RegisterFileExtCapability} "MKV"
 774         ${RegisterFileExtCapability} "MOV"
 775         ${RegisterFileExtCapability} "MP2"
 776         ${RegisterFileExtCapability} "MP3"
 777         ${RegisterFileExtCapability} "MP4"
 778         ${RegisterFileExtCapability} "MPEG"
 779         ${RegisterFileExtCapability} "MPG"
 780         ${RegisterFileExtCapability} "MPV"
 781         ${RegisterFileExtCapability} "NSV"
 782         ${RegisterFileExtCapability} "OGG"
 783         ${RegisterFileExtCapability} "OGM"
 784         ${RegisterFileExtCapability} "RM"
 785         ${RegisterFileExtCapability} "RMVB"
 786         ${RegisterFileExtCapability} "TS"
 787         ${RegisterFileExtCapability} "VOB"
 788         ${RegisterFileExtCapability} "WAV"
 789         ${RegisterFileExtCapability} "WEBM"
 790         ${RegisterFileExtCapability} "WMV"
 791
 792         ; Reset auto update interval
 793         DeleteRegValue HKLM "${MPlayerRegPath}" "LastUpdateCheck"
 794         DeleteRegValue HKCU "${MPlayerRegPath}" "LastUpdateCheck"
 795 SectionEnd
 796
 797 Section "$(MPLAYER_LANG_INST_AUTOUPDATE)" SECID_AUTOUPDATE
 798         SectionIn 1 2
 799         DetailPrint "$(MPLAYER_LANG_SCHEDULE_UPDATE)"
 800         WriteRegStr HKLM "SOFTWARE\Microsoft\Windows\CurrentVersion\Run" "MPlayerForWindows_AutoUpdateV2" '"$INSTDIR\Updater.exe" /L=$LANGUAGE /AutoCheck'
 801 SectionEnd
 802
 803 Section "-Protect Files"
 804         SetFileAttributes "$INSTDIR\AppRegGUI.exe"       FILE_ATTRIBUTE_READONLY
 805         SetFileAttributes "$INSTDIR\mplayer.exe"         FILE_ATTRIBUTE_READONLY
 806         SetFileAttributes "$INSTDIR\MPUI.exe"            FILE_ATTRIBUTE_READONLY
 807         SetFileAttributes "$INSTDIR\smplayer.exe"        FILE_ATTRIBUTE_READONLY
 808         SetFileAttributes "$INSTDIR\Updater.exe"         FILE_ATTRIBUTE_READONLY
 809
 810         SetFileAttributes "$INSTDIR\dsnative.dll"        FILE_ATTRIBUTE_READONLY
 811         SetFileAttributes "$INSTDIR\libeay32.dll"        FILE_ATTRIBUTE_READONLY
 812         SetFileAttributes "$INSTDIR\libgcc_s_dw2-1.dll"  FILE_ATTRIBUTE_READONLY
 813         SetFileAttributes "$INSTDIR\libstdc++-6.dll"     FILE_ATTRIBUTE_READONLY
 814         SetFileAttributes "$INSTDIR\libwinpthread-1.dll" FILE_ATTRIBUTE_READONLY
 815         SetFileAttributes "$INSTDIR\Qt5Core.dll"         FILE_ATTRIBUTE_READONLY
 816         SetFileAttributes "$INSTDIR\Qt5Gui.dll"          FILE_ATTRIBUTE_READONLY
 817         SetFileAttributes "$INSTDIR\Qt5Network.dll"      FILE_ATTRIBUTE_READONLY
 818         SetFileAttributes "$INSTDIR\Qt5Script.dll"       FILE_ATTRIBUTE_READONLY
 819         SetFileAttributes "$INSTDIR\Qt5Widgets.dll"      FILE_ATTRIBUTE_READONLY
 820         SetFileAttributes "$INSTDIR\Qt5Xml.dll"          FILE_ATTRIBUTE_READONLY
 821         SetFileAttributes "$INSTDIR\ssleay32.dll"        FILE_ATTRIBUTE_READONLY
 822         SetFileAttributes "$INSTDIR\zlib1.dll"           FILE_ATTRIBUTE_READONLY
 823 SectionEnd
 824
 825 Section "-Finished"
 826         ${PrintStatus} "$(MUI_TEXT_FINISH_TITLE)"
 827 SectionEnd
 828
 829
 830 ;--------------------------------------------------------------------------------
 831 ; UN-INSTALL SECTIONS
 832 ;--------------------------------------------------------------------------------
 833
 834 Section "Uninstall"
 835         SetOutPath "$TEMP"
 836         ${PrintProgress} "$(MPLAYER_LANG_STATUS_UNINSTALL)"
 837
 838         ; Validate uninstall path
 839         ${IfThen} "$INSTDIR" == "" ${|} Abort ${|}
 840         StrCpy $0 "$INSTDIR" "" -2
 841         ${IfThen} $0 == ":\" ${|} Abort ${|}
 842
 843         ; Startmenu
 844         !insertmacro MUI_STARTMENU_GETFOLDER Application $StartMenuFolder
 845         ${IfNot} "$StartMenuFolder" == ""
 846                 SetShellVarContext current
 847                 ${If} ${FileExists} "$SMPROGRAMS\$StartMenuFolder\SMPlayer.lnk"
 848                         ${StdUtils.InvokeShellVerb} $R1 "$SMPROGRAMS\$StartMenuFolder" "SMPlayer.lnk" ${StdUtils.Const.ShellVerb.UnpinFromTaskbar}
 849                         DetailPrint 'Unpin: "$SMPROGRAMS\$StartMenuFolder\SMPlayer.lnk" -> $R1'
 850                 ${EndIf}
 851                 ${If} ${FileExists} "$SMPROGRAMS\$StartMenuFolder\*.*"
 852                         Delete /REBOOTOK "$SMPROGRAMS\$StartMenuFolder\*.lnk"
 853                         Delete /REBOOTOK "$SMPROGRAMS\$StartMenuFolder\*.url"
 854                         Delete /REBOOTOK "$SMPROGRAMS\$StartMenuFolder\*.pif"
 855                         RMDir "$SMPROGRAMS\$StartMenuFolder"
 856                 ${EndIf}
 857                 SetShellVarContext all
 858                 ${If} ${FileExists} "$SMPROGRAMS\$StartMenuFolder\SMPlayer.lnk"
 859                         ${StdUtils.InvokeShellVerb} $R1 "$SMPROGRAMS\$StartMenuFolder" "SMPlayer.lnk" ${StdUtils.Const.ShellVerb.UnpinFromTaskbar}
 860                         DetailPrint 'Unpin: "$SMPROGRAMS\$StartMenuFolder\SMPlayer.lnk" -> $R1'
 861                 ${EndIf}
 862                 ${If} ${FileExists} "$SMPROGRAMS\$StartMenuFolder\*.*"
 863                         Delete /REBOOTOK "$SMPROGRAMS\$StartMenuFolder\*.lnk"
 864                         Delete /REBOOTOK "$SMPROGRAMS\$StartMenuFolder\*.url"
 865                         Delete /REBOOTOK "$SMPROGRAMS\$StartMenuFolder\*.pif"
 866                         RMDir "$SMPROGRAMS\$StartMenuFolder"
 867                 ${EndIf}
 868         ${EndIf}
 869
 870         ; Desktop icons
 871         Delete /REBOOTOK "$DESKTOP\MPUI.lnk"
 872         Delete /REBOOTOK "$DESKTOP\SMPlayer.lnk"
 873
 874         ; Files
 875         RMDir /r "$INSTDIR"
 876
 877         ; Virtual Store
 878         ${GetVirtualStorePath} $0 "$INSTDIR"
 879         ${If} ${FileExists} "$0\*.*"
 880                 RMDir /r "$0"
 881         ${EndIf}
 882
 883         ; Registry Keys
 884         DeleteRegKey HKLM "${MPlayerRegPath}"
 885         DeleteRegKey HKCU "${MPlayerRegPath}"
 886         DeleteRegValue HKLM "SOFTWARE\RegisteredApplications" "MPlayerForWindowsV2"
 887         DeleteRegValue HKCU "SOFTWARE\RegisteredApplications" "MPlayerForWindowsV2"
 888
 889         ; Auto Update
 890         DeleteRegValue HKLM "SOFTWARE\Microsoft\Windows\CurrentVersion\Run" "MPlayerForWindows_AutoUpdateV2"
 891         DeleteRegValue HKCU "SOFTWARE\Microsoft\Windows\CurrentVersion\Run" "MPlayerForWindows_AutoUpdateV2"
 892
 893         ; Shell
 894         DeleteRegKey HKCR "MPlayerForWindowsV2.File"
 895         DeleteRegKey HKLM "SOFTWARE\Classes\MPlayerForWindowsV2.File"
 896         DeleteRegKey HKCU "SOFTWARE\Classes\MPlayerForWindowsV2.File"
 897
 898         ${PrintStatus} "$(MUI_UNTEXT_FINISH_TITLE)"
 899 SectionEnd
 900
 901
 902 ;--------------------------------------------------------------------------------
 903 ; SECTION SELECTION CHANGED
 904 ;--------------------------------------------------------------------------------
 905
 906 Function .onSelChange
 907         ${IfNot} ${SectionIsSelected} ${SECID_MPUI}
 908         ${AndIfNot} ${SectionIsSelected} ${SECID_SMPLAYER}
 909                 MessageBox MB_TOPMOST|MB_ICONEXCLAMATION "$(MPLAYER_LANG_SELCHANGE)"
 910                 SectionGetFlags ${SECID_MPUI} $0
 911                 IntOp $0 $0 | ${SF_SELECTED}
 912                 SectionSetFlags ${SECID_MPUI} $0
 913         ${EndIf}
 914
 915         ${IfNot} ${SectionIsSelected} ${SECID_AUTOUPDATE}
 916                 StrCpy $0 "nope"
 917                 ${IfCmd} MessageBox MB_TOPMOST|MB_ICONEXCLAMATION|MB_YESNO|MB_DEFBUTTON2 "$(MPLAYER_LANG_SEL_AUTOUPDATE)" IDNO ${||} StrCpy $0 "ok" ${|}
 918                 ${If} "$0" == "ok"
 919                         SectionGetFlags ${SECID_AUTOUPDATE} $0
 920                         IntOp $0 $0 | ${SF_SELECTED}
 921                         SectionSetFlags ${SECID_AUTOUPDATE} $0
 922                 ${EndIf}
 923         ${EndIf}
 924 FunctionEnd
 925
 926
 927 ;--------------------------------------------------------------------------------
 928 ; LOCKED-LIST PLUGIN
 929 ;--------------------------------------------------------------------------------
 930
 931 !macro LockedListPage_Function
 932         !insertmacro MUI_HEADER_TEXT "$(MPLAYER_LANG_LOCKEDLIST_HEADER)" "$(MPLAYER_LANG_LOCKEDLIST_TEXT)"
 933
 934         InitPluginsDir
 935         File /oname=$PLUGINSDIR\LockedList64.dll `${NSISDIR}\Plugins\LockedList64.dll`
 936
 937         LockedList::AddModule "\MPlayer.exe"
 938         LockedList::AddModule "\SMPlayer.exe"
 939         LockedList::AddModule "\MPUI.exe"
 940         LockedList::AddModule "${NSISDIR}\Qt5Core.dll"
 941
 942         LockedList::Dialog /autonext /ignore "$(MPLAYER_LANG_IGNORE)" /heading "$(MPLAYER_LANG_LOCKEDLIST_HEADING)" /noprograms "$(MPLAYER_LANG_LOCKEDLIST_NOPROG)" /searching  "$(MPLAYER_LANG_LOCKEDLIST_SEARCH)" /colheadings "$(MPLAYER_LANG_LOCKEDLIST_COLHDR1)" "$(MPLAYER_LANG_LOCKEDLIST_COLHDR2)"
 943         Pop $R0
 944 !macroend
 945
 946 Function LockedListPage_Show
 947         !insertmacro LockedListPage_Function
 948 FunctionEnd
 949
 950 Function un.LockedListPage_Show
 951         !insertmacro LockedListPage_Function
 952 FunctionEnd
 953
 954
 955 ;--------------------------------------------------------------------------------
 956 ; CUSTOME PAGE: CPU SELECTOR
 957 ;--------------------------------------------------------------------------------
 958
 959 Function SelectCPUPage_Show
 960         ; Detect CPU type, if not detected yet
 961         ${If} $DetectedCPUType < 2
 962         ${OrIf} $DetectedCPUType > 5
 963                 Call DetectCPUType
 964                 !insertmacro INSTALLOPTIONS_READ $0 "Page_CPU.ini" "Field $DetectedCPUType" "Text"
 965                 !insertmacro INSTALLOPTIONS_WRITE "Page_CPU.ini" "Field $DetectedCPUType" "Text" "$0  <---"
 966         ${EndIf}
 967
 968         ; Make sure the current selection is valid
 969         ${IfThen} $SelectedCPUType < 2 ${|} StrCpy $SelectedCPUType $DetectedCPUType ${|}
 970         ${IfThen} $SelectedCPUType > 5 ${|} StrCpy $SelectedCPUType $DetectedCPUType ${|}
 971
 972         ; Translate
 973         !insertmacro INSTALLOPTIONS_WRITE "Page_CPU.ini" "Field 1" "Text" "$(MPLAYER_LANG_SELECT_CPU_TYPE)"
 974         !insertmacro INSTALLOPTIONS_WRITE "Page_CPU.ini" "Field 6" "Text" "$(MPLAYER_LANG_SELECT_CPU_HINT)"
 975
 976         ; Apply current selection to dialog
 977         ${For} $0 2 5
 978                 ${If} $0 == $SelectedCPUType
 979                         !insertmacro INSTALLOPTIONS_WRITE "Page_CPU.ini" "Field $0" "State" "1"
 980                 ${Else}
 981                         !insertmacro INSTALLOPTIONS_WRITE "Page_CPU.ini" "Field $0" "State" "0"
 982                 ${EndIf}
 983         ${Next}
 984
 985         ; Display dialog
 986         !insertmacro MUI_HEADER_TEXT "$(MPLAYER_LANG_SELECT_CPU_HEAD)" "$(MPLAYER_LANG_SELECT_CPU_TEXT)"
 987         !insertmacro INSTALLOPTIONS_DISPLAY "Page_CPU.ini"
 988
 989         ; Read new selection from dialog
 990         StrCpy $SelectedCPUType 0
 991         ${For} $0 2 5
 992                 !insertmacro INSTALLOPTIONS_READ $1 "Page_CPU.ini" "Field $0" "State"
 993                 ${IfThen} $1 == 1 ${|} StrCpy $SelectedCPUType $0 ${|}
 994         ${Next}
 995 FunctionEnd
 996
 997 Function SelectCPUPage_Validate
 998         ; Read new selection from dialog
 999         StrCpy $2 0
1000         ${For} $0 2 5
1001                 !insertmacro INSTALLOPTIONS_READ $1 "Page_CPU.ini" "Field $0" "State"
1002                 ${IfThen} $1 == 1 ${|} StrCpy $2 $0 ${|}
1003         ${Next}
1004
1005         ; Validate selection
1006         ${If} $2 < 2
1007         ${OrIf} $2 > 5
1008                 MessageBox MB_ICONSTOP "Oups, invalid selection detected!"
1009                 Abort
1010         ${EndIf}
1011 FunctionEnd
1012
1013 Function DetectCPUType
1014         StrCpy $DetectedCPUType 5 ;generic
1015         StrCpy $DetectedCPUCores 2
1016
1017         ${IfNot} ${Silent}
1018                 Banner::show /NOUNLOAD "$(MPLAYER_LANG_DETECTING)"
1019         ${EndIf}
1020
1021         ${CPUFeatures.GetCount} $0
1022         ${IfNot} $0 == "error"
1023                 StrCpy $DetectedCPUCores $0
1024         ${EndIf}
1025
1026         ; Debug Code
1027         !ifdef CPU_DETECT_DEBUG
1028                 ${CPUFeatures.GetVendor} $0
1029                 ${CPUFeatures.CheckFeature} "MMX1"   $1
1030                 ${CPUFeatures.CheckFeature} "3DNOW"  $2
1031                 ${CPUFeatures.CheckFeature} "SSE3"   $3
1032                 ${CPUFeatures.CheckFeature} "SSSE3"  $4
1033                 ${CPUFeatures.CheckFeature} "SSE4.2" $5
1034                 ${CPUFeatures.CheckFeature} "AVX1"   $6
1035                 ${CPUFeatures.CheckFeature} "FMA4"   $7
1036                 StrCpy $9 `Vendor = $0`
1037                 StrCpy $9 `$9$\n"MMX1" = $1`
1038                 StrCpy $9 `$9$\n"3DNOW" = $2`
1039                 StrCpy $9 `$9$\n"SSE3" = $3`
1040                 StrCpy $9 `$9$\n"SSSE3" = $4`
1041                 StrCpy $9 `$9$\n"SSE4.2" = $5`
1042                 StrCpy $9 `$9$\n"AVX1" = $6`
1043                 StrCpy $9 `$9$\n"FMA4" = $7`
1044                 MessageBox MB_TOPMOST `$9`
1045         !endif
1046
1047         ; Make sure we have at least MMX
1048         ${IfNot} ${CPUSupports} "MMX1"
1049                 Banner::destroy
1050                 Return
1051         ${EndIf}
1052
1053         ; Select the "best" model for Intel's
1054         ${If} ${CPUIsIntel}
1055                 ; Core2 (SSE3 + SSSE3)
1056                 ${If} ${CPUSupportsAll} "SSE3,SSSE3"
1057                         StrCpy $DetectedCPUType 2 ;
1058                 ${EndIf}
1059                 ; Nehalem (SSE3 + SSSE3 + SSE4.2)
1060                 ${If} ${CPUSupportsAll} "SSE3,SSSE3,SSE4.2"
1061                         StrCpy $DetectedCPUType 3
1062                 ${EndIf}
1063         ${EndIf}
1064
1065         ; Select the "best" model for AMD's
1066         ${If} ${CPUIsAMD}
1067                 ; K8+SSE3 (3DNow! + SSE3)
1068                 ${If} ${CPUSupportsAll} "3DNOW,SSE3"
1069                         StrCpy $DetectedCPUType 4
1070                 ${EndIf}
1071                 ; Bulldozer (SSE3 + SSSE3 + SSE4.2 + AVX + FMA4)
1072                 ;${If} ${CPUSupportsAll} "SSE3,SSSE3,SSE4.2,AVX1,FMA4"
1073                 ;       StrCpy $DetectedCPUType 5       #5 is now generic, as 'bdver1' build got dropped
1074                 ;${EndIf}
1075         ${EndIf}
1076
1077         Banner::destroy
1078 FunctionEnd
1079
1080
1081 ;--------------------------------------------------------------------------------
1082 ; CUSTOME PAGE: TWEAKS
1083 ;--------------------------------------------------------------------------------
1084
1085 Function SetTweaksPage_Show
1086         ; Apply current selection to dialog
1087         StrCpy $0 1
1088         ${For} $1 2 4
1089                 IntOp $2 $0 & $SelectedTweaks
1090                 ${If} $2 != 0
1091                         !insertmacro INSTALLOPTIONS_WRITE "Page_Tweaks.ini" "Field $1" "State" "1"
1092                 ${Else}
1093                         !insertmacro INSTALLOPTIONS_WRITE "Page_Tweaks.ini" "Field $1" "State" "0"
1094                 ${EndIf}
1095                 IntOp $0 $0 << 1
1096         ${Next}
1097
1098         ; Translate
1099         !insertmacro INSTALLOPTIONS_WRITE "Page_Tweaks.ini" "Field 1" "Text" "$(MPLAYER_LANG_TWEAKS_HINT)"
1100         !insertmacro INSTALLOPTIONS_WRITE "Page_Tweaks.ini" "Field 2" "Text" "$(MPLAYER_LANG_TWEAKS_SKINNEDUI)"
1101         !insertmacro INSTALLOPTIONS_WRITE "Page_Tweaks.ini" "Field 3" "Text" "$(MPLAYER_LANG_TWEAKS_OPENGL)"
1102         !insertmacro INSTALLOPTIONS_WRITE "Page_Tweaks.ini" "Field 4" "Text" "$(MPLAYER_LANG_TWEAKS_VOLNORM)"
1103
1104         ; Display dialog
1105         !insertmacro MUI_HEADER_TEXT "$(MPLAYER_LANG_TWEAKS_HEAD)" "$(MPLAYER_LANG_TWEAKS_TEXT)"
1106         !insertmacro INSTALLOPTIONS_DISPLAY "Page_Tweaks.ini"
1107
1108         ; Read new selection from dialog
1109         StrCpy $0 1
1110         ${For} $1 2 4
1111                 !insertmacro INSTALLOPTIONS_READ $2 "Page_Tweaks.ini" "Field $1" "State"
1112                 ${IfThen} $2 == 1 ${|} IntOp $SelectedTweaks $SelectedTweaks | $0 ${|}
1113                 IntOp $0 $0 << 1
1114         ${Next}
1115 FunctionEnd
1116
1117
1118 ;--------------------------------------------------------------------------------
1119 ; CHECK FOR UPDATE MODE
1120 ;--------------------------------------------------------------------------------
1121
1122 !macro SetControlEnabled item_id enable
1123         FindWindow $0 "#32770" "" $HWNDPARENT
1124         ${IfNot} $0 == 0
1125                 GetDlgItem $1 $0 ${item_id}
1126                 EnableWindow $1 ${enable}
1127         ${EndIf}
1128 !macroend
1129
1130 !macro SkipToNextPage
1131         GetDlgItem $0 $HWNDPARENT 1
1132         System::Call "User32::PostMessage(i $HWNDPARENT, i ${WM_COMMAND}, i 1, i $R0)"
1133 !macroend
1134
1135 !macro EnablePathEditable flag show_msg
1136         !insertmacro SetControlEnabled 1019 ${flag}
1137         !insertmacro SetControlEnabled 1001 ${flag}
1138         ${IfNot} $NotUpdateInstall == ${flag}
1139                 !if ${show_msg} == 1
1140                         MessageBox MB_OK|MB_ICONINFORMATION "$(MPLAYER_LANG_FORCE_UPDATE)" /SD IDOK
1141                 !endif
1142                 StrCpy $NotUpdateInstall ${flag}
1143                 !insertmacro SkipToNextPage
1144         ${EndIf}
1145 !macroend
1146
1147 Function CheckForUpdate
1148         ${StdUtils.GetParameter} $0 "Update" "?"
1149         ${IfNot} "$0" == "?"
1150                 !insertmacro EnablePathEditable 0 0
1151                 Return
1152         ${EndIf}
1153
1154         ${If} ${FileExists} "$INSTDIR\MPlayer.exe"
1155                 !insertmacro EnablePathEditable 0 1
1156                 Return
1157         ${EndIf}
1158
1159         !insertmacro EnablePathEditable 1 0
1160 FunctionEnd
1161
1162
1163 ;--------------------------------------------------------------------------------
1164 ; FINISHED
1165 ;--------------------------------------------------------------------------------
1166
1167 Function RunAppFunction
1168         !insertmacro DisableNextButton $R0
1169         ${If} ${FileExists} "$INSTDIR\SMPlayer.exe"
1170                 ${StdUtils.ExecShellAsUser} $R0 "$INSTDIR\SMPlayer.exe" "open" "http://lounge-office.rautemusik.fm/"
1171         ${Else}
1172                 ${StdUtils.ExecShellAsUser} $R0 "$INSTDIR\MPUI.exe" "open" "http://lounge-office.rautemusik.fm/"
1173         ${EndIf}
1174 FunctionEnd
1175
1176 Function ShowReadmeFunction
1177         !insertmacro DisableNextButton $R0
1178         ${StdUtils.ExecShellAsUser} $R0 "$INSTDIR\Readme.html" "open" ""
1179 FunctionEnd
1180
1181 Function .onInstSuccess
1182         ${StdUtils.ExecShellAsUser} $R0 "$SMPROGRAMS\$StartMenuFolder" "explore" ""
1183 FunctionEnd
1184
1185
1186 ### EOF ###